почему может не создаваться dispatchEvent?

kaetano · 23.11.2009, 03:51

Здравствуйте.

У меня есть класс, который формирует свое событие. Так получается что оно должно появляться дважды. Т.е сначала один экземпляр его создает. потом другой. Но вот во втором случае не происходит формирование этого события (хотя все остальные действия производит верно). Класс подгружает внешнюю swf, плавно увеличивается альфа, ждет 5 сек и плавно уменьшает альфу. после чего удаляет swf. Чувствую что надо как-то dispatchEvent где-то обнулять или что-то с ним делать......

Помогите разобраться. Спасибо! Рискну привести весь код класса

Код AS3:

package {
	import flash.display.*;
	import flash.events.*;
	import flash.net.*;
	import flash.utils.*;
 
	public class Anim extends MovieClip {
		private var loader:Loader;
		private var loaderContent:DisplayObject;
		private var _tTimer:Timer = new Timer(10);
		private var _tTimer5sek:Timer = new Timer(1000);
		private var _isLoad:Boolean = false;
		private var _countTime:int = 0;
		private var _selfEnd:Boolean = false;		//самозакрытие
 
		public static const END_APPEAR: String = "END_APPEAR"; 
		public static const END_DISAPPEAR: String = "END_DISAPPEAR"; 
 
		public function Anim(pic:String = "", selfEnd:Boolean = false){
			_selfEnd = selfEnd;
 
			this.alpha = 0;
			_countTime = 0;
			loader = new Loader();
			loader.contentLoaderInfo.addEventListener(Event.INIT, initListener);
			var urlRequest:URLRequest = new URLRequest(pic)
			loader.load(urlRequest);
 
		}		
 
		private function initListener(event:Event):void{
			_isLoad = true;
			loaderContent = loader.content;
 
			addChild(loaderContent);	
			_tTimer.reset();
			_tTimer.addEventListener(TimerEvent.TIMER, onTimer);
			_tTimer.start();
		}
		//Плавное появление
		private function onTimer(event:TimerEvent):void{
			if(!MainDisp.main.isPaused){
				if(this.alpha<=.8){
					this.alpha += .1;
				}
				else{
					this.alpha = 1;
					event.target.removeEventListener(TimerEvent.TIMER, onTimer);
					this.dispatchEvent(new Event(Anim.END_APPEAR, true));
					if(_selfEnd){
						_tTimer5sek.reset();
						_tTimer5sek.addEventListener(TimerEvent.TIMER, onTimer5sek);
						_tTimer5sek.start();
					}
				}
			}
		}		
		//ждем 5 сек
		private function onTimer5sek(event:TimerEvent):void{
			if(!MainDisp.main.isPaused){
				_countTime++;
				if(_countTime >= 6){
					_tTimer5sek.removeEventListener(TimerEvent.TIMER, onTimer5sek);
					_tTimer.reset();
					_tTimer.addEventListener(TimerEvent.TIMER, onTimerDisappear);
					_tTimer.start();
				}
			}
		}
		//плавное исчезновение
		private function onTimerDisappear(event:TimerEvent):void{
			if(!MainDisp.main.isPaused){
				if(this.alpha>=.2){
					this.alpha -= .1;
				}
				else{				
					event.target.removeEventListener(TimerEvent.TIMER, onTimerDisappear);
					exit();
					this.dispatchEvent(new Event(Anim.END_DISAPPEAR, true));
				}
			}
			else{
				trace("PAUSE!!!")
				//event.target.start();
			}
		}
		//экстренный выход (если родитель захочет перейти на дргой шаг)
		public function exit():void{
			_tTimer.removeEventListener(TimerEvent.TIMER, onTimerDisappear);
			_tTimer5sek.removeEventListener(TimerEvent.TIMER_COMPLETE, onTimer5sek);
			_tTimer.removeEventListener(TimerEvent.TIMER, onTimer);
 
			this.alpha = 0;				
				try{
					loader.close();
				}
				catch(e:*){};
 
			removeChild(loaderContent);
			loader.unload();
			_isLoad = false;
		}
 
		public function get isLoad():Boolean{
			return _isLoad;
		}
	}
}

Добавлено через 2 минуты

Родительский класс (в котором создаются экземпляры Anim)

Код AS3:

private function onPicture(){			
	_curPic = String(arrCurPic[_curI].picPath);
	//ожидаем когда картинка исчезнет
	addEventListener(Anim.END_DISAPPEAR, onEndDisappearPic);	
	showPic(_curPic, true);	
}
 
//Показать картинки
private function showPic(pic:String = "", flSelfEnd:Boolean = false){
	anim = new Anim(pic, flSelfEnd);
	addChild(anim);
}	
 
private function onEndDisappearPic(event:Event):void{
	if (anim!=null && anim.isLoad){
	     anim.exit();
	    anim = null;
             }
             removeEventListener(Anim.END_DISAPPEAR, onEndDisappearPic);
}

Добавлено через 22 минуты
Извиняюсь за обрезанное название, что-то сегодня тут еще более тяжко писать-отвечать (надеюсь это не у моего браузера глюк)

udaaff · 23.11.2009, 04:40

До конца не ясно, но возможно обработчики нужно на объекты Anim вешать, во втором коде.

kaetano · 23.11.2009, 13:25

Цитата:

Сообщение от udaaff

До конца не ясно, но возможно обработчики нужно на объекты Anim вешать, во втором коде.

ТОЧНО!
Спасибо!

Как-то была у меня подоблная ситуация, но почему-то решила в пользк stage....

dimarik · 23.11.2009, 21:46

Цитата:

Сообщение от kaetano

Извиняюсь за обрезанное название, что-то сегодня тут еще более тяжко писать-отвечать (надеюсь это не у моего браузера глюк)

Это обычное состояние flasher.ru =) Бывает, по три-четыре раза нужно перегрузить страницу, чтобы прочитать пост.

gloomyBrain · 23.11.2009, 22:01

Кстати, сори за оффтоп, но заметил, что в GoogleChrome (который я в основном использую) глючат только bb-тэги, а аватарки и посты грузятся полностью. А в мозилле бывает, что вообще пол страницы недогружается

dimarik · 23.11.2009, 22:44

это не зависит от браузера =)

gloomyBrain · 23.11.2009, 23:05

Да, но разница то есть (я понимаю, что там что-то с временем отдачи на сервере или что-то тп) =)

dimarik · 23.11.2009, 23:14

давайте проверим =)

Killer600 · 25.11.2009, 16:40

А у меня что-то не получается...

Имеется класс, в котором генерируются собственные события с помощью dispatchEvent:

Код AS3:

		public function sndPlay() : void
		{
			if (_sound == null) return;
 
			...
 
			this.dispatchEvent(new Event(SoundEvent.SOUND_PLAY, true));
			return;
		}
 
		public function sndPause() : void
		{
			if (_sound == null) return;
 
			_position = _soundchannel.position;
			_soundchannel.stop();
			soundstate = MusicPlayerStates.PAUSE;
			this.dispatchEvent(new Event(SoundEvent.SOUND_PAUSE, true));
			return;
		}
 
		public function sndStop() : void
		{
			if ((_sound == null) || (soundstate == MusicPlayerStates.STOP)) return;
 
			_position = 0;
			_soundchannel.stop();
			if (_isLoading) _sound.close();
			soundstate = MusicPlayerStates.STOP;
			this.dispatchEvent(new Event(SoundEvent.SOUND_STOP, true));
			return;
		}

В том месте, где создаётся экземпляр класса, я ставлю прослушиватель собственных сгенерированных событий:

Код AS3:

		musicSound = new MusicPlayerSound(_loc_2, _autoplay, true);
		...
		musicSound.addEventListener(SoundEvent.SOUND_STREAMERROR, soundError);

...и не работает

Класс SoundEvent:

Код AS3:

	public class SoundEvent extends Event
	{
		public static const SOUND_PLAY:String = "soundPlay";
		public static const SOUND_PAUSE:String = "soundPause";
		public static const SOUND_STOP:String = "soundStop";
		public static const SOUND_LOAD:String = "soundLoad";
		public static const SOUND_STATE:String = "soundState";
		public static const SOUND_STREAMERROR:String = "soundStreamError";
		public var data: Object;
 
		public function SoundEvent(type:String, date: Object, bubbles:Boolean=false, cancelable:Boolean=false)
		{
			super(type, bubbles, cancelable);
			this.data = data;
		}
 
		override public function clone():Event
		{
			return new SoundEvent(type, data, bubbles, cancelable);
		}
	}

Событие внутри класса срабатывает на ура, а в экземпляре - нет
Help me please

SamFR · 25.11.2009, 16:55

не

Код AS3:

this.dispatchEvent(new Event(SoundEvent.SOUND_PLAY, true));

а

Код AS3:

this.dispatchEvent(new SoundEvent(SoundEvent.SOUND_PLAY, true));

Добавлено через 4 минуты
Обработчик должен иметь следующий вид:

Код AS3:

function eSoundPlay(event:SoundEvent):void

Впрочем, параметр event обработчика может иметь и тип Event, но тогда вам придётся использовать кастинг для доступа к свойству data экземпляра события, а это не есть хорошо.