Убирание движения после нажатия на кнопку

[tgonta]

И ещё один вопрос: как убрать движение мыши при нажатии на кнопку? так не получается:

SvechaBox.onPress = function() {
    Candle._x = _root._xmouse;
    Candle._y = _root._ymouse;
	this.onMouseMove = function(){
	    Candle._x = _root._xmouse;
    	Candle._y = _root._ymouse;
	}
	dragging = true;
	if(dragging = false) {
		delete this.onMouseMove;
	}
}
btn1.onPress = function() {
	if(dragging = true) {
		dragging = false;
	    Candle._x = _root._xmouse;
	    Candle._y = _root._ymouse;
	}
}

[mooncar]

1. Ошибка синтаксиса. Условия пишутся вот так:

if(dragging == false)

2. даже с учетом ошибки синтаксиса есть еще ошибка логики. Вот тут

	dragging = true;
	if(dragging == false) { //исправлен синтаксис
		delete this.onMouseMove;
	}

условие dragging == false никогда не выполнится, в строке перед условием dragging всегда назначается true.

[tgonta]

SvechaBox.onPress = function() {
    Candle._x = _root._xmouse;
    Candle._y = _root._ymouse;
	this.onMouseMove = function(){
	    Candle._x = _root._xmouse;
    	Candle._y = _root._ymouse;
	}
	dragging = true;
	btn1.onPress = function() {
		if(dragging == true) {
			dragging = false;
	    	Candle._x = _root._xmouse;
	    	Candle._y = _root._ymouse;
		}
	}
	if(dragging == false) {
		delete this.onMouseMove;
	}
}

Всё равно не хочет...

[mooncar]

Выложите.

[tgonta]

if(dragging == true) {
			dragging = false;

вроде есть...

а как сделать, чтобы условие выполнялось?

[mooncar]

Решение, видимо, несложно, просто где у вас SvechaBox, Candle и btn1 относительно друг друга - не очень понятно, опишите или выложите.

[tgonta]

http://slil.ru/28203841 - вот эта часовенка...

[mooncar]

Если для одной свечи:

SvechaBox.onPress = function() {
    dragging = true ;
    moveCandle ();
   Candle.onMouseMove = moveCandle;
}	
 
function moveCandle () {
    Candle._x = _root._xmouse;
    Candle._y = _root._ymouse;
}
 
 
btn1.onPress = function() {
	if(dragging) {
		dragging = false ;
		delete Candle.onMouseMove ;
	}
}

Если для любой свечи, надо доработать.

PS. У вас в основании мувика-свечи есть невидимая кнопка - она мешает нажать на кнопку-подсвечник.
Если ее убрать, сделать несколько кнопок-подсвечников btn1, btn2 и тд. до 21, то можно реализовать алгоритм для нескольких свечей:

var count:Number = 0;
var currentCandle:MovieClip ;
var dragging:Boolean = false ;
 
SvechaBox.onPress = function() {
	var num:Number =  count++;
        dragging = true ;
	currentCandle = Candle.duplicateMovieClip('candele' + num, num);
	currentCandle.onMouseMove = moveCandle;	
	moveCandle ();
}	
 
for (i = 1; i <= 21; i++) {
	this['btn' + i].onPress = stopMoveCandle ;
}
 
function moveCandle () {
	currentCandle._x = _root._xmouse;
  	currentCandle._y = _root._ymouse;
}
 
function stopMoveCandle () {
	if(dragging && !this.ready) {
		delete currentCandle.onMouseMove;
		this.ready = true ; //предотвращает вставку свечи в подсвечник уже со свечой
		dragging = false ;		
	}
}

[tgonta]

mooncar

Попробовал сделать несколько свечек и не получилось. Жму - а свечу двигают.

[mooncar]

Посмотрите:
http://slil.ru/28213158