flash develop ругается на Delegate

[Fernando Costa]

при компиляции выдает ошибку

C:\Documents and Settings\anton\Local Settings\Application Data\Adobe\Flash CS3\en\Configuration\Classes/mx/utils/Delegate.as:27: characters 3-11 : type error Local variable redefinition : func

static function create(obj:Object, func:Function):Function
	{
		var f = function()
		{
			var target = arguments.callee.target;
			var func = arguments.callee.func;//  <- вот тут

			return func.apply(target, arguments);
		};

При компиляции во флеше - все нормально. Может есть где указать правило для компилятора?

что за лажа такая

[iNils]

Забыть про mx.utils.Delegate.as и использовать свой.
А учитывая, что mx.utils.Delegate.as инвалид, то это набло сделать давным давно.

[Fernando Costa]

не могу с помошью этого класса: http://flasher.ru/forum/showpost.php...35&postcount=4 передать параметры в эту штуку http://flasher.ru/forum/showthread.php?t=107944

[iNils]

Попробуй моим

/**
* Класс ru.inils.framework.Delegate, модифицированный mx.utils.Delegate. Выполнение функции в заданной области видимости с передачей аргументов.
* 
* @author	iNils
* @version	1.2
* @see		mx.utils.Delegate
* Изменения:
* 	1.2 (xx.xx.07)
* 	[*]	Переехал из пакета ru.inils.util.Delegate
* 
*	1.1 (xx.xx.07)
* 	[+]	Добавлена возможность передавать аргументы "родного" метода
* 
* 	1.0 (xx.xx.06)
*/

class ru.inils.framework.Delegate extends Object {
	/**
	* Метод, передает событие в заданную область видимость и в заданный метод.
	* 
	* @usage			public static create (obj:Object, func:Function, arg:Array) : Function
	* @param	obj		Object - Объект, заданная область видимости.
	* @param	func	Function - Метод, обработчик события.
	* @param	arg		Array [дополнительный параметр] - Массив передаваемых аргументов, замещающий аргументы передаваемые "родным" событием. По умолчанию возращаются аргументы переданный при вызове "родного" события.
	* @return  Function	- Функция обработчик.
	*/
	public static function create (obj:Object, func:Function, arg:Array):Function {
		var f = function () {
			var targetTemp:Object = arguments.callee.target;
			var funcTemp:Function = arguments.callee.func;
			var argTemp:Array = null;
			if (arguments.callee.arg) {
				argTemp = arguments.callee.arg;
			} else {
				argTemp = arguments;
			}
			return funcTemp.apply (targetTemp, argTemp);
		};
		f.target = obj;
		f.func = func;
		f.arg = arg;
		return f;
	}
}

[alekslitvinenk]

Как вариант можно пользоваться библиотекой классов ASWing
org.aswing.util.Delegate
Скачать можно тут:https://svn1.cvsdude.com/osflash/aswing/

[Fernando Costa]

2 iNils другое дело теперь стандартный заменоделегатовский класс будет этот. Спасибо
2 alekslitvinenk, спасибо за ссылку, почитаю