класс для сортировки массива

[divinus]

Собственно это не вопрос... ) просто я нашел хорошую реализацию сортировки массива и хочу поделиться... )

package {
	public class SortUtils {
		public function SortUtils() {
		}
		public static function sort(a:Array, p:String):void {
			if (!a || a.length <= 1) {
				return;
			}
			if (p && (typeof(a[0][p]) == "string" || typeof(a[0][p]) == "number" || typeof(a[0][p]) == "boolean")) {
				doObjSort(a, 0, a.length - 1, p);
			} else if (typeof(a[0]) == "string" || typeof(a[0]) == "number" || typeof(a[0]) == "boolean") {
				doPrimSort(a, 0, a.length - 1);
			}
		}
		private static function doObjSort(a, we:Number, ee:Number, p):void {
			var wc:Number = we;
			var ec:Number = ee;
			var pivot:Object = a[Math.round((we+ee)/2)][p];
			var t:Object;
			while (true) {
				while (a[wc][p] < pivot) {
					wc++;
				}
				while (a[ec][p] > pivot) {
					ec--;
				}
				if (wc > ec) {
					break;
				}
				t = a[wc];
				a[wc++] = a[ec];
				a[ec--] = t;
			}
			if (we < ec) {
				doObjSort(a, we, ec, p);
			}
			if (ee > wc) {
				doObjSort(a, wc, ee, p);
			}
		}
		private static function doPrimSort(a, we:Number, ee:Number):void {
			var wc:Number = we;
			var ec:Number = ee;
			var pivot:Object = a[we];
			var t:Object;
			while (true) {
				while (a[wc] < pivot) {
					wc++;
				}
				while (a[ec] > pivot) {
					ec--;
				}
				if (wc > ec) {
					break;
				}
				t = a[wc];
				a[wc++] = a[ec];
				a[ec--] = t;
			}
			if (we < ec) {
				doPrimSort(a, we, ec);
			}
			if (ee > wc) {
				doPrimSort(a, wc, ee);
			}
		}
	}
}

это собственно класс, ну и просто для ленивых архив.
Ах да, забыл сказать, для чего я это все... эта сортировка работает быстрее чем стандартный sort()

[mikleb]

По моему это намного тормазнее чем sort() (было бы странно если нет)

[Яски]

Это быстрая сортировка на флеше, делал подобную штуку.
Работает быстрее стандартной на данных с большим кол-вом повторяющихся элементов, иногда ускорение составляет больше 10000%.