Создание инструмента рисования овала

[rsdrp]

Подскажите пожалуйста как реализовать в графическом редакторе (написанном во флеше) инструмент для рисования овала?

[wvxvw]

public static function crlIn(mc:MovieClip, r:Number, c:Number, a:Number):MovieClip {
		var _mc:MovieClip = mc.createEmptyMovieClip("crl"+counter, mc.getNextHighestDepth());
		var c1:Number=r*(Math.SQRT2-1);
		var c2:Number=r*Math.SQRT2/2;
		var d:Number = r*2;
		_mc.beginFill(c,a);
		_mc.moveTo(d,r);
		_mc.curveTo(d,r+c1,r+c2,r+c2);
		_mc.curveTo(r+c1,d,r,d);
		_mc.curveTo(r-c1,d,r-c2,r+c2);
		_mc.curveTo(0,r+c1,0,r);
		_mc.curveTo(0,r-c1,r-c2,r-c2);
		_mc.curveTo(r-c1,0,r,0);
		_mc.curveTo(r+c1,0,r+c2,r-c2);
		_mc.curveTo(d,r-c1,d,r);
		_mc.endFill();
		return _mc;
	}

[rsdrp]

Так а че не работает?!..(

[CorC]

Все работает

[rsdrp]

Сообщение от CorC

Все работает

Простите...
Ну а как его использовать? Просто поставить в кадр и все? Если так то не работает.
Может в нем нужно какие-то параметры поменять?

[etc]

Если вы не понимаете, как использовать функцию, то кто пишет редактор тогда?

[wvxvw]

var _mc:MovieClip = crlIn(this, 100, 0xff00ff, 70);
_mc._xscale = 50;
_mc._x = Stage.width/2-_mc._width/2;
_mc._y = Stage.height/2-_mc._height/2;
function crlIn(mc:MovieClip, r:Number, c:Number, a:Number):MovieClip {
	var _mc:MovieClip = mc.createEmptyMovieClip("crl"+mc.getNextHighestDepth(), mc.getNextHighestDepth());
	var c1:Number = r*(Math.SQRT2-1);
	var c2:Number = r*Math.SQRT2/2;
	var d:Number = r*2;
	_mc.beginFill(c,a);
	_mc.moveTo(d,r);
	_mc.curveTo(d,r+c1,r+c2,r+c2);
	_mc.curveTo(r+c1,d,r,d);
	_mc.curveTo(r-c1,d,r-c2,r+c2);
	_mc.curveTo(0,r+c1,0,r);
	_mc.curveTo(0,r-c1,r-c2,r-c2);
	_mc.curveTo(r-c1,0,r,0);
	_mc.curveTo(r+c1,0,r+c2,r-c2);
	_mc.curveTo(d,r-c1,d,r);
	_mc.endFill();
	return _mc;
}

Адаптированое к использованю вне класса издание %) с примером %)

[rsdrp]

Мне нужен не генерирующийся кодом овал.. А возможность его "свободного рисования" на сцене!

[etc]

Нужно — напишите.
По аналогии с приведенным кодом.

[wvxvw]

_root.onMouseDown = function():Void {
	var __ax:Number = _root._xmouse;
	var __ay:Number = _root._ymouse;
	var __mc:MovieClip = null;
	_root.onEnterFrame = function():Void {
		if(__mc==null){
			__mc = crlIn(this, 100, Math.random()*0xffffff,Math.random()*100);
		}
		__mc._x = Math.min(__ax,_root._xmouse);
		__mc._y = Math.min(__ay,_root._ymouse);
		__mc._width = Math.max(__ax,_root._xmouse)-Math.min(__ax,_root._xmouse);
		__mc._height = Math.max(__ay,_root._ymouse)-Math.min(__ay,_root._ymouse);
	}
}
_root.onMouseUp = function():Void {
	delete this.onEnterFrame;
}
function crlIn(mc:MovieClip, r:Number, c:Number, a:Number):MovieClip {
	var _mc:MovieClip = mc.createEmptyMovieClip("crl"+mc.getNextHighestDepth(), mc.getNextHighestDepth());
	var c1:Number = r*(Math.SQRT2-1);
	var c2:Number = r*Math.SQRT2/2;
	var d:Number = r*2;
	_mc.beginFill(c,a);
	_mc.moveTo(d,r);
	_mc.curveTo(d,r+c1,r+c2,r+c2);
	_mc.curveTo(r+c1,d,r,d);
	_mc.curveTo(r-c1,d,r-c2,r+c2);
	_mc.curveTo(0,r+c1,0,r);
	_mc.curveTo(0,r-c1,r-c2,r-c2);
	_mc.curveTo(r-c1,0,r,0);
	_mc.curveTo(r+c1,0,r+c2,r-c2);
	_mc.curveTo(d,r-c1,d,r);
	_mc.endFill();
	return _mc;
}

%)