Форум Flasher.ru
Ближайшие курсы в Школе RealTime
Список интенсивных курсов: [см.]  
  
Специальные предложения: [см.]  
  
 
Блоги Правила Справка Пользователи Календарь Сообщения за день
 

Вернуться   Форум Flasher.ru > Flash > ActionScript 3.0

Версия для печати  Отправить по электронной почте    « Предыдущая тема | Следующая тема »  
Опции темы Опции просмотра
 
Создать новую тему Ответ
Старый 04.12.2016, 20:22
ZackMercury вне форума Посмотреть профиль Отправить личное сообщение для ZackMercury Найти все сообщения от ZackMercury
  № 41  
Ответить с цитированием
ZackMercury
 
Аватар для ZackMercury

блогер
Регистрация: Jul 2013
Адрес: Север
Сообщений: 1,922
Записей в блоге: 23
Отправить сообщение для ZackMercury с помощью ICQ Отправить сообщение для ZackMercury с помощью Skype™
Цитата:
пишет:
Всё работает, ищи косяк.

Цитата:
а что ?
ничего.
__________________
There is no thing in this world that is not simple.

Старый 04.12.2016, 20:51
zackscript вне форума Посмотреть профиль Отправить личное сообщение для zackscript Найти все сообщения от zackscript
  № 42  
Ответить с цитированием
zackscript
 
Аватар для zackscript

Регистрация: Jan 2014
Сообщений: 181
Отправить сообщение для zackscript с помощью Skype™
Но почему он пустой ?
Код AS3:
var _loader:Loader = new Loader();
var _imgData:BitmapData;
var _btm:Bitmap;
var _iter:Number = 0;
var _btmData:Vector.<BitmapData> = new Vector.<BitmapData>();
 
for (var i = 0; i <= 2; i++)
{
	_loader = new Loader();
	_loader.load(new URLRequest("sgu" + i + ".jpg"));
	_loader.contentLoaderInfo.addEventListener(Event.COMPLETE, onCmplt);
}
function onCmplt(e:Event):void
{
	_imgData = e.currentTarget.content.bitmapData;
	_btmData.push(_imgData);
         trace("bla"); // проблайкала 3 раза )
}
 
trace(_btmData); // пустой вектор

Старый 04.12.2016, 20:58
ZackMercury вне форума Посмотреть профиль Отправить личное сообщение для ZackMercury Найти все сообщения от ZackMercury
  № 43  
Ответить с цитированием
ZackMercury
 
Аватар для ZackMercury

блогер
Регистрация: Jul 2013
Адрес: Север
Сообщений: 1,922
Записей в блоге: 23
Отправить сообщение для ZackMercury с помощью ICQ Отправить сообщение для ZackMercury с помощью Skype™
Может потому, что код, идущий после описания функции onCmplt не означает, что он выполнится ПОСЛЕ выполнения кода функции? Почитайте про синхронные и асинхронные операции. Функция выполнится после загрузки, а код после подписки продолжит выполняться до конца.
Вот так всё загружается.
__________________
There is no thing in this world that is not simple.


Последний раз редактировалось ZackMercury; 04.12.2016 в 21:16.
Старый 04.12.2016, 22:09
zackscript вне форума Посмотреть профиль Отправить личное сообщение для zackscript Найти все сообщения от zackscript
  № 44  
Ответить с цитированием
zackscript
 
Аватар для zackscript

Регистрация: Jan 2014
Сообщений: 181
Отправить сообщение для zackscript с помощью Skype™
ZackMercury, благодарю , спасибо.
Да и ещё , кто эти люди на фото ?

Старый 04.12.2016, 22:13
ZackMercury вне форума Посмотреть профиль Отправить личное сообщение для ZackMercury Найти все сообщения от ZackMercury
  № 45  
Ответить с цитированием
ZackMercury
 
Аватар для ZackMercury

блогер
Регистрация: Jul 2013
Адрес: Север
Сообщений: 1,922
Записей в блоге: 23
Отправить сообщение для ZackMercury с помощью ICQ Отправить сообщение для ZackMercury с помощью Skype™
Цитата:
Да и ещё , кто эти люди на фото ?
Команда Microsoft, 1978. Слева внизу рыженький Билл.
__________________
There is no thing in this world that is not simple.

Старый 04.12.2016, 22:15
zackscript вне форума Посмотреть профиль Отправить личное сообщение для zackscript Найти все сообщения от zackscript
  № 46  
Ответить с цитированием
zackscript
 
Аватар для zackscript

Регистрация: Jan 2014
Сообщений: 181
Отправить сообщение для zackscript с помощью Skype™
Цитата:
Слева внизу рыженький Билл.
я так и знал )

Старый 05.12.2016, 07:44
caseyryan вне форума Посмотреть профиль Отправить личное сообщение для caseyryan Найти все сообщения от caseyryan
  № 47  
Ответить с цитированием
caseyryan
 
Аватар для caseyryan

Регистрация: Jun 2012
Адрес: Новосибирск
Сообщений: 6,644
Записей в блоге: 4
Цитата:
Сообщение от ZackMercury Посмотреть сообщение
[as3]
Зачем столько загрузчиков?
Если грузить с локалки, то лучше делать много загрузчиков. Так загрузка пройдет гораздо быстрее, чем в твоем примере. А если грузить из сети, то можно сделать мультизагрузчик, с возможностью ограничения количества открытых потоков.
Я делал как-то вот такой велосипед:
Код AS3:
package  {
	import flash.events.Event;
	import flash.events.EventDispatcher;
	import flash.filesystem.File;
	/**
	 * этот загрузчик может скачивать картинки с нескольких адресов одновременно
	 * а если количество ожидающих загрузок превышает указанный максимум, ставит их в очередь
	 * и ждет освобождения загрузчиков
	 * 
	 * @author Konstantin
	 */
	public class ImageDownloader extends EventDispatcher {
 
 
		private static var _instance:	ImageDownloader = null;
		private static const MAX_OPEN_STREAMS:	int 	= 15;
 
		// название подпапки в которую будут сохраняться картинки
		private var _folderName:String	= "All";
		private var _loaders:	Array	= [];
		private var _buffer:	Array	= []; 
		private var _rewriteExisting:Boolean = false;
		// если директорию не задать, то по умолчанию используется desktopDirectory
		private var _directory:	File	= File.desktopDirectory; 
		private var _downloaded:int 	= 0;
 
 
		public function ImageDownloader() {
			if (_instance) throw new Error("Singlton!");
			_instance 	= this;
			for (var i:int = 0; i < MAX_OPEN_STREAMS; i++) {
				var loader:ExtendedURLLoader = new ExtendedURLLoader();
				loader.addEventListener(ExtendedURLLoader.LOADER_READY, onLoaderReady);
				loader.addEventListener(Event.COMPLETE, onLoaderComplete);
				loader.folderName 	= folderName;
				loader.directory 	= directory;
				_loaders.push(loader);
			}
		}
 
		private function onLoaderComplete(e:Event):void {
			_downloaded++;
			//trace(getLoadedPercent());
		}
		public function getNumEnqueued():int {
			return _buffer.length || 1;
		}
		public function getNumDownloaded():int {
			return _downloaded || 1;
		}
		/// возвращает процент загруженных картинок к проценту ожидающих в буфере
		public function getLoadedPercent():int {
			return int(getNumDownloaded() / getNumEnqueued()) * 100;
		}
 
		private function onLoaderReady(e:Event):void {
			if (_buffer.length) {
				var data:Object = _buffer.pop();
				load(data.imageURL, data.imageNameToSave);
			}
 
		}
		public function load(imageURL:String, imageNameToSave:String):void {
 
			if (!rewriteExisting) {
				var file:File = directory.resolvePath(folderName + File.separator + imageNameToSave);
				if (file.exists) {
					//trace("файл существует, игнорируем");
					return;	
				}
			}
 
			var loader:ExtendedURLLoader = getReadyLoader();
			if (!loader) {
				//trace("картинка ждет в буфере");
				_buffer.push({ imageURL: imageURL, imageNameToSave: imageNameToSave });
			} else {
				loader.beginLoad(imageURL, imageNameToSave);
				//trace("картинка поставлена на загрузку");
			}
		}
		private function getReadyLoader():ExtendedURLLoader {
			for each (var loader:ExtendedURLLoader in _loaders) {
				if (loader.isReady) return loader;
			}
			return null;
		}
		public function reset():void {
			for each (var loader:ExtendedURLLoader in _loaders) {
				loader.reset();
			}
			_downloaded		= 0;
			_folderName 	= null;
			_directory		= null;
			_buffer.length 	= 0;
		}
 
		static public function get instance():ImageDownloader {
			return _instance || new ImageDownloader();
		}
 
		public function get folderName():String {
			if (!_folderName) _folderName = "All";
			return _folderName;
		}
 
		public function set folderName(value:String):void {
			_folderName = value;
			for each (var loader:ExtendedURLLoader in _loaders) {
				loader.folderName = value;
			}
		}
 
		public function get directory():File {
			if (!_directory) _directory = File.desktopDirectory;
			return _directory;
		}
 
		public function set directory(value:File):void {
			_directory = value;
			for each (var loader:ExtendedURLLoader in _loaders) {
				loader.directory = value;
			}
		}
 
		public function get rewriteExisting():Boolean {
			return _rewriteExisting;
		}
 
		public function set rewriteExisting(value:Boolean):void {
			_rewriteExisting = value;
		}
 
	}
 
}
import flash.events.Event;
import flash.events.IOErrorEvent;
import flash.events.ProgressEvent;
import flash.events.SecurityErrorEvent;
import flash.filesystem.File;
import flash.filesystem.FileMode;
import flash.filesystem.FileStream;
import flash.net.URLLoader;
import flash.net.URLLoaderDataFormat;
import flash.net.URLRequest;
import flash.utils.ByteArray;
import ru.serovkonstantin.plagiatorpro.utils.ByteTypes;
 
internal class ExtendedURLLoader extends URLLoader {
 
	public static const LOADER_READY:	String 	= "loaderReady";
 
 
	private var _assetURL:			String 	= null;
	private var _isReady:			Boolean	= true;
	private var _imageNameToSave:	String 	= null;
	private var _folderName:		String 	= null;
	private var _directory:			File	= null; 
 
	public function ExtendedURLLoader() {
		addEventListener(Event.COMPLETE, onComplete);
		addEventListener(SecurityErrorEvent.SECURITY_ERROR, onError);
		addEventListener(IOErrorEvent.IO_ERROR, onError);
		addEventListener(ProgressEvent.PROGRESS, onProgress);
		dataFormat = URLLoaderDataFormat.BINARY;
	}
 
	public function beginLoad(imageURL:String, imageNameToSave:String):void {
		isReady 			= false;
		_imageNameToSave 	= imageNameToSave;
		super.load(new URLRequest(imageURL));
	}
 
	override public function load(request:URLRequest):void {
		throw new Error("используй beginLoad() вместо load()");
	}
 
	private function onComplete(e:Event):void {
		if (_imageNameToSave) {
			var bytes:ByteArray = data as ByteArray;
			saveImage(bytes);
		} else {
			reset();
		}
	}
	private function saveImage(imageBytes:ByteArray):void {
		if (!imageBytes || imageBytes.length < 1) {
			reset();
			return;
		}
 
		var file:		File 		= getSaveDirectory(_imageNameToSave);
		if (!file.exists) {
			//trace(file.nativePath);
			var fileStream:	FileStream	= new FileStream();
			fileStream.open(file, FileMode.WRITE);
			fileStream.writeBytes(imageBytes, 0, imageBytes.length);
			fileStream.close();
			isReady = true;
		} else {
			reset();
		}
	}
	private function getSaveDirectory(fileName:String):File {
		return directory.resolvePath(folderName + File.separator + fileName);
 
	}
 
	private function onError(e:IOErrorEvent):void {
		reset();
	}
	override public function close():void {
		try {
			super.close();
		} catch (e:Error) {
			trace("ошибка загрузки", e.getStackTrace(), this);
		}
	}
 
	private function onProgress(e:ProgressEvent):void {
 
	}
 
	public function reset():void {
		close();
		_imageNameToSave 	= null;
		isReady 			= true;
		_directory			= null;
	}
 
	public function get isReady():Boolean {
		return _isReady;
	}
 
	public function set isReady(value:Boolean):void {
		_isReady = value;
		if (value) {
			dispatchEvent(new Event(LOADER_READY));
		}
	}
 
	public function get folderName():String {
		return _folderName;
	}
 
	public function set folderName(value:String):void {
		_folderName = value;
	}
 
	public function get directory():File {
		return _directory;
	}
 
	public function set directory(value:File):void {
		_directory = value;
	}
 
}
Использовать просто:
Код AS3:
ImageDownloader.instance.load(/*адрес картинки*/, /*название для сохранения*/);
Но это просто скачиватель картинок для AIR. Чтобы его использовать в флеере или просто для загрузки картинок в приложение, придется переписать метод load и во внутреннем классе ExtendedLoader сделать отдачу картинки. А для плеера убрать все операции с File и FileStream
__________________
Ко мне можно и нужно обращаться на ты)

Старый 05.12.2016, 22:38
ZackMercury вне форума Посмотреть профиль Отправить личное сообщение для ZackMercury Найти все сообщения от ZackMercury
  № 48  
Ответить с цитированием
ZackMercury
 
Аватар для ZackMercury

блогер
Регистрация: Jul 2013
Адрес: Север
Сообщений: 1,922
Записей в блоге: 23
Отправить сообщение для ZackMercury с помощью ICQ Отправить сообщение для ZackMercury с помощью Skype™
С локалки время загрузки не играет роли, т.к. оно стремится к нулю.
__________________
There is no thing in this world that is not simple.

Старый 06.12.2016, 06:29
caseyryan вне форума Посмотреть профиль Отправить личное сообщение для caseyryan Найти все сообщения от caseyryan
  № 49  
Ответить с цитированием
caseyryan
 
Аватар для caseyryan

Регистрация: Jun 2012
Адрес: Новосибирск
Сообщений: 6,644
Записей в блоге: 4
Цитата:
Сообщение от ZackMercury Посмотреть сообщение
С локалки время загрузки не играет роли, т.к. оно стремится к нулю.
К нулю? Ты не перестаешь удивлять своими теориями. Может поспорим?
Положи в локальную папку сотню картинок, хотя бы килобайт по 200, и загрузи их своим способом.
Даже если у тебя будет стоять SSD, такая загрузка займет секунд 7 - 10 (может даже больше), а на простом жестком диске ещё дольше. А потом загрузи все тоже самое множеством загрузчиков.
Результат тебя удивит. Не забывай, что загрузчики во флеше работают асинхронно
__________________
Ко мне можно и нужно обращаться на ты)

Старый 06.12.2016, 16:49
ZackMercury вне форума Посмотреть профиль Отправить личное сообщение для ZackMercury Найти все сообщения от ZackMercury
  № 50  
Ответить с цитированием
ZackMercury
 
Аватар для ZackMercury

блогер
Регистрация: Jul 2013
Адрес: Север
Сообщений: 1,922
Записей в блоге: 23
Отправить сообщение для ZackMercury с помощью ICQ Отправить сообщение для ZackMercury с помощью Skype™
HDD, 100 копий изображения размером 2.03 мбайт, 6 секунд для обоих случаев.

Один экземпляр загрузчика
Код AS3:
package com.zackmercury.test
{
	import flash.display.Bitmap;
	import flash.display.BitmapData;
	import flash.display.Loader;
	import flash.display.Sprite;
	import flash.events.Event;
	import flash.net.URLRequest;
	import flash.sampler.NewObjectSample;
	import flash.utils.getTimer;
 
	/**
	 * ...
	 * @author ZackMercury
	 */
	public class Main extends Sprite 
	{
		public var s:Vector.<BitmapData> = new Vector.<BitmapData>();
		private var _loader:Loader = new Loader();
		private var _images:Array = [];
		private var _current:int = 0;
		private var _previousTime:int = 0;
 
		public function Main() 
		{
			if (stage) init();
			else addEventListener(Event.ADDED_TO_STAGE, init);
		}
 
		private function init(e:Event = null):void 
		{
			removeEventListener(Event.ADDED_TO_STAGE, init);
			// entry point
 
			_previousTime = getTimer();
			for (var i:int = 0; i < 100; i ++)
				_images.push("img/p (" + (i + 1) + ").png");
			trace("adding links took " + (getTimer() - _previousTime) + "ms;");
			_loader.contentLoaderInfo.addEventListener(Event.COMPLETE, onLoad);
			_loader.load(new URLRequest(_images[_current]));
			trace("loading started");
			_previousTime = getTimer();
		}
 
		private function onLoad(e:Event = null):void
		{
			if (_current < _images.length - 1)
			{
				_current++;
				_loader.load(new URLRequest(_images[_current]));
			}
			else
			{
				trace("loading took " + (getTimer() - _previousTime) + "ms;");
				trace("done");
			}
		}
 
	}
 
}
Код:
adding links took 0ms;
loading started
loading took 6761ms;
done
попытка 2
Код:
adding links took 0ms;
loading started
loading took 5186ms;
done
Много экземпляров загрузчика:
Код AS3:
package com.zackmercury.test
{
	import flash.display.Bitmap;
	import flash.display.BitmapData;
	import flash.display.Loader;
	import flash.display.Sprite;
	import flash.events.Event;
	import flash.net.URLRequest;
	import flash.utils.getTimer;
 
	/**
	 * ...
	 * @author ZackMercury
	 */
	public class Main extends Sprite 
	{
		public var s:Vector.<BitmapData> = new Vector.<BitmapData>();
		private var _loader:Loader = new Loader();
		private var _images:Array = [];
		private var _counter:int = 0;
		private var _previousTime:int = 0;
 
		public function Main() 
		{
			if (stage) init();
			else addEventListener(Event.ADDED_TO_STAGE, init);
		}
 
		private function init(e:Event = null):void 
		{
			removeEventListener(Event.ADDED_TO_STAGE, init);
			// entry point
 
			_previousTime = getTimer();
			for (var i:int = 0; i < 100; i ++)
			{
				_loader = new Loader();
				_loader.contentLoaderInfo.addEventListener(Event.COMPLETE, onLoad);
				_loader.load(new URLRequest("img/p (" + (i + 1) + ").png"));
			}
			trace("creating loaders took " + (getTimer() - _previousTime) + "ms;");
			trace("loading started");
			_previousTime = getTimer();
		}
 
		private function onLoad(e:Event = null):void
		{
			_counter++;
			if (_counter == 100)
			{
				trace("loading took " + (getTimer() - _previousTime) + "ms;");
				trace("done");
			}
		}
 
	}
 
}
Код:
creating loaders took 25ms;
loading started
loading took 5783ms;
done
попытка 2
Код:
creating loaders took 21ms;
loading started
loading took 6104ms;
done
Заключение
Количество загрузчиков(асихнронных процессов загрузки) слабенько никак не влияет на скорость считывания с одного и того же диска.
Возможно тут дело в количестве файлов, но тут уж мне лень.
__________________
There is no thing in this world that is not simple.


Последний раз редактировалось ZackMercury; 06.12.2016 в 17:27.
Создать новую тему Ответ Часовой пояс GMT +4, время: 02:23.
Быстрый переход
  « Предыдущая тема | Следующая тема »  

Ваши права в разделе
Вы не можете создавать новые темы
Вы не можете отвечать в темах
Вы не можете прикреплять вложения
Вы не можете редактировать свои сообщения

BB коды Вкл.
Смайлы Вкл.
[IMG] код Вкл.
HTML код Выкл.


 


Часовой пояс GMT +4, время: 02:23.


Copyright © 1999-2008 Flasher.ru. All rights reserved.
Работает на vBulletin®. Copyright ©2000 - 2026, Jelsoft Enterprises Ltd. Перевод: zCarot
Администрация сайта не несёт ответственности за любую предоставленную посетителями информацию. Подробнее см. Правила.