Проблема с Event

[Akopalipsis]

Я сделал тест - подписал сто тысяч объектов, каждый на свой ентерФрейм, результат - 5 fps. А когда в цикле пробегал по этим ста тысячам - 16 fps.

Возможно я не правильно понял, так что переспрошу - отдельные enterFrame быстрее в три раза?

И как их можно сделать доступными для сборщика мусора, после удаления?

Так как они создаются у Вас локально и единственное, что их удерживает, это DOC, то после удаления из него, они будут доступны для GC.

А если я в самом классе CircleAnimation напишу, что бы он удалялся из родительского объекта после воспроизведения, будет лучше?

Лучше, чтобы родитель удалял детей, а не дети самопроизвольно руководили родителем.

[samana]

Сообщение от Akopalipsis

Возможно я не правильно понял, так что переспрошу - отдельные enterFrame быстрее в три раза?

Один ентерФрейм, с тысячей методов выполниться быстрее, чем тысяча ентерФреймов.

[Akopalipsis]

samana Спасибо!

[gloomyBrain]

Сообщение от Akopalipsis

Тогда такой вопрос - подписывая circle на ENTER_FRAME, мы передаём listener в EventDispatcher, где он помещается в массив и при каждом тике, вызываются все listeners из массива. Если сделать отдельный класс для ENTER_FRAME, то в моём понимании, это будет выглядеть так - создали экземпляр и чтобы подписаться на его тики, мы передаем в него ссылку на класс с методом, который должен вызываться каждый тик. Передав ссылку в класс ENTER_FRAME, она помещается в массив и каждый тик, этот массив перебирается циклом и вызывает нужный метод. Получается тоже самое.
По этому мне кажется, что я не понимаю, как сделать один класс с ENTER_FRAME. Где я ошибаюсь?

Событие Event.ENTER_FRAME создается FlashPlayer'ом для каждого подписчика. то есть как это работает:
- FP берет список подписчиков
- для каждого подписчика создается НОВЫЙ объект класса Event
- каждому подписчику отдается его собственный экземпляр класса Event

Если же мы сделаем так:

package {
 
	import flash.display.Shape;
	import flash.errors.IllegalOperationError;
 
 
    /**
	 * Глобальный диспатчер события flash.events.Event.ENTER_FRAME
	 * 
	 * @author gloomyBrain
	 */
	public final class EnterFrameBroadcaster extends Shape {
 
		private static var _instance:EnterFrameBroadcaster;
 
		/**
		 * Экземпляр синглтона
		 */
		public static function get instance():EnterFrameBroadcaster {
 
			if (!EnterFrameBroadcaster._instance) EnterFrameBroadcaster._instance = new EnterFrameBroadcaster();
			return _instance;
 
		}
 
		/**
		 * Для получения экземпляра используется статический акцессор EnterFrameBroadcaster.instance!
		 */
		public function EnterFrameBroadcaster() {
 
			super();
 
			if (EnterFrameBroadcaster._instance) throw new IllegalOperationError("Для получения экземпляра используется статический акцессор instance!");
 
		}
 
	}
 
}

и будем подписываться на событие Event.ENTER_FRAME от объекта EnterFrameBroadcaster.instance, то для всех подписчиков будет создаваться только один экземпляр класса Event. Таким образом можно сэкономить на созднаии объектов событий, что при большом количестве слушателей может быть актуально.

[Akopalipsis]

gloomyBrain Спасибо! Вот когда я читал форум раньше, то сложилось впечатление, что синглетон - это ВООБЩЕ не нужный паттерн. А вот чем больше я углубляюсь в архитектуру,
тем больше понимаю его полезность. И не важно, как его реализовать, главное, что это будет всегда один и тот же экземпляр.

[gloomyBrain]

Ну на самом деле тут синглтон необязателен, все можно сделать через статические методы подписки/отписки.
Я вообще не знаю, где синглтон обязателен или хотя бы чуть более полезен чем какой-то другой вариант статического доступа =)

[LIGHTHILL]

Такой вариант лучше? Здесь, как я понимаю ENTER_FRAME только один.
Единственное для упрощения, на каждом новом кадре я проверяю только самый первый объект из массива, а не перебираю весь массив, т.к. вряд ли кто-то сможет дважды кликнуть мышкой за один кадр, при 60fps.
Является ли такое упрощение нормальным при разработке полноценного приложения?

package 
{
	import flash.display.MovieClip;
	import flash.events.Event;
	import flash.events.MouseEvent;
 
	public class Main extends MovieClip 
	{
		private var circle: Array = new Array();;
		private var new_circle: CircleAnimation;
 
		public function Main():void 
		{
			if (stage) init();
			else addEventListener(Event.ADDED_TO_STAGE, init);
		}
 
		private function init(e:Event = null):void 
		{
			removeEventListener(Event.ADDED_TO_STAGE, init);
 
			stage.addEventListener(MouseEvent.CLICK, onClick);
			addEventListener(Event.ENTER_FRAME, onEnter);
		}
 
		private function onClick(e:MouseEvent): void
		{
			new_circle = new CircleAnimation();
			circle.push(new_circle);
			addChild(circle[circle.length - 1]);
			circle[circle.length - 1].x = mouseX;
			circle[circle.length - 1].y = mouseY;
		}
 
		private function onEnter(e:Event): void
		{
			if (circle[0] != null)												// проверка, есть ли ещё объекты в массиве
			{
				if (circle[0].currentFrame == circle[0].totalFrames)
				{
					removeChild(circle[0]);
					circle.splice(0, 1);										// удаление из массива самого "старого" объекта из массива, который полностью воспроизвёлся
				}
			}
		} 
 
 
	}
 
}

И ещё вопрос: есть ли какая-нибудь функция для определения того, что MovieClip полностью воспроизвёлся, что бы не сравнивать текущий кадр с количеством кадров.
А ещё лучше ивент, срабатывающий при достижении последнего кадра.