как нарисовать безье на EnterFrame

[silin]

сдается мне, что Безье не при делах здесь, а нужны только какие-то правила 'кривляния' кривой и модификации их у дочерних элементов
вот поиграйся: фрактал - не фрактал, но что-то вроде

package
{
	import flash.display.Sprite;
 
	public class Main extends Sprite
	{
 
		public function Main():void
		{
			var swirl:Swirl = new Swirl();
			swirl.x = 100;
			swirl.y = 300;
			addChild(swirl);
 
		}
	}
 
}
import flash.display.Sprite;
import flash.events.TimerEvent;
import flash.utils.Timer;
 
class Swirl extends Sprite
{
	public var step:Number = 5;
	public var dir:Number = 0;
	public var deviation:Number = 0.1;
	public var thickNess:Number = 16;
	public var fidgety:Number = 1;
	public var fertility:Number = 8;
	public var damp:Number = 0.98;
 
	private var tX:Number = 0;
	private var tY:Number = 0;
	private var timer:Timer;
 
	public var length:int = 0;
 
	public function Swirl()
	{
 
		timer = new Timer(100);
		timer.addEventListener(TimerEvent.TIMER, timer_timer);
		timer.start();
	}
 
	private function timer_timer(e:TimerEvent):void
	{
		length++;
		dir += deviation;
		if (Math.random() < fidgety)
		{
			deviation *= -1;
		}
 
		tX += step * Math.cos(dir);
		tY += step * Math.sin(dir);
 
		thickNess *= damp;
 
		graphics.lineStyle(thickNess);
		graphics.lineTo(tX, tY);
 
		// какой-то критерий порождения детей
		var tLen:int = fertility * (1 + Math.random());
		if (length && length % tLen == 0)
		{
			var swirl:Swirl = new Swirl();
			swirl.x = tX;
			swirl.y = tY;
			// какие-то правила наследования свойств
			swirl.thickNess = thickNess;
			swirl.fidgety = 0.65 * fidgety;
			swirl.fertility = 1.25 * fertility;
			swirl.deviation = 1.25 * deviation;
			swirl.dir = dir;
			addChild(swirl);
		}
 
		// какой-то критерий 'умирания'
		if (length > 50 || thickNess < 1)
		{
			timer.stop();
			timer.removeEventListener(TimerEvent.TIMER, timer_timer);
		}
 
	}
 
}