For each и MovieClip

[LEXiy]

Здравствуйте.
Не могу понять, почему у меня не работает for each
В AS2 for in быстро пробегался по всем свойствам и объектам любого мувика, а здесь что-то молчит.
Допустим, что есть клип в котором лежит еще два, но при вызове из класса первого клипа например такого кода:

for each (var item in this) { 
      trace(item); 
}

Он молчит, как будто он пустой... В чем дело?
Мастера и мастерицы, помогите плиз.

[etc]

Потому что это классы, у них свойства закрыты от перечисления. Если очень надо, есть describeType.

[silin]

The for each..in statement iterates only through the dynamic properties of an object, not the fixed properties

т.е. свойства, определенные как часть класса (твоя ситуация) не будут перечисляться, а динамически добавленные свойства будут

var myMc:MovieClip = new MovieClip();
myMc.child = new Sprite();
myMc.prop = "someProperty";
for each(var item:Object in myMc) {
	trace( "item : " + item );
}
//item : someProperty
//item : [object Sprite]

[LEXiy]

Спасибо за ответы.

myMc.child = new Sprite();

А так тоже можно клипы добавлять?

У меня не показываются клипы созданные addChild()
Ситуация такая: в одном клипе есть мувик win1, в который он добавляет другие клипы. Вот код первого мувика:

public function change(s:String, ...args):void {
...
   var ClassReference:Class = getDefinitionByName("main."+s) as Class;
   newobj = new ClassReference();
   win1.addChild(MovieClip(newobj));
...
}

Код добавляемого клипа:

package main{
	import flash.display.MovieClip;
	import flash.display.Sprite;
	import flash.events.Event;
	import flash.utils.describeType;
	import main.*;
	
	dynamic public class MenuScreen extends MovieClip {
		
		public function MenuScreen() {
			this.addEventListener(Event.ADDED_TO_STAGE, onAdded);
		}
		
		private function onAdded(e:Event):void{
			trace("Hello! I am "+this.name);
			trace("My parent is "+this.parent.name);
			
			for each (var item:Object in this.parent) { 
    			trace(item); 
			} 
		}
	}
}

И результат:

Hello! I am MenuScreen
My parent is win1

...и все!
Может быть есть другие способы, чтобы пробежаться по всем созданным обьектам (кроме describeType)?

[silin]

путаница в том, что клипы (любые дисплейОбжекты) добавленные в дисплей лист (addChild) не обязательно являются свойствами класса..
а for each перечисляет именно свойства( и то не все, а только динамически добавленные)
что бы посмотреть дисплейЛист см. numChildren/getChildAt/getChildByName
или, если так нужен for each, оставляй ссылку на мувик в родителе

public function change(s:String, ...args):void {
...
   var ClassReference:Class = getDefinitionByName("main."+s) as Class;
   win1.newobj = new ClassReference();
   win1.addChild(MovieClip(win1.newobj));
...
}

[LEXiy]

Спасибо вери мач!!!
Теперь все стало понятнее. Я правда решил вообще без этого обойтись... но тем не менее для общего развития полезно было