Запись узла со множеством свойств в XML

[HorusWM]

Возможно ли записать в XML строку в виде <label name="name" x="0" y="0" /> и как это сделать? Пробовал через XMLList задавать свойства на ходу в виде list.label.@x = object.x, но получаю ошибку, что такой способ не поддерживается.

[wvxvw]

Ну только в цикле, по-другому никак. Вы же хотите, если я правильно понял нескольким узлам назначить новый атрибут?

[HorusWM]

в общем, в конечном итоге я хочу получить вот такую структуру

<world>
    <triggers>
        <pathpoint id="1" x="1600" y="1714" />
        <pathpoint id="2" x="1614" y="1728" />
    </triggers>
</world>

[Wolsh]

var xml:XML =  <world><triggers/></world>;
var node1:XML = <pathpoint id="1" x="1600" y="1714" />;
var node2:XML = <pathpoint id="2" x="1614" y="1728" />;
xml.triggers[0].appendChild(node1);
xml.triggers[0].appendChild(node2);
 
trace(xml.toXMLString());

Добавлено через 7 минут
Ну или по кускам собрать, быстрее будет без е4х поиска (возможно)

var xml:XML =  <world/>;
var triggersNode:XML = <triggers/>;
var node1:XML = <pathpoint id="1" x="1600" y="1714" />;
var node2:XML = <pathpoint id="2" x="1614" y="1728" />;
triggersNode.appendChild(node1);
triggersNode.appendChild(node2);
xml.appendChild(triggersNode);
trace(xml.toXMLString());

Добавлено через 16 минут
атрибуты можно добавлять, была бы ссылка на ноду XML (не XMLList!)

var xml:XML =  <world><triggers/></world>;
var node1:XML = <pathpoint id="1" x="1600" y="1714" />;
var node2:XML = <pathpoint/>;
xml.triggers.appendChild(node1);
xml.triggers.appendChild(node2);
// немного магии: XML хранит ссылку на ноды, а не просто значение:
node2.@id = "2";
node2.@x = "1614";
node2.@y = "1728";
trace(xml.toXMLString());

Добавлено через 31 минуту
заполнение переменными в цикле можно делать так:

var triggers:Array = [new Point(1600, 1714), new Point(1614, 1728), new Point(1628, 1742), new Point(1642, 1756)];
var xml:XML =  <world/>;
var triggersNode:XML = <triggers/>;
for (var i:uint = 0; i < triggers.length; i++)
{
	var node:XML = <pathpoint id={i+1} x={triggers[i].x} y={triggers[i].y} />;
	triggersNode.appendChild(node);
}
xml.appendChild(triggersNode);
trace(xml.toXMLString());

[HorusWM]

да, у меня в цикле пробрасывается массив объектов. Благодарю!