проблема скролинга с помощью колеса

[palsany4]

после нескольких прокрутов ползунок (scrol_mc) начинает безумствовать, шаг получается уже не 9 а гораздо больше. Сперва всю полосу можно было за 17 движение колеса, потом стает за 7, потом вообще за 3... В чем ошибка, не понимаю...
спасибо.

var mouseListener:Object = new Object();
mouseListener.onMouseWheel = function (wheel) { 
	if (wheel < 0) {
		if (scrol_mc._y <= 576) {
			scrol_mc._y = scrol_mc._y + 9;}
}
 
	else {		
		if (scrol_mc._y >= 9) {
			scrol_mc._y = scrol_mc._y - 9;}
	}
};
Mouse.addListener(mouseListener);
if (scrol_mc._y > 576) { scrol_mc._y = 576};
if (scrol_mc._y < 9) { scrol_mc._y = 9};

[udaaff]

Проверил ваш код. Никакого безумства не заметил. Единственное что, упростил бы слегка:

var speed:Number = 3;
var minY:Number = 9;
var maxY:Number = 576;
 
Mouse.addListener(this);
scroll_mc._y = truncate(minY, maxY, scrol_mc._y);
 
function onMouseWheel(delta):Void
{
	scroll_mc._y = truncate(minY, maxY, scroll_mc._y + speed * delta);
}
 
function truncate(min:Number, max:Number, n:Number):Number
{
	return Math.max(min, Math.min(max, n));
}

[iNils]

Я так подозреваю, что вы пишите на таймлайне и в кадр с кодом заходите несколько раз, тогда каждый заход подписывает вас еще раз на событие от колесика мыши. И на одно движение приходится несколько вызовов обработчика события.

var step:Number = 9;
var topLimit:Number = 9;
var bottomLimit:Number = 576;
this.onMouseWheel = function (wheel:Number) {
	trace ("q")
	if (wheel < 0) {
		if (scrol_mc._y < bottomLimit) {
			scrol_mc._y += step;
		} else if (scrol_mc._y > bottomLimit) {
			scrol_mc._y = bottomLimit
		}
	} else {
		if (scrol_mc._y > topLimit) {
			scrol_mc._y -= step;
		} else if (scrol_mc._y < topLimit) {
			scrol_mc._y = topLimit
		}
	}
};
Mouse.addListener (this);

[palsany4]

to udaaff, код красивый, но не работает
to iNils, stop (); в начале кода - проблема решена. Спасибо!

[udaaff]

palsany4, scroll потому что с двумя l, потому и не работает.

[palsany4]

действительно, не заметил. Все класс! Какой проницательный контингент форума, чудо!