Не могу достать имя(глупая ошибка)

[DEN123]

import fl.controls.Label;
 
///Load XML
var myXMLLoader:URLLoader = new URLLoader();
myXMLLoader.load(new URLRequest("1.xml"));
myXMLLoader.addEventListener(Event.COMPLETE, processXML);
 
var myXML:XML;
function processXML (e:Event):void
{
	myXML = new XML(e.target.data);
	createLabel();
} 
 
var myLabel:Label;
 
function createLabel()
{
	var object:XMLList = myXML.TEST;
	for (var t:int=0; t<object.length(); t++) 
	{
		myLabel = new Label();
		myLabel.move(10,t*20);
		myLabel.htmlText = "<u>"+object[t].@title+"</u>";
		myLabel.name = object[t].@title;
		myLabel.addEventListener(MouseEvent.CLICK, moveTo);
		addChild(myLabel);
	}
}
 
function moveTo(e:MouseEvent):void 
{
	var mylab:Label = e.target as Label;
	trace(mylab);
}

mylab - должно быть имя того объекта который я нажал.

[dimarik]

trace(mylab.name);

[DEN123]

TypeError: Error #1009: Cannot access a property or method of a null object reference.
	at test_fla::MainTimeline/moveTo()

проверял уже ,вот такая ошибка

[dimarik]

сорри, сразу не заметил:

function moveTo(event:MouseEvent):void {
	var mylab:Label = event.currentTarget as Label;
	trace(mylab.name);
}

[DEN123]

эм можешь объяснить почему так? просто у меня тот код в другом месте работал

и сразу.
хотел сделать массив ХМЛ.
а меня обругали

var myXML:Array;
function processXML (e:Event):void
{
	myXML[0]:XML = new XML(e.target.data);
	createLabel();
}

и вообще мне кажется я не верно делаю, мне надо что бы если ХМЛ один раз загрузился то он остался.

[dimarik]

Судя по Вашему количеству вопросов на откровенно "нубские" темы, Вы не удосужились почитать ни одного авторитетного источника для начинающих программировать в AS3. Вот мой ответ.

Это упрек только в пользу того, что потерять время на обсуждения на форуме можно гораздо больше, чем занимаясь самообразованием. Следующий Ваш вопрос должен звучать так: "Где я могу прочитать о E4X реализации для AS3, желательно на русском языке?".

[DEN123]

эхх ты прав.

[dimarik]

Сообщение от DEN123

эм можешь объяснить почему так? просто у меня тот код в другом месте работал

разница в event.target и event.currentTarget. разницу легко определить и запомнить.
Слушай сюда. target - это тот, кто инициировал событие. currentTarget - кто событие явно отдиспатчил.
На примере.
Есть

var sprite:Sprite = new Sprite();
super.addChild(sprite);
var shape:Shape = new Shape();
sprite.addChild(shape);
sprite.addEventListener(MouseEvent.CLICK, this.handler_click);
 
function handler_click(event:Event):void {
   trace(event.target);
   trace(event.currentTarget);
}

Так вот, если ты кликнешь на sprite - то он явно задиспатчит событие MouseEvent.CLICK потомучто мы специально на него и подписали спрайт. а значит, что

trace(event.target); // sprite
trace(event.currentTarget); // sprite

А теперь кликни на его дитё (shape):

trace(event.target); // shape
trace(event.currentTarget); // sprite

Потому что события всплывающие к родителю.

Т. о. в event.currentTarget всегда падает тот, кто явно диспатчит событие (на кого подписали), а в event.target попадает тот, на ком кликнули (кто вызвал событие).

Добавлено через 9 минут
Мой совет, не пожалей денег и времени на покупку этой книги Колина Мука. Он очень хорошо объясняет и достаточно хоршо переведен на русский. Дима Гурский там там был "заведующий редакцией". Поэтому и "достаточно" хорошо. Если бы Нокс - то было бы "прелесть".

[DEN123]

Спасибо огромное.
Книга уже лежит.
Времени просто сейчас нету, вот если появляется время сразу лезу в реализацию идеи без теории.

[dimarik]

В книге Мука популярно описаны E4X, namespaces и Event.RENDER. Меня очень просвятило. Правда, вынужден был просто ознакомиться с этими разделами, т. к. прикладных задач на тот час для применения этих технологий не было. Но сейчас периодически обращаюсь, чтобы вспомнить про этот "E4X" и подумать о применении неймспейсов в своих проектах (пока обхожусь нативными).