как корректно обратится к методу parent?

[mikhailk]

package  
{
	import flash.display.*;
	import flash.events.*;
 
	public class MyObject extends Sprite
	{
		public static const CHANGE_PARENT:String = "changeParent";
 
		public var param1:int;
		public var param2:int;
 
		public function MyObject() 
		{
 
		}
 
		public function sendEventToParent() : void
		{
			// задаем параметры, которые потом считаем из парента
			param1 = 1;
			param2 = 2;
 
			// сообщаем паренту, что ему нужно считать параметры в объекте
			dispatchEvent(new Event(CHANGE_PARENT));
		}
 
	}
 
}

Добавлено через 4 минуты
Парент:

package 
{
	import flash.display.Sprite;
	import flash.events.Event;
 
	public class Main extends Sprite 
	{
		public function Main():void 
		{
			if (stage) init();
			else addEventListener(Event.ADDED_TO_STAGE, init);
		}
 
		private function init(e:Event = null):void 
		{
			removeEventListener(Event.ADDED_TO_STAGE, init);
			// entry point
 
			var myObject:MyObject = new MyObject();
			addChild(myObject);
			myObject.addEventListener(MyObject.CHANGE_PARENT, onChangeParent);
			myObject.sendEventToParent();
 
		}
 
		private function onChangeParent(e:Event) : void
		{
			var myObject:MyObject = e.target as MyObject;
			trace(myObject.param1,myObject.param2);
		}
 
	}
 
}