Форум Flasher.ru
Ближайшие курсы в Школе RealTime
Список интенсивных курсов: [см.]  
  
Специальные предложения: [см.]  
  
 
Блоги Правила Справка Пользователи Календарь Сообщения за день
 

Вернуться   Форум Flasher.ru > Flash > ActionScript 3.0

Версия для печати  Отправить по электронной почте    « Предыдущая тема | Следующая тема »  
Опции темы Опции просмотра
 
Создать новую тему Ответ
Старый 01.02.2011, 16:13
gloomyBrain вне форума Посмотреть профиль Отправить личное сообщение для gloomyBrain Найти все сообщения от gloomyBrain
  № 11  
Ответить с цитированием
gloomyBrain
 
Аватар для gloomyBrain

блогер
Регистрация: Mar 2008
Адрес: РФ, Санкт-Петербург
Сообщений: 2,272
Записей в блоге: 5
Отправить сообщение для gloomyBrain с помощью ICQ Отправить сообщение для gloomyBrain с помощью Skype™
А это зависит от MTU
от 576 до 1500 байт
__________________
...вселенская грусть

Старый 01.02.2011, 16:26
avilov вне форума Посмотреть профиль Отправить личное сообщение для avilov Найти все сообщения от avilov
  № 12  
Ответить с цитированием
avilov
[+1 31.01.11]

Регистрация: Jun 2008
Сообщений: 91
Код AS3:
Socket.writeBytes();
Засовываете любой обьем данных , он сам раскидает его на пакеты , и он будет считаться как один пакет , правда передаваться будет кусками это уже ТСР его сам разделит на нужные куски , на сервере данные будут доступны когда все пакеты будут переданы.

Старый 01.02.2011, 16:51
gloomyBrain вне форума Посмотреть профиль Отправить личное сообщение для gloomyBrain Найти все сообщения от gloomyBrain
  № 13  
Ответить с цитированием
gloomyBrain
 
Аватар для gloomyBrain

блогер
Регистрация: Mar 2008
Адрес: РФ, Санкт-Петербург
Сообщений: 2,272
Записей в блоге: 5
Отправить сообщение для gloomyBrain с помощью ICQ Отправить сообщение для gloomyBrain с помощью Skype™
В данном аспекте все зависит от сервера. По идее - да. На практике - не всегда
__________________
...вселенская грусть

Старый 01.02.2011, 17:00
avilov вне форума Посмотреть профиль Отправить личное сообщение для avilov Найти все сообщения от avilov
  № 14  
Ответить с цитированием
avilov
[+1 31.01.11]

Регистрация: Jun 2008
Сообщений: 91
главное что б когда в Socket.writeBytes(); передаются байты , не было там нулевого байта , тогда они придут все за раз придут

Старый 01.02.2011, 17:17
ChuwY вне форума Посмотреть профиль Отправить личное сообщение для ChuwY Посетить домашнюю страницу ChuwY Найти все сообщения от ChuwY
  № 15  
Ответить с цитированием
ChuwY
 
Аватар для ChuwY

Регистрация: Nov 2009
Адрес: Тула / Москва
Сообщений: 734
Отправить сообщение для ChuwY с помощью ICQ Отправить сообщение для ChuwY с помощью Skype™
Не все. Сказали же выше.

А вообще посмотрите вот эту тему

Старый 02.02.2011, 00:53
etc вне форума Посмотреть профиль Найти все сообщения от etc
  № 16  
Ответить с цитированием
etc
Et cetera
 
Аватар для etc

Регистрация: Sep 2002
Сообщений: 30,787
Вписываем длину пакета. Если пришло меньше, ждем ещё кусок. Всё.

Старый 02.02.2011, 01:07
Psycho Tiger вне форума Посмотреть профиль Отправить личное сообщение для Psycho Tiger Найти все сообщения от Psycho Tiger
  № 17  
Ответить с цитированием
Psycho Tiger
 
Аватар для Psycho Tiger

блогер
Регистрация: Jun 2005
Адрес: Toronto
Сообщений: 6,601
Записей в блоге: 17
Цитата:
Сообщение от XBEEN Посмотреть сообщение
Спасибо, принцип понял. А пример нужен для большей ясности...
Отдуши.
Код AS3:
package artshlagin.network 
{
	import flash.events.DataEvent;
	import flash.events.Event;
	import flash.events.IOErrorEvent;
	import flash.events.ProgressEvent;
	import flash.events.SampleDataEvent;
	import flash.events.SecurityErrorEvent;
	import flash.net.Socket;
	import flash.utils.ByteArray;
 
	/**
	 * ...
	 * @author Artem Shlagin
	 */
 
	[Event(name = "sampleData", type = "flash.events.SampleDataEvent")]
 
	public class BinarySocket extends Socket
	{
		/**
		 * Два байта выделять под заголовок (true) или один (false)
		 */
		public static var HEADER_BYTES_DOUBLE:Boolean = true;
 
		/**
		 * Два байта выделять под заголовок (true) или один (false)
		 */
		public static var MESSAGE_LENGTH_DOUBLE:Boolean = true;
 
 
		private var _responseByteArray:ByteArray;
		private var _messageLength:uint;
 
		/**
		 * Класс для обмена бинарными данными с сокет-сервером
		 * @param	host
		 * @param	port
		 */
		public function BinarySocket(host:String = null, port:int = 0) 
		{
			super(host, port);
			super.addEventListener(Event.CONNECT, onConnect);
 
			_messageLength = 0;
			_responseByteArray = new ByteArray();
		}
 
		public function send(packet:uint, message:ByteArray = null):void {
			HEADER_BYTES_DOUBLE ? super.writeShort(packet) : super.writeByte(packet);
			if (message) {
				var l:uint = message.length;
				MESSAGE_LENGTH_DOUBLE ? super.writeShort(l) : super.writeByte(l);
				super.writeBytes(message);
			}
			else MESSAGE_LENGTH_DOUBLE ? super.writeShort(0) : super.writeByte(0);
			super.flush();
		}
		private function onConnect(event:Event):void 
		{
			super.addEventListener(ProgressEvent.SOCKET_DATA, onSocketData);
		}
 
		protected function onSocketData(event:ProgressEvent):void 
		{
			var ba:uint;
			var headerBytes:uint = HEADER_BYTES_DOUBLE ? 2 : 1;
			var messageBytes:uint = MESSAGE_LENGTH_DOUBLE ? 2 : 1;
			do {
 
				ba = super.bytesAvailable;
				if (_messageLength > 0) { //reading message
					if (ba >= _messageLength) {
						super.readBytes(_responseByteArray, headerBytes, _messageLength);
						flushToClient();
					}
					else return; //reading only a full message, or wait
				}
				else{
					if (_responseByteArray.length >= headerBytes) { //header passed
						if (ba >= messageBytes) { //reading message length if can
							_messageLength = MESSAGE_LENGTH_DOUBLE ? super.readUnsignedShort() : super.readUnsignedByte();
							if (!_messageLength) flushToClient(); //if no message
						}
						else return; // or waiting to load full length
					}
 
					else { // if header is not passed - reading
						if (ba >= headerBytes) { //reading header if can
							super.readBytes(_responseByteArray, 0, headerBytes);
						}
						else return; //or waiting to load full header
					}
				}
 
			}
 
			while (super.bytesAvailable); //NOT ba, мы считывали байты после калькуляции ba
 
		}
 
		/**
		 * Отправляет данные клиенту
		 */
		protected function flushToClient():void {
			_messageLength = 0;
			var event:SampleDataEvent = new SampleDataEvent(SampleDataEvent.SAMPLE_DATA);
			_responseByteArray.position = 0;
			event.data = _responseByteArray;
			_responseByteArray = new ByteArray();
			super.dispatchEvent(event);
 
		}
 
	}
 
}

Создать новую тему Ответ Часовой пояс GMT +4, время: 07:29.
Быстрый переход
  « Предыдущая тема | Следующая тема »  

Ваши права в разделе
Вы не можете создавать новые темы
Вы не можете отвечать в темах
Вы не можете прикреплять вложения
Вы не можете редактировать свои сообщения

BB коды Вкл.
Смайлы Вкл.
[IMG] код Вкл.
HTML код Выкл.


 


Часовой пояс GMT +4, время: 07:29.


Copyright © 1999-2008 Flasher.ru. All rights reserved.
Работает на vBulletin®. Copyright ©2000 - 2026, Jelsoft Enterprises Ltd. Перевод: zCarot
Администрация сайта не несёт ответственности за любую предоставленную посетителями информацию. Подробнее см. Правила.