Фиксированная колонка в DataGrid.

[Tr1te]

В DataGrid много колонок, все в экран не помещаются, для этого внизу есть ползунок. Как мне сделать так чтобы когда я двигаю ползунок то первая колонка была статичной, не двигалась, а все остальные колонки перелистывались?

[mayakwd]

стандартными средствами никак. только извращаясь с двумя датагридами и дополнительным контейнером
ну или пилить датагрид )

[Tr1te]

А когда один Datagrid будет смещаться по вертикали скролом или по нажатию. Как мне ловить это и изменять в другом Datagrid.

[mayakwd]

скролы просто ставите в контейнере, а не в датагриде, и при скролле смещаете оба по вертикали.

[Tr1te]

Так UIScrollBar подключается только к TextField'у.
А какие события отвечают за нажатие кнопки вниз/вверх, для UIScrollBar.

[mayakwd]

UIScrollBar можно подключить к чему угодно.

@see ScrollEvent, UIScrollBar, ScrollPane

Вот вам наглядный пример без ScrollPane:

package {
	import fl.events.ScrollEvent;
	import fl.controls.UIScrollBar;
 
	import flash.display.Shape;
	import flash.display.Sprite;
	import flash.geom.Rectangle;
 
	/**
	 * @author Ilya Malanin (designer@pastila.org)
	 */
	public class Test extends Sprite {
		public static const ITEMS_COUNT : uint = 5;
 
		private var scroll : UIScrollBar;
		private var container : Sprite; 
 
		public function Test() {
			container = new Sprite();
			container.scrollRect = new Rectangle(0, 0, 100, 300);
			container.x = 20;
			container.y = 20;
			addChild(container);
 
			var i : uint = ITEMS_COUNT;
			var maxY : Number = 0;
			while (i--) {
				var shape : Shape = new Shape();
				with (shape.graphics) {
					beginFill(Math.random() * uint.MAX_VALUE, 1);
					drawRect(0, 0, 100, 100);
					endFill();
				}
				shape.y = maxY;
				container.addChild(shape);
 
				maxY += shape.height;
			}
 
			scroll = new UIScrollBar();
			scroll.addEventListener(ScrollEvent.SCROLL, scrollEventHandler);
			scroll.maxScrollPosition = Math.max(maxY - 300, 0); // = container.contentHeight - container.height;
			scroll.setSize(16, 300);
			scroll.x = container.x + 100;
			scroll.y = container.y;
			addChild(scroll); 
		}
 
		private function scrollEventHandler(event : ScrollEvent) : void {
			setContainerScrollPosition(event.position);
		}
 
		private function setContainerScrollPosition(position : Number) : void {
			var rect : Rectangle = container.scrollRect;
			rect.y = position;
			container.scrollRect = rect; 
		}
	}
}