web-camera->server

[igogor]

Кажись вот так.

package {
	import flash.display.Sprite;
	import flash.net.NetConnection;
	import flash.net.NetStream;
	import flash.events.NetStatusEvent;
	import flash.media.Camera;
	import flash.media.Video;
 
	public class FMS extends Sprite {
		private var nc:NetConnection;
		private var ns:NetStream;
		private var cam:Camera;
		private var vid:Video;
 
		public function FMS() {
			// подключаемся к камере
			cam = Camera.getCamera();
			cam.setMode(320, 240, 21);
			// показуем на екране 
			vid = new Video(cam.width, cam.height);
			vid.x = 10; vid.y = 25;
			vid.attachCamera(cam);
			addChild(vid);
			// создаем подключение к серверу
			nc = new NetConnection();
			nc.connect("rtmp://localhost/YOU_FOLDER_NAME"); // создай папку на сервере
			nc.addEventListener(NetStatusEvent.NET_STATUS, connect);
		}
 
		private function connect(e:NetStatusEvent):void {
			switch (e.info.code) {
				case "NetConnection.Connect.Success" :
					trace("Попытка подключения удалась");
					ns = new NetStream(nc);
					ns.attachCamera(cam);
					//записываем видео(YouVideoFileName - имя файла без разширения)
					ns.publish("YouVideoFileName", "record"); 
					break;
				case ("NetConnection.Connect.Failed" || "NetConnection.Connect.Rejected") :
					trace("Попытка подключения не удалась");
					break;
			}
		}
	}
}