Fade in fade out

[vsovinflash]

Здравствуйте коолеги как сделать мязгие переходы через альфу и паузу между ними
мой код такой:

_root.createEmptyMovieClip("slideShow_mc",1);
setProperty("slideShow_mc", _x, "0");
imageArray = new Array("images/image1.jpg", "images/image2.jpg", "images/image3.jpg", "images/image4.jpg", "images/image5.jpg");
randNum = random(5);
slideShow_mc.loadMovie(imageArray[randNum]);

[Reijii]

а где тут альфа ?

ps. и где тег " [code] "

[vsovinflash]

альфу я не знаю как сделать вот и спрашиваю уважаемых профессоров

[Reijii]

вот, набросал на скорую руку, в начале было лень, но подумал может в будующем вопросов не будет подобных .

альфа по сути тут

mx.transitions.TransitionManager.start(target, {type:mx.transitions.Fade, direction:0, duration:.3, easing:mx.transitions.easing.Regular.easeOut});

//  duration:.3 - скорость в секундах провки
//  direction:0 - направление проявки ( 0 или 1)
//  easing:mx.transitions.easing.Regular.easeOut - вид проявки, 
//  все подробности в help

stop();
var slideShowContainer:MovieClip = _root.createEmptyMovieClip("slideShow_mc", 1);
//
var loader:MovieClipLoader = new MovieClipLoader();
var loaderListener:Object = new Object();
var imageArray:Array = new Array("images/image1.jpg", "images/image2.jpg", "images/image3.jpg");
var numImages:Number = imageArray.length;
var current:Number = random(numImages);
var prev:Number = current;
var interval:Number;
//
loader.addListener(loaderListener);
//
StartShow();
function StartShow():Void
{
	if (imageArray[current] && current != prev)
	{
		LoadImage(current);
		current = random(numImages);
	}
	else
	{
		current = random(numImages);
		StartShow();
	}
}
//
function LoadImage($num:Number):Void
{
	loader.loadClip(imageArray[$num], slideShowContainer);
	prev = $num;
	clearInterval(interval);
	//
}
loaderListener.onLoadComplete = function(target:MovieClip, httpStatus:Number):Void 
{
	interval = setInterval(StartShow, 2000);
};
//
loaderListener.onLoadProgress = function(target:MovieClip, bytesLoaded:Number, bytesTotal:Number):Void 
{
	if (Math.floor(bytesLoaded / 1024) == Math.floor(bytesTotal / 1024))
	{
		mx.transitions.TransitionManager.start(target, {type:mx.transitions.Fade, direction:0, duration:.3, easing:mx.transitions.easing.Regular.easeOut});
	}
};
//
loaderListener.onLoadError = function(target:MovieClip, errorCode:String):Void 
{
	clearInterval(interval);
	current = random(numImages);
	StartShow();
};

[etc]

Reijii, зачем ты используешь типизацию там, где от неё никакого смысла нет? Я бы сказал, даже вред.

[Nirth]

Reijii, зачем ты используешь типизацию там, где от неё никакого смысла нет? Я бы сказал, даже вред.

лично я пишу код в FlexDevelop/Sepy, там с типизацией легко, и авто комплит удобный=)

[Reijii]

Сообщение от __etc

Reijii, зачем ты используешь типизацию там, где от неё никакого смысла нет? Я бы сказал, даже вред.

а чем вред ?. подскажи в чем не прав, плиз.
пишу по привычке, в классах так пишу все параметры и переменные,
да и глазу легче понять что за зверь..


2 Nirth: я тоже FlashDevelop, правда сейчас перехожу в новых проектах на Eclipse + FDT.

[vsovinflash]

Огромное спасибо - буду разбираться респектище

[etc]

Сообщение от Reijii

а чем вред ?. подскажи в чем не прав, плиз.
пишу по привычке, в классах так пишу все параметры и переменные,
да и глазу легче понять что за зверь.

Для AS1 чужда подобная типизация. Если тебе потребуется скомпилировать такой проект под 6-ой плеер, то он ругнётся на каждую строку с типизацией.

[Reijii]

Сообщение от __etc

Для AS1 чужда подобная типизация. Если тебе потребуется скомпилировать такой проект под 6-ой плеер, то он ругнётся на каждую строку с типизацией.

ок спасибо за информацию, обязательно учту.
просто не разрабатывал никогда под 6