[AS2] Как прописать OnEnterFrame?

[Gaen]

Внешний класс:

class MyClass{

	function MyClass(){
		this.onEnterFrame=function(){;	};
	}

}

Выдаёт: There is no property with the name 'onEnterFrame'.

...как сделать правильно?

[Antares]

Перевожу: нет члена класса с именем OnEnterFrame

Очевидный выход -- создать его, либо наследовать у Мувилкипа (плохая техника), либо делегировать в классе, который содержит ссылку на мувиклип (лучшая техника).

Читайте Колина Мука...

[Gaen]

Тьфу ты, забыл приписать extends MovieClip. Но всёравно спасибо. А про Колина Мука поподробнее...

[ir73]

Сообщение от Antares

Перевожу: нет члена класса с именем OnEnterFrame

Очевидный выход -- создать его, либо наследовать у Мувилкипа (плохая техника), либо делегировать в классе, который содержит ссылку на мувиклип (лучшая техника).

Читайте Колина Мука...

Вот вы все время не рекоммендуете наследовать мувиклип. А как тогда обходитша с классами, которые мы присваимаем мувикам через Линкаге? Они же должны быть все, как я понимаю , extends MovieClip

[Antares]

Сообщение от ir73

Вот вы все время не рекоммендуете наследовать мувиклип. А как тогда обходитша с классами, которые мы присваимаем мувикам через Линкаге? Они же должны быть все, как я понимаю , extends MovieClip

Это опять же, если мыслить только как "объект сам должен иметь методы"... А что если объект имеет ссылку? Мы создаем экземпляр класса, конструктору (либо методу) передаем ссылку на его визуальную компоненту и все.

В крайнем случае никто не отменял createClassObject.

Базовый класс выглядит так:

import visual.scene.IVisualObject;
import mx.transitions.Tween;
import mx.transitions.easing.Elastic;

/**
 * @date        26.07.2003 
 * @author	Michael Klishin	
 * @version     1.0
 **/
class visual.scene.VisualObject implements IVisualObject
{
	private var __viewport:MovieClip;
	
	function VisualObject( mc:MovieClip )
	{
		__viewport = mc;
	}
	
	
	/**
	 * 
	 * @usage   
	 * @param   x 
	 * @param   y 
	 * @return  
	 */
	public function move( x:Number, y:Number ): Void
	{
		__viewport._x = x;
		__viewport._y = y;
	}


	/**
	 * 
	 * @usage   
	 * @param   state 
	 * @return  
	 */
	public function changeState( state:String ): Void
	{
		if(state) __viewport.gotoAndStop(state);
	}


	/**
	 * 
	 * @usage   
	 * @param   x 
	 * @param   y 
	 * @return  
	 */
	public function slideTo( x:Number, y:Number, relative:Boolean, time:Number, callback:Function ): Void
	{
		if(relative)
		{
			var xTo:Number = __viewport._x + x;
			var yTo:Number = __viewport._y + y;			
		} else
		{
			var xTo:Number = x;
			var yTo:Number = y;
		}
		
		var xTween:Tween = new Tween(__viewport, '_x', Elastic.easeOut, __viewport._x, xTo, time, true );
		var yTween:Tween = new Tween(__viewport, '_y', Elastic.easeOut, __viewport._y, yTo, time, true );
		
		if(callback) xTween.onMotionStopped = callback;
		
		xTween.start();
		yTween.start();
	}

	/**
	 * 
	 * @usage   
	 * @return  
	 */
	public function show(  ):Void 
	{
		__viewport._visible = true;
	}

	/**
	 * 
	 * @usage   
	 * @return  
	 */
	public function hide(  ):Void 
	{
		__viewport._visible = false;
	}

	/**
	 * 
	 * @usage   
	 * @return  
	 */
	public function getVisualObject(): MovieClip
	{
		return __viewport;
	}

}

И все. Очень логично и удобно, мухи отделены от котлет.

P.S. Занимаясь Flash не знать Мука -- то же самое, что быть лингвистом и не знать Достоевского

[ir73]

>P.S. Занимаясь Flash не знать Мука -- то же самое, что быть лингвистом
> и не знать Достоевского

у него книги платные : (

[KUZEN]

Сообщение от ir73

>P.S. Занимаясь Flash не знать Мука -- то же самое, что быть лингвистом
> и не знать Достоевского

у него книги платные : (

На халяву только сыр в мышеловке ...

[ir73]

KUZEN, не поделишся сыром ? )

[KUZEN]

Сообщение от ir73

KUZEN, не поделишся сыром ? )

Сколько вешать в граммах )))

[s_u_m_p]

2Antares

В крайнем случае никто не отменял createClassObject.

A это то причем? если у меня нету ни одного компонента в библиотеке, то этой функции тоже нету

Кстати единственный + в подходе Мука (на мой взгляд) это то что ты не должен ждать след. кадра при иницилизации мувов.