Интернационализация

[stasuss]

Всем привет.

Подскажите как проще и удобнее делать интернационализацию в приложении. Т.е. возможность выбора языка для вывода сообщений и надписей.

[caseyryan]

как обычно. Делать языковые пакеты, одинаковые по структуре, но с разным переводом, при выборе языка просто указывать языковой пакет, и оттуда будут браться все надписи

[stasuss]

ооо. а можно по подробнее? какие такие пакеты? package? по словам "языковой пакет actionscript" гугл какую то ерунду выдает...

[caseyryan]

Ну, например создать какой-то класс, на подобие абстрактной фабрики, который будет принимать для инициализации ксласс с каким-то интерфейсом, например

package language {
 
	public class LangPack {
 
		private static var _langPack:ILang;
 
		public static function setLanguage(langPack:ILang):void {
			_langPack = langPack;
		}
		public static function getList():Array {
			if (!_langPack) throw "сначала передайте языковой пакет через setLanguage()";
			return _langPack.getList();
		}
	}
 
}

сам интерфейс

package language {
 
	public interface ILang  {
		function getList():Array;
	}
}

и два примера языковых пакетов:

package language {
 
	public class RusPack implements ILang {
 
		private var _list:Array = ["главное меню", "выбор языка"];
 
		public function getList():Array {
			return _list;
		}
 
	}
 
}

и английский

package language {
 
	public class EngPack implements ILang {
 
		private var _list:Array = ["main menu", "select language"];
 
		public function getList():Array {
			return _list;
		}
 
	}
 
}

потом где-то инициализируем пакет

LangPack.setLanguage(new RusPack());
_mainMenu.text = LangPack.getList()[0]; // если передан русский пакет, будет выдавать надпись "главное меню", если английский "main menu"

Ну, типа того, надеюсь идея ясна
Для смены языка будет нужно опять передать в метод setLanguage новый экземпляр

LangPack.setLanguage(new EngPack());

ну или даже так, для наглядности

LangPack.setLanguage(new EngPack() as ILang);

[stasuss]

огромное спасибо)

[alatar]

Поищите по ключевым словам as3 i18n.
Вот, например, первое попавшееся.

[-De-]

Более использующийся термин "локализация".
http://www.flasher.ru/forum/showthre...E7%E0%F6%E8%FF

[alatar]

Это все-таки несколько разные термины. И ТС выбрал верный из них.

Internationalization is the process of designing a software application so that it can be adapted to various languages and regions without engineering changes. Localization is the process of adapting internationalized software for a specific region or language by adding locale-specific components and translating text.

[iflamberg]

Я. например, не оперирую большими текстами для перевода, поэтому у себя сделал очень просто. У меня есть translations.xml с такой структурой:

<translations>
	<t ru="Подтвердить" en="Confirm" />
	<t ru="Отмена" en="Cancel" />
	<t ru="Вы действительно хотите удалить это сохранение?" en="Delete savegame?" />
	<t ru="Инвентарь" en="Inventory" />
	<t ru="Купить" en="Buy" />
	<t ru="Продать" en="Sell" />
	<t ru="Сбросить" en="Reset" />
</translations>

Есть вот такая функция пакета:

package engine {
	public function t(str:String):String {
		if (Main.DEFAULT_LANG == Main.curLang) return str;
		var list:XMLList = Main.translations.t.(@[Main.DEFAULT_LANG] == str);
		return list.length()?list[0].@[Main.curLang]:str; 
	}
}

и в коде мне остается только добавить что-нибудь типа:

btnReset.label = t("Сбросить");

или даже

btnReset.label = t(btnReset.label);

Меня устраивает.

[expl]

_mainMenu.text = LangPack.getList()[0];

Выбирать текст по индексу? 0_o
Хранить в масссиве? Получается из середины ставший лишним текст удалили - всё съехало.
В Notepad++, вроде так и сделано, но есть же более человеческие способы

У нас статическая локализация представлена txt-файлом(все языки в одном файле), в котором текст хранится в TSV(разделенные табом значения).
TSV, потому что легко копипастить в Excel(по неясным причинам в других форматах переводчики работать не умеют)
Т.к. формат текстовый - он легко мержится
Пробовали сразу хранить в xls, но ручной мержинг доводит до белого коленья
Представляет текст типа:

	ru	en
menuName	Меню	Menu
okButton	OK	OK
cancelButton	Отмена	Cancel

По этому txt-файлу скриптом (у нас на haXe, но можно хоть на Haskell) генерятся:
- по xml-файлу на язык
- as3-файл Localization.as, с набором методов(утрировано):

public class Localization {
    private static _texts:Object;
    public static setParsedFromXmlTexts(texts:Object):void { _texts = texts }
    public static menuName():String { return _texts["menuName"] }
    public static okButton():String { return _texts["okButton"] }
    public static cancelButton():String { return _texts["cancelButton"] }
}

Если Localization.get("menuName") писать руками - начинаются бесконечные поиски описки, неиспользуемые ключи тяжело найти, постоянные перепроверки и вообще муторное занятие
А так - Localization.menuName() - и всё! Если ключ пропал - компилятор скажет.

При отдаче переводчикам содержимое txt-файла копируется в Excel
Сам файл (т.к. TSV править мягко говоря неудобно) - редактируется в самопальном редакторе на C# (подходящий несамопальный не нагуглили). Внешне это похоже на правку таблиц в том же Excel. При сохранении автоматом запускает скрипт, генерирующий xml и as.

Эта схема, конечно, не претендует на единственно верную и удобную во всех случаях, но в нашей практике ничего удобнее родить не смогли.