Задать условие

[Pon]

У меня есть мозайка, и каждый символ с именем 0-0, 0-1, 0-2 итд,
и когда я задаю условие типа

if (0-0._alpha > 70)
{
nextFrame();
}

Не хочет работать, выдаёт ошибку, не ужели это из-за того, что элементы называются 0-0 0-1 0-2 ? Можно что-нибуь сделать?

[Kikasso]

if (this['0-0']._alpha > 70)
{
nextFrame();
}

как раз из-за этого. Назвать с буквой вначале.
И код обводите тегами.

[Pon]

А если не получается с буквой? и зачем this что оно значит?

[motor4ik]

расскажите почему не получается с буквой , мы подумаем ) что мешает вам называть из element0_0 к примеру или el0_0

[Pon]

onClipEvent(mouseDown) {
	// get mouse location
	mx = _root._xmouse;
	my = _root._ymouse;

	// loop through pieces looking for hit
	for(x=0;x<3;x++) {
		for(y=0;y<4;y++) {
			piece = _root[x+"-"+y];

			// see whether the piece is under the cursor
			// and if it has not yet been placed
			if (piece.hitTest(mx,my) and (piece._alpha < 100)) {
				// this is the piece clicked
				piece.startDrag();

				// break out of all loops
				x = 3;
				y = 4;
				break;
			}
		}
	}
}

onClipEvent(mouseUp) {
	// stop piece from moving
	stopDrag();

	// get distance from center of piece
	// to center of outline

	dx = _root.outline._x - piece._x;
	dy = _root.outline._y - piece._y;
	dist = Math.sqrt(dx*dx+dy*dy);

	// if close enough, then set it in place
	if (dist < 10 ) {
		piece._x = _root.outline._x;
		piece._y = _root.outline._y;

		// set to full color
		piece._alpha = 100;
	}
}

Данный код был мной нагло украден Я не особо во всем разобрался, т.к. знание Actionscript еще неделю назад было вобще нулевое, но я так понимаю, что фишка в этой строчке

piece = _root[x+"-"+y];

и если элементы мозайки будут называться не 0-0 0-1 1-0 2-0 итд, мой piece двигаться не будет

[Aziz Zaynutdinoff]

мда...
посмотрите сами, вы обращаетесь к элементу в строчке

piece = _root[x+"-"+y];

а в проверки условия почему-то просто 0-0. Замените на _root[x+"-"+y] и будет вам счастье.

P.S.>>>
this – это ссылка на текущий клип, в котором используется вызов.
Т.е. если написать:

mc.onRelease = function()
{
     trace(_root.mc); // Outpur _level0.mc
     trace(this); // Output _level0.mc;
}
mc2.onRelease = function()
{
    trace(_root.mc2); // Output _level0.mc2;
    trace(this); // Output _level0.mc2;
}

[Pon]

Aziz Zaynutdinoff 0-0 0-1 0-2 0-3 1-0 1-1 1-2 1-3 2-0 2-1 2-2 2-3 это всё имена кусочков мозайки, и я хочу сделать банальную вещь, сделать поверку если все куски мозайки имеют прозрачность (Alpha) 100, сделать переход на новый кадр, и не могу

[Aziz Zaynutdinoff]

товарищ Pon, вы когда-нибудь занимались программированием до этого момента?

Знаете что такое циклы, обращение к переменным?
Для того, чтобы задать ваше условие достаточно организовать цикл от 0 до кол-ва элементов по OX, внутри которого цикл от 0 и кол-во элементов по OY, а дальше обычный перебор в теле условия.

Код писать за вас никто не будет (если конечно попадётся кто добрый, то всегда пожалуйста), а посылов к решению вашей задачи уже достаточно, чтобы её решить.

[motor4ik]

хорошее слово сарказм, мне нравится

function testMazaikaHaHa():Boolean {
for (i=0;i<n;i++){
  for (j=0;j<m;j++){
       if (_root[i+"-"+j]._alpha!=100){ 
          return false;
       }
  }
}
return true;
}


if (testMazaikaHaHa()) nextFrame();

[Pon]

motor4ik cпасибо огромное