Реализация onReleaseOutside

[NewMan_by]

Собственно меня интересует ответ на сабж, как сделать это событие в AS3. Если кто-то уже поднимал этот вопрос киньте ссылку, по поиску ничего не нашел.

[etc]

onReleaseOutside() EventHandler
----
flash.display.InteractiveObject dispatches event: mouseUp
----
Replaced in the new event model by a mouseUp event after a call to flash.display.InteractiveObject.setCapture().
----
Topic: ActionScript 2.0 Migration.

[MerlinTwi]

InteractiveObject.setCapture убрали.
Можно так:

package {
	import flash.display.Sprite;
	import flash.events.*;

	dynamic public class Test extends Sprite {

		function Test() {
			buttonMode=true;
			addEventListener(MouseEvent.MOUSE_DOWN, onMouseDown);
		}
		
		private function onMouseDown(e:Event):void {
			stage.addEventListener(MouseEvent.MOUSE_UP, onMouseUp);
		}
		private function onMouseUp(e:Event):void {
			stage.removeEventListener(MouseEvent.MOUSE_UP, onMouseUp);
			if (e.target==this) {
				trace("onRelease");
			} else {
				trace("onReleaseOutside");
			}
		}
		
	}
}

[artcraft]

MerlinTwi,

на случай если над stage есть объекты с MOUSE_UP, которые будут перекрывать MOUSE_UP сцены
cчитаю нужным немного добавить:

package {
import flash.display.Sprite;
import flash.events.*;

dynamic public class Test extends Sprite {

	function Test() {
		buttonMode=true;
		addEventListener(MouseEvent.MOUSE_DOWN, onMouseDown);
	}
		
	private function onMouseDown(e:Event):void {
		stage.addEventListener(MouseEvent.MOUSE_UP, onMouseUp, true);
	}
	private function onMouseUp(e:Event):void {
		stage.removeEventListener(MouseEvent.MOUSE_UP, onMouseUp, true);
		if (e.target==this) {
			trace("onRelease");
		} else {
			trace("onReleaseOutside");
		}
	}
		
}
}

еще могут быть запарки с утягиванием мышки со сцены - тогда листнер onMouseUp не будет удалён и сработает при следующем поднимании мышки над сценой... так что надо повесить на stage листнер для ещё одного события

[NewMan_by]

может я что-то не догоняю, но что это за flash.display.InteractiveObject и как его использовать?

[Nirth]

Это базовый класс для DisplayObjectContaiener который в свою очередь базовый для Sprite. ну а Sprite базовый для MovieClip

[etc]

MerlinTwi, это в хелпе Flex 2 8)

[NewMan_by]

MerlinTwi попробовал не работает, то есть когда за пределами клипа не срабатывает событие, хотя вроде должно.

[MerlinTwi]

__etc, старый хелп, пора обновить
см. livedocs.macromedia.com коммент от Jul 25, 2006 at 6:49 PM

[NewMan_by]

UPD
Работает со stage. В общем со stage фактически как использовать parent, то есть не совсем хороший способ