Удалить объект из массива по клику на него на сцене

[PrincessRoma]

Коротко о происходящем - по нажатию клавиши 1 создаем новый шарик, делаем его ObjectList.push() ( в массив такой), потом добавляем на сцену
По клику мышки хочется удалять соответствующий шарик со сцены и из массива. Со сцены все удаляется, а вот как удалить из массива - непонятно, а именно непонятно как получить номер i шарика в массиве, чтобы сделать ObjectList.slice(i,1);

package 
{
 
	import flash.display.MovieClip;
	import flash.display.Sprite;
	import flash.events.KeyboardEvent;
	import flash.events.MouseEvent;
	import flash.display.DisplayObject;
 
 
	public class Main extends MovieClip
	{
 
		var ObjectList: Array = new Array();
 
		public function Main()
		{
			stage.addEventListener(KeyboardEvent.KEY_DOWN,keyDownHandler);
			stage.addEventListener(MouseEvent.CLICK,mouseClickHandler);
		}
 
		function mouseClickHandler(e:MouseEvent)
		{
			trace(e.target);
			if (e.target != '[object Stage]')
			{
				var displayObject:DisplayObject = (DisplayObject) (e.target);
				displayObject.parent.removeChild(displayObject);
			}
			//ObjectList.slice(); // Проблемное место;
		}
 
 
 
		function keyDownHandler(e:KeyboardEvent)
		{
			if (e.keyCode == 49)
			{
				var Ball: Sprite = new Sprite();
				Ball.graphics.beginFill(Math.random()*0x1000000);
				Ball.graphics.drawCircle(0,0,20);
				Ball.graphics.endFill();
				ObjectList.push(Ball);
				Ball.x = 30 * ObjectList.length * 2;
				Ball.y = 30;
				addChild(Ball);
			}
 
			if (e.keyCode == 50)
			{
				trace(ObjectList.length);
			}
		}
	}
}

Мое решение - для шариков добавить параметр i, который будет хранить место в массиве, но вот как извлечь этот параметр по клику и передать в функцию - без понятия.
Читал и тут и на StackOverflow - ничего не нашел, что бы мне помогло.
через e.target к параметрам никак не обратиться.

Плюс в будущем у шариков появятся eventListener-ы, их тоже надо будет как-то удалять, пока без понятия, причем у разных шариков они могут быть так же разные.

[myakushka]

function mouseClickHandler(e:MouseEvent)
{
	var ball:Sprite = e.target as Sprite;
	if (ball)
	{
		removeChild(ball);
		objectsList.splice(objectsList.indexOf(ball), 1);
		//ball.removeEventListener(Event.*, eventHandler);
	}
}

Добавлено через 1 минуту
Еще советую завести для шарика отдельный класс Ball и спрятать в него отрисовку шарика. Тогда проверка

var ball:Sprite = e.target as Ball;
	if (ball)
	{...

будет более надежной

[PrincessRoma]

Спасибо за ответ, все работает. )