Ограничение на перемещение по вертикали клипа

[TheToxa]

Нужно сделать объектом MovieClip что-то наподобие слайдера. То есть есть стрелочка и есть шкала, по которой эта стрелочка перемещается. Нужно написать условие, чтобы стрелочка выше и ниже шкалы не могла перемещаться. Шкала находится на сцене между 250 и 350 по y.

Вот мой код:

R2.addEventListener(MouseEvent.MOUSE_DOWN, R2_pickup);
R2.addEventListener(MouseEvent.MOUSE_UP, R2_place);
 
function R2_pickup(e:MouseEvent):void {
stage.addEventListener(MouseEvent.MOUSE_MOVE, changeXY);
}
 
function R2_place(e:MouseEvent):void {
stage.removeEventListener(MouseEvent.MOUSE_MOVE, changeXY);
}
 
function changeXY(e:MouseEvent):void {
 
	if (R2.y<=350 && R2.y>=250) {
 
R2.y=mouseY;
 
}
 
}

При таком коде получается, что я могу выйти при перемещении стрелки за пределы и при этом обратно вернуться уже нельзя, т.к. координаты стрелки будут выходить за указанные пределы. Как сделать так, чтобы стрелочка двигалась только в пределах между 250 и 350 и не могла выйти за них? Спасибо!

[Alex Lexcuk]

Зацените готовый архив с нарисованным слайдером.
http://murmadillo.tut.su/m/sv-gor-sl.zip

[udaaff]

R2.addEventListener(MouseEvent.MOUSE_DOWN, R2_pickup);
//R2.addEventListener(MouseEvent.MOUSE_UP, R2_place);
 
function R2_pickup(e:MouseEvent):void
{
	stage.addEventListener(MouseEvent.MOUSE_MOVE, changeXY);
	stage.addEventListener(MouseEvent.MOUSE_UP, R2_place);
}
function R2_place(e:MouseEvent):void
{
	stage.removeEventListener(MouseEvent.MOUSE_MOVE, changeXY);
	stage.removeEventListener(MouseEvent.MOUSE_UP, R2_place);
}
 
 
function changeXY(e:MouseEvent):void
{
 
	R2.y = Math.max(250, Math.min(350, mouseY));
 
	//if (R2.y<=350 && R2.y>=250)
//	{
//
//		R2.y=mouseY;
//
//	}
}

[mickfallout]

package 
{
	import flash.display.Sprite;
	import flash.events.MouseEvent;
	public class Main extends Sprite 
	{
		private var sprite:Sprite = new Sprite();
		private var backGround:Sprite = new Sprite();
		public function Main():void 
		{
			super();
			addChild(backGround);
			addChild(sprite);
			backGround.graphics.beginFill(0xE0E0E0);
			backGround.graphics.drawRect(0, 0, stage.stageWidth, stage.stageHeight);
			backGround.graphics.endFill();
			sprite.graphics.beginFill(0xFF0000);
			sprite.graphics.drawCircle(0, 0, 10);
			sprite.graphics.endFill();
			sprite.x = 50;
			sprite.y = 250;
			sprite.addEventListener(MouseEvent.MOUSE_DOWN, mouseDownListner);
		}
		private function mouseDownListner(event:MouseEvent):void
		{
			addEventListener(MouseEvent.MOUSE_MOVE, mouseMoveListner);
			addEventListener(MouseEvent.MOUSE_UP, mouseUpListner);
		}
		private function mouseMoveListner(event:MouseEvent):void
		{
			sprite.y = event.stageY
			if (sprite.y > 350)
				sprite.y = 350;
			if (sprite.y < 250)
				sprite.y = 250;
		}
		private function mouseUpListner(event:MouseEvent):void
		{
			removeEventListener(MouseEvent.MOUSE_MOVE, mouseMoveListner);
			removeEventListener(MouseEvent.MOUSE_UP, mouseUpListner);
		}
	}
}

[TheToxa]

Большое спасибо за быстрый ответ!