Форум Flasher.ru - Движение клипа к точке

Форум Flasher.ru (http://www.flasher.ru/forum/index.php)

- ActionScript 1.0/2.0 (http://www.flasher.ru/forum/forumdisplay.php?f=93)

- - Движение клипа к точке (http://www.flasher.ru/forum/showthread.php?t=87834)

Движение клипа к точке

Сразу говорю, вопрос тупой) Но я перерыл всё, что только можно, нашёл кучу разных вариантов движения мувиков, но РАВНОМЕРНОГО нету нигде =(

Значится задача такая: пользователь кликает мышью по флэшке, и какой-то мувик начинает туда равномерно двигаться.

Нашёл такой способ:

Код:

clip.onEnterFrame = function()

{

       clip._x+=(clip_target_x-clip._x)/koefficient;

       clip._y+=(clip_target_y-clip._y)/koefficient;

}

Но этот код заставляет двигаться клип к точке неравномерно, сначала быстро, потом всё медленнее.

Пробовал делать так:

Код:

clip.onEnterFrame = function()

{

       clip._x+=(clip_target_x-clip._x)/Math.abs(clip_target_x-clip._x)*0.1;

       clip._y+=(clip_target_y-clip._y)/Math.abs(clip_target_y-clip._y)*0.1;

}

Здесь клип двигается равномерно, по 0.1 пикселя в кадр, но (!) его движение не строго по прямой к цели, а сначала по диагонали, а потом по горизонтали или вертикали, или же наоборот.

Может кто знает, как заставить клип равномерно по прямой заставить двигаться к заданной точке? Ведь, казалось бы, ничего проще нет =)

У меня такая же проблема была.Сел за математику и получилось.
для этого нужно знать что через 2 точки проходит прямая и ее функция придается в виде y=k*x+b нам надо найти k и b.
Обусловимся, что
a - имя мувика, который должен двигаться - координаты(x1,y1)
с - имя мувика, к которому движется а - координаты(x2,y2)
тогда,

Код:

//находим k

var k = (a._y-b._y)/(a._x-b._x);

//находим b

var b = a._y-k*a._x;

_root.onEnterFrame = function() {

moveTo(a, a._x, a._y, b._x, b._y)

}

function moveTo(f,x1,y1,x2,y2) {

       //если х1<x2, в противном случае x1-=2

       x1 += 2;//цифра вставлена от балды - можно любую поставить - это   как бы скорость

       y1 = k*x1+h;

       f._x = x1;

       f._y = y1;

}

впрочем второй мувик не обязателен - достаточно указать координату точки

Код:

onEnterFrame = function () {

        point = {x:_xmouse, y:_ymouse};

        theta = Math.atan2(point.y-myClip._y, point.x-myClip._x);

        speed = 5;

        myClip._x += Math.cos(theta)*speed;

        myClip._y += Math.sin(theta)*speed;

};

Спасибо, всё работает =)
Zone71, вроде лучше не называть собственные функции зарезервированными именами, типа moveTo(), а то плохо будет)

класс Tween тоже может это делать.

Snakesdesign, а поподробнее можно?

Цитата:

Сообщение от Randomm

Snakesdesign, а поподробнее можно?

Откройте хелп и прочтите.

2 Randomm:
Вставить на кадр таймлайна.

Код:

import mx.transitions.Tween;

import mx.transitions.easing.*;



var myCircleName:String = "circle";

var myCircleX:Number = Stage.width / 2;

var myCircleY:Number = Stage.height / 2;

var myCircleRadius:Number = 30;

var myCircleFillColor:Number = 0xff0000;

var myCircleLineColor:Number = 0x000000;

var myCircleLineWidth:Number = 1;

var circleSpeed:Number = 60;

var circleXMoveTween:Tween;

var circleYMoveTween:Tween;



var circleClip:MovieClip = createCircleMovieClip(myCircleName, this, this.getNextHighestDepth(), myCircleX, myCircleY, myCircleRadius, myCircleFillColor, 100, myCircleLineColor, 100, myCircleLineWidth);



this.onMouseDown = function()

{

        circleXMoveTween = new Tween(circleClip, "_x", Strong.easeOut, circleClip._x, this._xmouse - circleClip._width / 2, circleSpeed, false);

        circleXMoveTween = new Tween(circleClip, "_y", Strong.easeOut, circleClip._y, this._ymouse - circleClip._height / 2, circleSpeed, false);        

}



function createCircleMovieClip(circleName:String, parentClip:MovieClip, parentClipDepth:Number, circleX:Number, circleY:Number, circleRadius:Number, circleFillColor:Number, circleFillAlpha:Number, circleLineColor:Number, circleLineAlpha:Number, circleLineWidth:Number):MovieClip

{

        var newCircleClip:MovieClip = parentClip.createEmptyMovieClip(circleName, parentClipDepth);

        newCircleClip._x = circleX - circleRadius;

        newCircleClip._y = circleY - circleRadius;

        newCircleClip.lineStyle(circleLineWidth, circleLineColor, circleLineAlpha);

        newCircleClip.beginFill(circleFillColor, circleFillAlpha);

        var tanPI8:Number = Math.tan(Math.PI / 8);

        var sinPI4:Number = Math.sin(Math.PI / 4);

        newCircleClip.moveTo(2 * circleRadius, circleRadius);

        newCircleClip.curveTo(2 * circleRadius, (tanPI8 + 1) * circleRadius, (sinPI4 + 1) * circleRadius, (sinPI4 + 1) * circleRadius);

        newCircleClip.curveTo((tanPI8 + 1) * circleRadius, 2 * circleRadius, circleRadius, 2 * circleRadius);

        newCircleClip.curveTo((1 - tanPI8) * circleRadius, 2 * circleRadius, (1 - sinPI4) * circleRadius, (sinPI4 + 1) * circleRadius);

        newCircleClip.curveTo(0, (tanPI8 + 1) * circleRadius, 0, circleRadius);

        newCircleClip.curveTo(0, (1 - tanPI8) * circleRadius, (1 - sinPI4) * circleRadius, (1 - sinPI4) * circleRadius);

        newCircleClip.curveTo((1 - tanPI8) * circleRadius, 0, circleRadius, 0);

        newCircleClip.curveTo((tanPI8 + 1) * circleRadius, 0, (sinPI4 + 1) * circleRadius, (1 - sinPI4) * circleRadius);

        newCircleClip.curveTo(2 * circleRadius, (1 - tanPI8) * circleRadius, 2 * circleRadius, circleRadius);        

        newCircleClip.endFill();

        return newCircleClip;

}

Для движения без узкорений в конструкторе вместо Strong.easeOut использовать None.easeNone...
Исходник прикрепляю...

2 Randomm:
Да кстати не заметил (у меня все-таки тянет):D

2 Хемуль:
Ужс) длинно как-то)

2 iNils:
Иногда лучше жевать, чем говорить =)
В хелпе можно всё прочитать, но не за этим на форуме вопросы задаются