onWindowBlur and so on AS2

[in4core]

Ребят , кто нить понял как на АС2 подключать эти события ???!!! Помогите чем можете!!!

var sends = new LocalConnection();
sends.allowDomain('*');
var recive = new LocalConnection();
recive.allowDomain('*');
 
 
pannel.bt_friend.onRelease = function() {
 
	recive.connect("_out_" + _root.lc_name);
	sends.addEventListener('onWindowFocus',_root.focusF);
	sends.send("_in_" + _root.lc_name,'showInviteBox');
 
};
 
function focusF() {
	removeEventListener('onWindowFocus',sends);
	_root._visible = false;
}

соотв функция focusF у нас не работает ((( .... не могу понять как сделать верно

Добавлено через 8 часов 19 минут
Старички-проффи !!! подскажите, что никто не знает? Мне кажется вопрос простой!!!!

[KirAmp]

Что-то не работает.... можно попробовать сделать по другому... скажем
pannel.bt_friend.onRelease создает прозрачный клип, И сделать иф маус мув по нему, то => фокус с окна потерян

[in4core]

Ворпрос закрыт

	/*
	* APIConnection AS 2.0
	* author: Dima Chumak
	* used: APIConnection AS 3.0 by Andrew Rogozov
	*       APIConnection AS 2.0 by Alexey Lavrov
	*/
class APIConnection{
	//Params:
	private var conName:String;
	private var localCon:LocalConnection;
	private var isCon:Boolean;
 
	//Callbacks:
	public var onWindowBlur:Function;
	public var onWindowFocus:Function;
	public var onBalanceChanged:Function;
	public var onSettingsChanged:Function;
	public var onApplicationAdded:Function;
	public var onInit:Function;
	public var onMethod:Function;
	public var onError:Function;
	public var debugger:Function;
 
	//Constructor:
	public function APIConnection(conName:String){
		this.conName=conName;
		isCon=false;
		localCon=new LocalConnection();
		localCon.allowDomain=function(sendingDomain){ return true; }//return(sendingDomain==this.domain()); }
 
		localCon.main=this;
		localCon.onWindowBlur=function(){ this.main.onWindowBlur(); }
		localCon.onWindowFocus=function(){ this.main.onWindowFocus(); }
		localCon.onBalanceChanged=function(balance:String){ this.main.onBalanceChanged(parseInt(balance)); }
		localCon.onSettingsChanged=function(settings:String){ this.main.onSettingsChanged(parseInt(settings)); }
		localCon.onApplicationAdded=function(){ this.main.onApplicationAdded(); }
 
		localCon.onStatus=function(loaded:Object){
			if(loaded.level=="status"){
				if(!this.main.isCon){
					this.main.isCon=true;
					this.main.onInit();
				}
				else this.main.onMethod();
			}
			else{
				if(!this.main.isCon) this.main.onError(1);
				else this.main.onError(2);
			}
		}
	}
 
	//Create connection:
	public function startConnection():Boolean{
		if(!isCon){
			localCon.connect("_out_"+conName);
			localCon.send("_in_"+conName,"initConnection");
			return true;
		}
		else return false;
	}
 
	//Methods:
	public function showInstallBox():Void{ sendMethod(new Array("showInstallBox")); }
	public function showSettingsBox(settings:Number):Void{ sendMethod(new Array("showSettingsBox", settings.toString())); }
	public function showInviteBox():Void{ sendMethod(new Array("showInviteBox")); }
	public function showPaymentBox(votes:Number):Void{ sendMethod(new Array("showPaymentBox", votes.toString())); }
 
	private function sendMethod(paramsArr:Array):Void{
		if(isCon){
			if(paramsArr.length==1) localCon.send("_in_"+conName,paramsArr[0]);
			else if(paramsArr.length==2) localCon.send("_in_"+conName,paramsArr[0],paramsArr[1]);
			else onError(3);
		}
		else onError(4);
	}
}