Удаление детей в цикле

[in4core]

Есть большой контейнер в нем сотня разных клип-классов, мне нужно удалить только одну группу.

Дано контейнер А. В нем изначально 100 клипов одного класса. Затем в контейнер добавляются еще дети, но уже другого класса. Вопрос

for (var i:int = 0; i < A.numChildren; i++) {
 
	var co:DisplayObject = A.getChildAt(i);
 
	if (co is NewClass) _A.removeChildAt(i);
}

Если не так, то как? Ведь индексы сдвигаются после удаления. Дело в том, что я конечно знаю что индексация идет со 100, и проблем в удалении не вижу, но хочется рациональный способ для любой ситуации.

[goodguy]

может кто-то сочтет это быдлокодерством, но я бы сделал так:
перед циклом создал пустой массив, пробежался бы по детям, так же как сделал ты, но вместо удаления, затолкал бы нужное в этот массив, а потом уже пробежкой по этому массиву в обратном порядке, снес бы все ненужное

[bav]

Как вариант:

if (co is NewClass) _A.removeChildAt(i--);

[in4core]

как вариант - не прокатит )) То что индекс мы уменьшили это хорошо, а вот конечное значение цикла не меняется.
Goodguy , не могу сказать , что это быдлокодство, этот вариант и так понятен, я думаю должен же быть какой то красивый вариант

[Bgg]

Сообщение от in4core

То что индекс мы уменьшили это хорошо, а вот конечное

Начните конечным значением индекса, а заканчивайте нулем.

[bav]

а вот конечное значение цикла не меняется

numChildren меняется после removeChildAt.

package 
{
    import flash.display.DisplayObject;
    import flash.display.MovieClip;
    import flash.display.Sprite;
    import flash.events.Event;
 
    public class TestProject extends Sprite 
    {
        public function TestProject() 
        {
            if (stage) init();
            else addEventListener(Event.ADDED_TO_STAGE, init);
        }
 
        private function init(event:Event = null):void 
        {
            removeEventListener(Event.ADDED_TO_STAGE, init);
 
            for (var i:int = 0; i < 5; i++)
                if (Math.random() > 0.5)
                    addChild(createSprite(i));
                else
                    addChild(createMovieClip(i));
 
            for (var j:int = 0; j < numChildren; j++)
            {
                trace(getChildAt(j));
                var co:DisplayObject = getChildAt(j);
                if (co is MovieClip)
                    removeChildAt(j--);
                // В итоге останутся только белые кружки спрайтов.
            }
        }
 
        private function createSprite(i:int):Sprite
        {
            var s:Sprite = new Sprite();
            s.graphics.lineStyle(1);
            s.graphics.beginFill(0xFFFFFF);
            s.graphics.drawCircle(i * 20 + 10, i * 20 + 10, 20);
            return s;
        }
        private function createMovieClip(i:int):Sprite
        {
            var m:MovieClip = new MovieClip();
            m.graphics.lineStyle(1);
            m.graphics.beginFill(0x5555FF);
            m.graphics.drawCircle(i * 20 + 10, i * 20 + 10, 20);
            return m;
        }
    }
}

[Котяра]

Сделайте обратный цикл от numchildren до 0
UPD опередили)

[in4core]

Все верно bav , только я тут немного условия не указал видимо....

Вот пример

private function cancelBet(e:MouseEvent):void 
		{
			for (var i:int = 0 ;  i < _TB.numChildren; i++ ) {
 
				var co:DisplayObject = _TB.getChildAt(i);
				var a:Boolean = co is Coin;
				var b:Boolean = (co as Coin).code == _serverBetCode; // тут ругаемся
 
				if (a && b ) _TB.removeChildAt(i--) ;
 
			}
		}

Добавлено через 48 секунд
если без ремува, а ставить просто трейс все окей, ошибок нет. вывод верный

[bav]

(co as Coin)

может вернуть null, если co не Coin.

var co:DisplayObject = _TB.getChildAt(i);
if (co is Coin)
    if ((co as Coin).code == _serverBetCode)
        _TB.removeChildAt(i--);

[Dweem]

var i:int = container.numChildren
while(i--){
	if(container.getChildAt(i) is NewClass && (container.getChildAt(i) as NewClass).code == _serverBetCode)
		container.removeChildAt(i);
}