Ограниченный Drag - объект болтается по иксу

[zerAlex2]

Почему болтается клип при перетаскивании?
mc - мувик с текстом для скроллера.
Mask - маска для скроллера
Размер ширины текстового поля и маски совпадают.

mc.startDrag(false, new Rectangle(Mask.x, Mask.y-mc.height, Mask.x, Mask.y+mc.height));

Я думал, что если выставить в паратетрах по X одинаковы значения, то драг будет только вертикальным. Однако образуется какой-то зазор пикселов в 100.

[Wolsh]

Потому что ширина и координата х это разные вещи.

mc.startDrag(false, new Rectangle(Mask.x, Mask.y-mc.height, 0, Mask.y+mc.height));

[zerAlex2]

Японский... Я всегда думал, что там по координатам указывается квадрат...
Кстати, при кликаньи мышкой на клипе, он всё равно смещается где-то на пиксель. Я так понимаю, это просто глюк флэша.

[Wolsh]

координаты целые или дробные?

[zerAlex2]

Вроде всё целое. Но при клике влево на 1 пиксель скачет. Я с таким уже сталкивался как-то... только вот с шириной я тогда угадал )

[t4arty]

маленькой отступление: 1 пиксель присутствует всегда, не знаю зачем, но такое есть у sprite объектов, у bitmap такого не замечал.

[Wolsh]

Впервые слышу.

package 
{
	import flash.display.Shape;
	import flash.display.Sprite;
	import flash.events.Event;
	import flash.events.MouseEvent;
	import flash.geom.Rectangle;
 
	public class Main extends Sprite 
	{
		private var _pimp:Sprite;
 
		public function Main():void 
		{
			if (stage) init();
			else addEventListener(Event.ADDED_TO_STAGE, init);
		}
 
		private function init(e:Event = null):void 
		{
			removeEventListener(Event.ADDED_TO_STAGE, init);
			// entry point
			var track:Shape = new Shape();
			track.graphics.beginFill(0x000000);
			track.graphics.drawRect(0, 0, 20, 400);
			this.addChild(track);
			track.x = 200;
			track.y = 100;
 
			_pimp = new Sprite();
			_pimp.graphics.beginFill(0x006600);
			_pimp.graphics.drawRect(0, 0, 20, 40);
			this.addChild(_pimp);
			_pimp.x = 200;
			_pimp.y = 100;
			_pimp.addEventListener(MouseEvent.MOUSE_DOWN, startPimpDragHandler);
		}
 
		private function startPimpDragHandler(event:MouseEvent):void 
		{
			_pimp.startDrag(false, new Rectangle(200, 100, 0, 400 - 40));
			stage.addEventListener(MouseEvent.MOUSE_UP, stopPimpDragHandler);
		}
 
		private function stopPimpDragHandler(event:MouseEvent):void 
		{
			stage.removeEventListener(MouseEvent.MOUSE_UP, stopPimpDragHandler);
			_pimp.stopDrag();
		}
 
	}
 
}

Проверяйте размеры и координаты, если рисуете графику руками. Еще может глючить обводка.