Код паузы звука не работает!

[U4enik]

var sound:Sound = new Sound();
sound.loadSound("Van.mp3", true);
sound.start(loop);
 
var pausa:Boolean;
 
pause_btn.onRelease = function(){
  s_pos = sound.position;
  pausa = true;
  sound.stop();
  }
 
play_btn.onRelease = function(){
  if(pausa){sound.start(s_pos);}
  else{sound.start();}
  pausa = false;
  }

После нажатия на кнопку воспроизведения , звук начинает проигрываться сначала, а не оттуда где был остановлен? А бывает вобще не проигрывается. Где я ошибаюсь?

[mooncar]

1. Ошибка в несоответствии единиц измерения.

secondOffset должен быть в секундах

start (Sound.start method)
public start([secondOffset: Number], [loops: Number]) : Void

А позиция считывается в миллисекундах:

Sound.position property
public position :  Number [read-only]
The number of milliseconds a sound has been playing...

Поэтому:

var sound:Sound = new Sound();
sound.loadSound("Van.mp3", true);
sound.start(); // у вас тут было написано loop  - к чему это было? Так ничего не зациклется.
 
var pausa:Boolean ;
 
pause_btn.onRelease = function()
{
	s_pos = sound.position ;
	pausa = true ;
	sound.stop();
	trace(sound.position);
};
 
play_btn.onRelease = function()
{
	if(pausa)
	{
		sound.start(s_pos/1000); //нюанс тут!
	}
	else
	{
		sound.start();
	}
	pausa = false ;
};

3. Далее, некторые нюансы в использовании методов Sound.

3.1. Это можно не писать:

sound.start();

(и даже вредно), еслиу вас true в

sound.loadSound("Van.mp3", true);

, то есть звук потоковый.
Звук начнет играть сам. Иначе старт может произойти два раза.

3.2. И наконец, если вам нужно зациклить звук, то конечный код будет такой:

var sound:Sound = new Sound();
sound.loadSound("Van.mp3", true);
sound.onSoundComplete = function () 
{
	sound.start();
};
 
var pausa:Boolean ;
 
pause_btn.onRelease = function()
{
	s_pos = sound.position;
	pausa = true ;
	sound.stop();
	trace(sound.position);
};
 
play_btn.onRelease = function()
{
	if(pausa)
	{
		sound.start(s_pos/1000);
	}
	else
	{
		sound.start();
	}
	pausa = false ;
};

PS.
На будущее - не склеивайте уж так ваш код скобочка к скобочке - самим же неудобно, причесывать сперва приходится, чтобы разобраться.
По типу

if(pausa){sound.start(s_pos);}
else{sound.start();}

Компилятору пофиг такое уплотнение, и производительности это не прибавит, крутизна кода от этого сомнительная, а читабельность кода никакая, тем более для потенциальных советчиков.
Если хотите сократить, так иногда тернарный оператор годится:

play_btn.onRelease = function()
{
	pausa ? sound.start(s_pos/1000) : sound.start() ;
	pausa = false ;
};