Задержка добавления мувика через attachMovie

[JOKER_MAX]

Есть такой код:

for (i=1;i<5;i++)
   {	  
      cl = _root.attachMovie("panel_menu","panel"+i,i);
      cl._y = i*100;
   }

Как сделать чтобы мувики добавлялись с разницей в одну секунду? пробовал так:

for (i=1;i<5;i++)
   {	  
      setTimeout(function(){	
      cl = _root.attachMovie("panel_menu","panel"+i,i);
      cl._y = i*100;
      },1000);
   }

не получается

[Hauts]

var totalMovies = 5;
var addedMoviesCount = 0;
var addMoviesInterval = setInterval(addMovie, 1000);
 
function addMovie() {
	addedMoviesCount++;
	if (addedMoviesCount == totalMovies) {
		clearInterval(addMoviesInterval);
		return;
	}
	var i = addedMoviesCount + 1;
	var mc = _root.attachMovie("panel_menu", "panel" + i, i);
	mc._y = i * 100;
}

А вообще, если вам нужно просто появление с задержкой, можете воспользоваться классом TweenLite для анимации появления. То есть создать все мувики в цикле за раз, и там же, в цикле, каждому мувику добавить анимацию появления _alpha : 100 со значением задержки delay. Если такой подход интересен, могу подробнее описать.

[JOKER_MAX]

Hauts, интересен. Подробнее, пожалуйста. Меня и интересует именно появление с задержкой. Только там _alpha не подходит. Мувики с движением.

[mooncar]

Тут как раз уместно использовать setInterval :

var i:Number = 1;
var attachInterval:Number = setInterval(setPanel, 1000);
 
function setPanel() 
{
	if (i < 5)
	{
		var cl:MovieClip = _root.attachMovie('panel_menu', 'panel' + i, i);
		cl._y = i * 100;
		i++;
	}
	else
	{
		clearInterval(attachInterval);
	}
}

[JOKER_MAX]

Спасибо. и так и так работает

[Hauts]

Идем на сайт greensock и скачиваем библиотеки AS2 для анимации. Вам потребуется TweenLite (можно и другие, конечно).

Далее в папку с вашим исходником кладете папку "com" из скаченого архива и в коде, где планируете использовать класс TweenLite подключаете его следующей строкой (в начале кода):

import com.greensock.*

Теперь относительно появления клипов, я покажу на примере с прозрачностью.

import com.greensock.*
for (var i = 1; i < 5; i ++){	  
      var newClip = _root.attachMovie("panel_menu","panel"+i,i);
      newClip._y = i*100;
      newClip._alpha = 0;
      TweenLite.to(newClip, i, {_alpha : 100, delay: i});
}

В последней строке вы создаете новую программную анимацию. В обычном случае программно можно анимировать любые числовые значения объектов. Такие, как _alpha, _x, _y, _xscale и т.д.

Первый параметр в TweenLite.to — это целевой объект, у которого вы будете менять свойство. Можно, например, поставить _root (или this) и менять свойства у основной временной шкалы.

Второй параметр, в данном случае, "1" — это продолжительность анимации в сукундах.

Третий параметр — это объект со свойствами для анимации. В нем я прописал "_alpha:100", что значит, что непрозрачность объекта за одну секунду должна стать 100-процентной. Так же в этом объекте есть свойство delay — это задержка до старта анимации в сукундах.

Таким образом вы получаете создание объектов единовременно, но последовательно их появление с задержкой в 1 секунду.

Вообще почитайте по ссылке документацию, для объекта со свойствами анимации существуют разные "настройки", не только delay.