Рисовать программно или импортировать графику

[Akopalipsis]

caseyryan за иконки я принял "иконки окна виндовса".

Вам не кажется, что это была бы лишняя трата времени и ресурсов процессора и памяти?

Пока нет, мне бы очень хотелось так графиксом нарисовать)

[Wolsh]

Иконки это иконка пятнашек в левом углу и иконки на кнопках окна _ □ х
Конечно же не проблема и их нарисовать кодом, че там рисовать то) Не помню точно, почему я предпочел битмап, думаю что он просто весил бы меньше и требовал меньше процессора (однозначно) чем рисование вектором с градиентами и матрицами.
Цифры на фишках — ну это смешно.. Это тупо текстфилды, и кажется даже шрифт не внедрен.
Кстати прошу прощения за вес файла — забыл убрать из библиотеки большую картинку, служившую обоями десктопа оконного интерфейса, из теста которого я и сляпал эту флэшку по-быстрому для демонстрации. Ну и там шрифтик псевдопиксельный (которым написано ПЯТНАШКИ) встроен, тоже что-то весит. Это я к тому, что бы вы не подумали, что рисование Графиксом дает такой огромный вес)))

Добавлено через 6 минут
Да, вот код фишки

package  test.game15 
{
	import flash.display.Shape;
	import flash.display.Sprite;
	import flash.filters.BevelFilter;
	import flash.filters.GlowFilter;
	import flash.text.TextField;
	import flash.text.TextFormat;
 
/* * * * * * * * * *
*                  *
*  @author wolsh   *
*                  *
\* * * * * * * * * */ 
	public class Chip extends Sprite implements IChip
	{
		private var _tf:TextField;
		private var _embedShape:Shape;
		private var _id:uint;
		private var _w:uint;
		private var _h:uint;
		private var _textBevel:Array = 
		[
			new BevelFilter(1, 45, 0xFFFFFF, 1.0, 0x441100, 0.5, 1, 1, 1, 3, "outer"),
			new BevelFilter(1, 45, 0xFFFFFF, 1.0, 0x441100, 0.5, 1, 1, 1, 3)
		];
 
		public function Chip(id:uint) 
		{
			_id = id;
			_embedShape = new Shape();
			_tf = new TextField();
			redraw(0xFFCC99, 0xEEBB88);
		}
 
		public function redraw(borderColor:uint, fillColor:uint):void
		{
			this.graphics.clear();
			this.graphics.beginFill(borderColor);
			this.graphics.drawRoundRect(0,0,50,50,6);
			_embedShape.graphics.clear();
			_embedShape.graphics.beginFill(fillColor);
			_embedShape.graphics.drawRoundRect(8,8,34,34,3);
			_embedShape.filters = [ new BevelFilter(2, 245, 0xFFFFFF, 0.5, 0x663300, 0.3, 0, 0, 1, 3, "outer") ];
 
			_tf.width = 30, _tf.height = 30;
			_tf.x = 9, _tf.y = 8;
			_tf.selectable = false;
			_tf.mouseEnabled = false;
			_tf.defaultTextFormat = new TextFormat("Arial", 24, borderColor, true, false,false,null,null,"center");
			_tf.text = _id.toString();
			addChild(_tf);
			_tf. filters =  _textBevel //[];
			_tf.text = _id.toString();
			addChildAt(_embedShape, 0);
			this.filters = [ new BevelFilter(4, 45, 0xFFFFFF, 0.5, 0x441100, 0.5, 2, 2, 1, 3) ];
		}
 
		public function hilightOn():void
		{
			redraw(0xFFEEAA, 0xEEDD88);
			_tf. filters =  _textBevel.concat([new GlowFilter(0xFFF0EE, 1, 18, 18, 1, 3)]);
		}
 
		public function hilightOff():void
		{
			redraw(0xFFCC99, 0xEEBB88);
			_tf. filters =  _textBevel //[];
		}
 
		/*  IChip implement  */
 
		public function get id():uint {return _id;} // сеттер не нужен, закрытое свойство.
 
		public function get w():uint {return _w;}
 
		public function set w(value:uint):void {_w = value;}
 
		public function get h():uint {return _h;}
 
		public function set h(value:uint):void {_h = value;}
	}
 
}

[Akopalipsis]

Wolsh я к чему спросил о цифрах, как то я думал, как нарисовать текст графиксом, наподобие написания рукой. С начала и беспрерывно, как рукой. И мне первое что пришло в голову, это растрировать TextField и считать границы пикселей и по этим координатам рисовать.
И очень классно у Вас получилось!

[dark256]

Нет. Не надо. Бред. Рисуем и туда его. Не преумножайте. (с)Оккам