инвертировать альфа канал

[zuxul]

Нужно из прозрачных мест сделать не прозрачные, а непрозрачные прозрачными.
alpha = 255 - alpha
Делаю так, но уверен, что есть более быстрый метод, подскажите пожалуйста:

var data:BitmapDate = ...
invert_date = new BitmapData(date.width, date.height, true, 0x00000000);
var r:Rectangle = new Rectangle(0, 0, date.width, date.height);
var byte:ByteArray = date.getPixels(r);
var new_byte:ByteArray = new ByteArray();
byte.position = 0;
for (var i:uint = byte.length / 4; i > 0; i--) {
    var hex:int = byte.readInt()
    var alpha:uint = 0xFF - (hex >> 24 & 0xFF);
    hex &= 0x00FFFFFF;
    hex |= alpha << 24;
    new_byte.writeInt(hex);
}
new_byte.position = 0;
invert_date.setPixels(r, new_byte);

[wvxvw]

Я не уверен... но, просто для эксперимента - а что будет если через copyChannel скопировать только альфаканал, инвертировать только его, а потом вернуть на место?

Из разряда общей оптимизации:
а / 4 == а * 0.25 == a >>> 2
в вашей ситуации лучше было бы закешировать длинну массива (т.как она не меняется) и сразу поделить на 4 вместо того, чтобы делать это каждую итерацию.
(Имеется в виду - инкрементить i в цикле, а не декрементить - инкремент быстрее).

А, да, и инкремент с int быстрее инкремента с uint - почему - это загадка AVM2

[zuxul]

С делением, и вправду, можно выкинуть одну здоровенную спичку из коробка, а вот про инкремент и декремент не знал...
Для использования copyChannel нужен еще один BitmapDate, в который придется загнать этот канал, вообщем, я что-то не смог придумать, как его прикрутить.

[VVall]

Инвертирование альфа-канала - это alpha^=0xff000000, а не вся эта куча операций.

[udaaff]

в вашей ситуации лучше было бы закешировать длинну массива (т.как она не меняется) и сразу поделить на 4 вместо того, чтобы делать это каждую итерацию.

В цикле деление не в условии, так что оно каждую итерацию вычисляться не должно.

[zuxul]

И так, получилось:

var data:BitmapDate = ...
invert_date = new BitmapData(date.width, date.height, true, 0x00000000);
var r:Rectangle = new Rectangle(0, 0, date.width, date.height);
var byte:ByteArray = date.getPixels(r);
var new_byte:ByteArray = new ByteArray();
byte.position = 0;
var length:int = byte.length >> 2; // == byte.length / 4
for (var i:int = 0; i < length; i++) {
    new_byte.writeInt(byte.readInt() ^ 0xFF000000);
}
new_byte.position = 0;
invert_date.setPixels(r, new_byte);

[wvxvw]

Сообщение от udaaff

В цикле деление не в условии, так что оно каждую итерацию вычисляться не должно.

я имел в виду:

for (var i:int; i < len; i += 4)

или

len >>>= 2;
for (var i:int; i < len; i++)

вместо:

for (var i:int = len / 4; i > 0; i--)

[TERRORist]

разве CopyChannel не быстрее?

[zuxul]

Сообщение от zuxul

... вообщем, я что-то не смог придумать, как его прикрутить.

Подкинте вариант...

[silin]

alpha = 255 - alpha

var mtrx:Array=[	1, 0, 0, 0, 0,
			0, 1, 0, 0, 0,
			0, 0, 1, 0, 0,
			0, 0, 0, -1, 255];
var filter:ColorMatrixFilter = new ColorMatrixFilter(mtrx);
bmd.applyFilter(bmd, bmd.rect, new Point(), filter);