Изменение свойств фильтра(ов)

[TanaTiX]

Есть некий DisplayObject, на который действует неопределенное количество фильтров.
В какой-то момент необходимо один или несколько из них "обновить", т.к. они поменяли ряд своих значений.
Как, если предположительно неизвестно что и как поменялось?
Пример кода:

import flash.display.Sprite;
import flash.filters.DropShadowFilter;
 
var mc:Sprite=new Sprite();
mc.graphics.beginFill(0xff0000);
mc.graphics.drawCircle(100,100,100);
mc.graphics.endFill();
addChild(mc);
 
var filter:DropShadowFilter = new DropShadowFilter();
mc.filters=[filter];
 
filter.distance=50;
//вот тут необходимо обновить фильтр/отображение объекта, с учетом того, что количество примененных фильтров и ссылки на них не известны

[Wolsh]

Просто заново назначить массив фильтров... Или что именно неизвестно?

var shadow:DropShadowFilter = new DropShadowFilter();
var blur:BlurFilter = new BlurFilter();
var blurShadow:Array = [shadow, blur];
 
mc.filters = blurShadow;
 
shadow.distance = 50;
mc.filters = blurShadow;

[Deimos747]

for each(var oldFilter: Object in mc.filters) {
   if (oldFilter is DropShadowFilter) {
      for (var prop: String in filter) {
           DropShadowFilter(oldFilter)[prop] = filter[prop]
      }
      break;
   }
}

Я думаю, как то так

[Wolsh]

Массив-то хранит ссылки на экземпляры фильтров, и когда фильтры меняются, "в массиве" они "тоже меняются". Но дело в том, что когда Вы отдавали массив свойству filters, фильтры применяются один раз как набор эффектов с установками (значениями). Автоматического обновления не происходит, так же как здесь:

var b:Number = 500;
mc.width = b; // применили, mc стал шириной 500
b = 1000; // но mc не стал шириной 1000 ))
mc.width = b; // а вот теперь 1000.

[TanaTiX]

Wolsh, да, то что необходимо назначить, - не известно.
Массив - объект ссылочного типа, думал что по сеттеру происходит сравнение массивов. Но нижеприведенный код на результате никак не отразился:

var arr:Array = mc.filters;
var newArr:Array=[];
for each(var item:Object in arr){
	newArr.push(item);
}
mc.filters = newArr;

Очень бы не хотелось воспользоваться чем-то похожим на вариант Deimos747

[Wolsh]

А как он должен был отразиться? Если ты скопировал и назначил обратно то же, что и было?

var filtersArr:Array = [_shadow, _blur];
mc.filters = filtersArr;
trace(mc.filters == filtersArr); // false !

Добавлено через 11 минут

Очень бы не хотелось воспользоваться чем-то похожим на вариант Deimos747

И не придется, ибо он не будет работать. Я вроде объяснил, почему. И как будет работать, ответил. Если не знаете, каким объектам какие фильтры поназначили, то это уж не моя вина. Как обычно – чините архитектуру.

[Inet_PC]

Ну, а в чем проблема то? Нужно обновить фильтры в любой момент времени?

if (mc && mc.filters) mc.filters = mc.filters.concat();

Конкат тут так на всякий случай. Если без него работает, то лучше без него. И чем Вас ответ Wolsh-а не устроил?

[dimarik]

Нужно сначала получить фильтры, обновить их и засеттить заново.

[Silicium]

Почему бы не переопределить сеттер для фильтров и в нем все это реализовывать?

[Wolsh]

Silicium, отличная мысль!
FilteredSprite.as :

package  
{
	import flash.display.Sprite;
	public class FilteredSprite extends Sprite 
	{
		private var _filterArray:Array = [];
 
		public function FilteredSprite() 
		{
 
		}
 
		override public function set filters(value:Array):void
		{
			_filterArray = value;
			super.filters = value;
		}
 
		public function updateFilters():void
		{
			super.filters = _filterArray;
		}
	}
}

var mc:FilteredSprite = new FilteredSprite();
mc.graphics.beginFill(0x000000, 1);
mc.graphics.drawRect(0, 0, 200, 150);
addChild(mc);
mc.x = mc.y = 100;
var filtersArr:Array = [_shadow, _blur];
mc.filters = filtersArr;
 
_shadow.distance = 80;
mc.updateFilters(); // работает