Проблема с созданием прелоадера

[ChuwY]

1. Лезете в настройки проекта http://*************/s/1oIsN и указываете export classes in frame 2.
2. Создаете пустой мувик и указываете ему в качестве класса ваш мейн-класс. То есть SlideGalleryClass.
http://*************/s/1oIuc не забывая поставить галочку export in frame 2
3. Лезем на таймлайн и создаем там второй кадр. Рисовать не обязательно ни в первом ни во втором. Просто они должны быть. http://*************/s/1oIvT -- как видите, пусто.
4. Добавляем переход во второй кадр в хендлере комплита загрузки. Вот так:

private function startup():void{
  gotoAndStop(2);
  var mainClass:Class = getDefinitionByName("SlideGalleryClass") as Class;
  addChild(new mainClass() as DisplayObject);
}

5. Включаем тест муви. Включаем view> Brandwidth Profiler; включаем view Simulate Download, где не забываем выставить канал потоньше, а в мейн заембедить\накидать чего-нибудь потяжелее, если там еще пусто. Это чтобы потестить нормально. Любуемся на то, как код прелоадера рисует циферки. http://*************/s/1oIBa

Код прелоадера в примере прост:

package 
{
 
	import flash.display.MovieClip;
	import flash.utils.getDefinitionByName;
	import flash.display.DisplayObject;
	import flash.events.Event;
	import flash.text.TextField;
	import flash.events.ProgressEvent;
 
 
	public class Preloader extends MovieClip
	{
 
		private var _textField:TextField = new TextField();
		public function Preloader()
		{
			addChild(_textField);
			loaderInfo.addEventListener(Event.COMPLETE, completeHandler);
			loaderInfo.addEventListener(ProgressEvent.PROGRESS, progressHandler);
		}
 
		private function progressHandler(event : ProgressEvent):void
		{
			_textField.text = String(int(100*loaderInfo.bytesLoaded / loaderInfo.bytesTotal));
		}
 
		private function completeHandler(event : Event):void
		{
			gotoAndStop(2);
			var mainClass:Class = getDefinitionByName("Main") as Class;
			var main : DisplayObject = new mainClass();
			addChild(main);
		}
 
	}
 
}

6. Любуемся на то, как все загрузилось, переключилось на второй кадр и в мейне приаттачилась большая балластная картинка.
http://imageshost.ru/photo/66527/id1140020.html

Вот как-то так можно, если не хотите переходить на более подходящие для кода среды разработки.

[GBee]

Кодовый вариант давно реализован на FlashDevelop.

+1

package 
{
	import flash.display.DisplayObject;
	import flash.display.MovieClip;
	import flash.display.StageAlign;
	import flash.display.StageScaleMode;
	import flash.events.Event;
	import flash.events.IOErrorEvent;
	import flash.events.ProgressEvent;
	import flash.text.TextField;
	import flash.text.TextFieldAutoSize;
	import flash.text.TextFormat;
	import flash.utils.getDefinitionByName;
 
	[SWF(width = 800, height = 700, backgroundColor="#FFFFFF")]
	public class Preloader extends MovieClip 
	{
		private var _tf:TextField;
		public function Preloader() 
		{
			if (stage) {
				stage.scaleMode = StageScaleMode.NO_SCALE;
				stage.align = StageAlign.TOP_LEFT;
			}
			addEventListener(Event.ENTER_FRAME, checkFrame);
			loaderInfo.addEventListener(ProgressEvent.PROGRESS, progress);
			loaderInfo.addEventListener(IOErrorEvent.IO_ERROR, ioError);
 
			// TODO show loader
			_tf = new TextField();
			_tf.defaultTextFormat = new TextFormat("Tahoma", 20, 0x8A9B4A);
			_tf.autoSize = TextFieldAutoSize.LEFT;
			_tf.text = "0%";
			_tf.x = (Config.WIDTH - _tf.width)/2; //350;
			_tf.y = (Config.HEIGHT - _tf.height)/2;//325;
 
			addChild(_tf);
		}
 
		private function ioError(e:IOErrorEvent):void 
		{
			trace(e.text);
		}
 
		private function progress(e:ProgressEvent):void 
		{
			// TODO update loader
			_tf.text = int((e.bytesLoaded/e.bytesTotal)*100) + "%";
			_tf.x = (Config.WIDTH - _tf.width)/2; //350;
			_tf.y = (Config.HEIGHT - _tf.height)/2;//325;
		}
 
		private function checkFrame(e:Event):void 
		{
			if (currentFrame == totalFrames) 
			{
				stop();
				loadingFinished();
			}
		}
 
		private function loadingFinished():void 
		{
			removeEventListener(Event.ENTER_FRAME, checkFrame);
			loaderInfo.removeEventListener(ProgressEvent.PROGRESS, progress);
			loaderInfo.removeEventListener(IOErrorEvent.IO_ERROR, ioError);
 
			// TODO hide loader
			removeChild(_tf);
			_tf = null;
			startup();
		}
 
		private function startup():void 
		{
			var mainClass:Class = getDefinitionByName("MyMainClass") as Class;
			addChild(new mainClass() as DisplayObject);
		}
 
	}
 
}

package
{
	import flash.display.Sprite;
	[Frame(factoryClass="Preloader")]
	public class MyMainClass extends Sprite
	{
        }
}

Добавлено через 1 минуту
Все дело в волшебном метатеге [Frame(factoryClass="Preloader")]