Ошибка, не выводится список thumbs видеороликов в компоненте ScrollPane

[mariamarfi]

При компиляции выдаётся ошибка:

Монтажный кадр 1, слой "AS3", кадр 1, строка 82 1136: Неправильное количество аргументов. Ожидается 1.
Монтажный кадр 1, слой "AS3", кадр 1, строка 114 1119: Обращение возможного неопределенного свойства text через ссылку со статическим типом String .

import flash.net.URLLoader;
import flash.net.URLRequest;
import flash.events.Event;
import flash.display.MovieClip;
import flash.display.Loader;
import flash.display.Bitmap;
 
stop();
//initialize variables
var video_url: String;
var video_title_default: String;
var i: uint;
var tn: Number = 0;
var total_items: Number;
var current_no: Number = 0;
var video_playlist = new Array();
var mediatutorial_xml: XML;
var xml_file: String = "xmls/video_playlist.xml";
 
//load xml
var xml_loader: URLLoader = new URLLoader();
xml_loader.load(new URLRequest(xml_file));
xml_loader.addEventListener(Event.COMPLETE, create_array);
 
//make movieClip
var mc: MovieClip = new MovieClip();
var thumbnail_group: MovieClip = new MovieClip();
playlist.addChild(thumbnail_group);
 
function create_array(e:Event): void
{
	mediatutorial_xml = new XML(e.target.data);
	total_items = mediatutorial_xml.videoKu.length();
	var firstVideoTitle: String = mediatutorial_xml.videoKu[0].videoTitle;
	var firstVideoFile: String = mediatutorial_xml.videoKu[0].videoFile;
 
	for(i=0; i < total_items; i++)
	{
		video_playlist.push({
								videoTitle: mediatutorial_xml.videoKu[i].videoTitle.toString(),
								videoFile: mediatutorial_xml.videoKu[i].videoFile.toString(),
								videoThumb: mediatutorial_xml.videoKu[i].videoThumb.toString()
							});
	}
 
	prepare_thumb_item();
	//mari kita putar video pertama
	video_title_default = firstVideoTitle;
	video_title.text = firstVideoTitle;
	video_url = "video_folder/" + firstVideoFile;
	gotoAndPlay(3);
 
}
 
function prepare_thumb_item():void
{
	var pic_request: URLRequest = new URLRequest("video_folder/thumbs/" + video_playlist[tn].videoThumb);
	var pic_loader: Loader = new Loader();
	pic_loader.load(pic_request);
	pic_loader.contentLoaderInfo.addEventListener(Event.COMPLETE, create_thumb_item);
}
 
function create_thumb_item(e:Event):void
{
	var mediatutorial_bm: Bitmap = new Bitmap();
	var mediatutorial_mc: MovieClip = new MovieClip();
 
	mediatutorial_bm = Bitmap(e.target.content);
	mediatutorial_bm.smoothing = true;
	mediatutorial_bm.x = 10;
	mediatutorial_bm.y = 10+tn*(mediatutorial_bm.height+10);
 
	mediatutorial_mc.addChild(mediatutorial_bm);
	mediatutorial_mc.name = "mediatutorial_thumb_" + thumbnail_group.numChildren;
	mediatutorial_mc.buttonMode = true;
 
	thumbnail_group.addChild(mediatutorial_mc);
	tn++;
	if (tn < total_items)
		prepare_thumb_item();
	else
		complete_thumb_item();
	scrollpane.source = playlist;
 
}
 
function complete_thumb_item(e:Event):void
{
	for (i=0; i < total_items; i++)
	{
		mc = MovieClip(thumbnail_group.getChildByName("mediatutorial_thumb_" + i));
		mc.addEventListener(MouseEvent.MOUSE_OVER, tn_over);
		mc.addEventListener(MouseEvent.MOUSE_OUT, tn_out);
		mc.addEventListener(MouseEvent.CLICK, tn_click);
	}
}
 
function tn_over(e: MouseEvent): void
{
	mc = MovieClip(e.target);
	current_no = parseInt(mc.name.slice(20,21));
	video_title.text = video_title_default;
}
 
function tn_out(e: MouseEvent): void
{
	video_title.text = video_title_default;
}
 
function tn_click(e: MouseEvent): void
{
	mc = MovieClip(e.target);
	current_no = parseInt(mc.name.slice(20,21));
	video_title_default.text = video_playlist[current_no].videoTitle;
 
	video_title.text = video_playlist[current_no].videoTitle;
	video_url = "video_folder/" + video_playlist[current_no].videoFile;
	gotoAndPlay(2);
 
}

XML:

<?xml version="1.0" encoding="utf-8"?>
<XML>
	<videoKu>
		<videoTitle>Барсук</videoTitle>
		<videoFile>barsuk.flv</videoFile>
		<videoThumb>barsuk.jpg</videoThumb>
	</videoKu>
		<videoKu>
		<videoTitle>Белка</videoTitle>
		<videoFile>belka.flv</videoFile>
		<videoThumb>belka.jpg</videoThumb>
	</videoKu>
	<videoKu>
		<videoTitle>Енот</videoTitle>
		<videoFile>enot.flv</videoFile>
		<videoThumb>enot.jpg</videoThumb>
	</videoKu>
	<videoKu>
		<videoTitle>Тигр</videoTitle>
		<videoFile>tigr.flv</videoFile>
		<videoThumb>tigr.jpg</videoThumb>
	</videoKu>
		<videoKu>
		<videoTitle>Волк</videoTitle>
		<videoFile>volk.flv</videoFile>
		<videoThumb>volk.jpg</videoThumb>
	</videoKu>
	<videoKu>
		<videoTitle>Леопард</videoTitle>
		<videoFile>leopard.flv</videoFile>
		<videoThumb>leopard.jpg</videoThumb>
	</videoKu>
</XML>

[Rivexe]

Сообщение от mariamarfi

При компиляции выдаётся ошибка:

Монтажный кадр 1, слой "AS3", кадр 1, строка 82 1136: Неправильное количество аргументов. Ожидается 1.
Монтажный кадр 1, слой "AS3", кадр 1, строка 114 1119: Обращение возможного неопределенного свойства text через ссылку со статическим типом String .

В строчке 82 первого кадра вызывается функция complete_thumb_item(), у которой есть обязательный аргумент e:Event, на это как раз и ругается компилятор.

В сточке 114 вы пытаетесь обратиться к несуществующему свойству text переменной video_title_default типа String.

[mariamarfi]

http://www.youtube.com/watch?v=0S78NgWTx3k Part 1
http://www.youtube.com/watch?v=SWmPyZsFuY4 Part 2
http://www.youtube.com/watch?v=2YD-wJBSJ5M Part 3

Я новичок. Не судите меня строго, пожалуйста. Я всё ещё учусь. Кстати, я ничего не слышу и не понимаю, о чём говорят на роликах. Я глухая =(.
Кстати, я следовала по роликам и написала программу. Только не могу понять, а также разобраться с моими ошибками... Я написала всё также, что и на роликах...

Почему-то на роликах все сработало, а у меня ошибки... Я уже сверяла всё... Может, я что-то пропустила?...

[Hauts]

mariamarfi, для первой ошибки можно так:

function complete_thumb_item(e:Event = null):void
{
	for (i=0; i < total_items; i++)
	{
		mc = MovieClip(thumbnail_group.getChildByName("mediatutorial_thumb_" + i));
		mc.addEventListener(MouseEvent.MOUSE_OVER, tn_over);
		mc.addEventListener(MouseEvent.MOUSE_OUT, tn_out);
		mc.addEventListener(MouseEvent.CLICK, tn_click);
	}
}

Я добавил " = null" что означает, что этот аргумент опциональный.

Для второго варианта попробуйте так:

function tn_click(e: MouseEvent): void
{
	mc = MovieClip(e.target);
	current_no = parseInt(mc.name.slice(20,21));
	video_title_default = video_playlist[current_no].videoTitle;
 
	video_title.text = video_playlist[current_no].videoTitle;
	video_url = "video_folder/" + video_playlist[current_no].videoFile;
	gotoAndPlay(2);
 
}

mariamarfi, уроки, судя по всему, довольно бестолковые.

[mariamarfi]

Спасибо большое! Всё сработало!