Повторение звука

[greatilya]

Имеется код:

var snd:Sound = new Sound();
snd.load(new URLRequest("sound.mp3"));
var channel:SoundChannel = new SoundChannel();
snd.addEventListener(Event.COMPLETE, onLoadComplete, false, 0, true);
snd.addEventListener(Event.SOUND_COMPLETE, onSoundComplete, false, 0, true);
 
function onLoadComplete(evt:Event):void {
	//var localSnd:Sound = evt.target as Sound;
	channel = snd.play();
}
function onSoundComplete(evt:Event):void 
{ 
//channel.stop();
channel = snd.play(); 
}

Не могу понять почему не происходит повторение музыки.

Уже ошибочно писал в другую тему: http://flasher.ru/forum/showthread.php?t=136595

Заранее спасибо.

[E-mail]

Событие soundComplete отправляет объект класса SoundChannel, а не Sound

[greatilya]

Не могу понять что требуется, так не получается если заменть на это:

channel.addEventListener(Event.SOUND_COMPLETE, onSoundComplete);

Если не сложно дайте более подробные комментарии. еще раз извините.

[E-mail]

package 
{
	import flash.media.Sound;
	import flash.media.SoundChannel;
	import flash.events.Event;
	import flash.net.URLRequest;
 
	public class MyClass
	{
		public var snd:Sound;
		public var channel:SoundChannel;
 
		public function MyClass()
		{
			snd = new Sound();
			snd.addEventListener(Event.COMPLETE, completeHandler);
			snd.load(new URLRequest("sound.mp3"));
		}
		private function completeHandler(evt:Event):void
		{
			channel = snd.play();
			channel.addEventListener(Event.SOUND_COMPLETE, soundCompleteHandler);
		}
		private function soundCompleteHandler(evt:Event):void
		{
			channel.removeEventListener(Event.SOUND_COMPLETE, soundCompleteHandler);
			channel = snd.play();
			channel.addEventListener(Event.SOUND_COMPLETE, soundCompleteHandler);
		}
	}
}

как-то так

[greatilya]

Огромное спасибо!
Сам бы не догадался...