Как кешировать подгружаемые картинки?

[Nooob]

Всё просто. У тебя есть путь до картинки, создаешь хеш таблицу/словарь (Object/Dictionary) в качестве ключа путь, а значение BitmapData.
Когда нужна картинка спрашиваешь у хеша, есть ли такое значение по ключу. если нет, то грузишь её и после загрузки добавляешь в хеш и отдаешь нуждающемуся, если есть значение в хеше то создаешь Bitmap с этой BitmapData.

[grafillo!]

Сообщение от Nooob

Всё просто. У тебя есть путь до картинки, создаешь хеш таблицу/словарь (Object/Dictionary) в качестве ключа путь, а значение BitmapData.
Когда нужна картинка спрашиваешь у хеша, есть ли такое значение по ключу. если нет, то грузишь её и после загрузки добавляешь в хеш и отдаешь нуждающемуся, если есть значение в хеше то создаешь Bitmap с этой BitmapData.

О! Вот то что искал, а можешь скинуть пример кода?

[KBAC]

Храните в object'e или словаре соотношения url->BitmapData или Loader и проверяйте, если по такому url уже что-то есть, то не загружать

Ой, не дочитал до конца)

[grafillo!]

Сообщение от KBAC

Храните в object'e или словаре соотношения url->BitmapData или Loader и проверяйте, если по такому url уже что-то есть, то не загружать

Ой, не дочитал до конца)

А можно пример кода, как это реализовать?

[Nooob]

package
{
	import flash.display.Bitmap;
	import flash.display.BitmapData;
	import flash.display.Loader;
	import flash.display.LoaderInfo;
	import flash.display.Sprite;
	import flash.events.ErrorEvent;
	import flash.events.Event;
	import flash.events.IOErrorEvent;
	import flash.events.MouseEvent;
	import flash.net.URLRequest;
	import flash.utils.Dictionary;
 
	public class ImageChache extends Sprite
	{
		private const bitmapDataByURL:Object     = new Object();
		private const bitmapsByURL:Object        = new Object();
		private const urlByLoaderInfo:Dictionary = new Dictionary();
 
		public function ImageChache ()
		{
			stage.addEventListener(MouseEvent.CLICK, onClick);
		}
 
		private function onClick (event:MouseEvent):void
		{
			while (numChildren > 0)
			{
				removeChild(getChildAt(0));
			}
			addChild(getImage("http://www.flasher.ru/forum//image.php?u=32784&dateline=1321357870"));
		}
 
		public function getImage (url:String):Bitmap
		{
			var bitmap:Bitmap         = new Bitmap();
			var bitmapData:BitmapData = bitmapDataByURL[url];
			if (bitmapData == null)
			{
				var bitmaps:Vector.<Bitmap> = bitmapsByURL[url];
				if (bitmaps == null)
				{
					bitmaps = new Vector.<Bitmap>();
					bitmapsByURL[url] = bitmaps;
					bitmaps.push(bitmap);
 
					var loader:Loader = new Loader();
					loader.contentLoaderInfo.addEventListener(Event.COMPLETE, onLoadComplete);
					loader.contentLoaderInfo.addEventListener(IOErrorEvent.IO_ERROR, onLoadError);
					urlByLoaderInfo[loader.contentLoaderInfo] = url;
					loader.load(new URLRequest(url));
					return bitmap;
				}
				bitmaps.push(bitmap);
				return bitmap;
			}
			bitmap.bitmapData = bitmapData;
			return bitmap;
		}
 
		private function onLoadError (event:ErrorEvent):void
		{
			var loaderInfo:LoaderInfo = event.target as LoaderInfo;
			loaderInfo.removeEventListener(Event.COMPLETE, onLoadComplete);
			loaderInfo.removeEventListener(IOErrorEvent.IO_ERROR, onLoadError);
 
			trace(event.text);
		}
 
		private function onLoadComplete (event:Event):void
		{
			var loaderInfo:LoaderInfo = event.target as LoaderInfo;
			loaderInfo.removeEventListener(Event.COMPLETE, onLoadComplete);
			loaderInfo.removeEventListener(IOErrorEvent.IO_ERROR, onLoadError);
 
			var url:String              = urlByLoaderInfo[loaderInfo];
			var bitmapData:BitmapData   = (loaderInfo.content as Bitmap).bitmapData;
			var bitmaps:Vector.<Bitmap> = bitmapsByURL[url];
			for each (var bitmap:Bitmap in bitmaps)
			{
				bitmap.bitmapData = bitmapData;
			}
			bitmapDataByURL[url] = bitmapData;
 
			delete bitmapsByURL[url];
			delete urlByLoaderInfo[loaderInfo];
		}
	}
}

[caseyryan]

Nooob, неплохой вариант) Я обычно делал малость по-другому. А тут в любом случае получишь картинку и поставишь ее в нужное место, независимо от того, загружена она уже или нет