AS3 во внешнем файле

[Felicast]

грузить и исполнять *.as файл не получится
можно грузить и исполнять заранее скомпилированный файл *.swf

[Котяра]

Пример: dynamicCode.zip

package 
{
	import flash.display.Loader;
	import flash.display.LoaderInfo;
	import flash.display.Sprite;
	import flash.events.Event;
	import flash.net.URLRequest;
 
	/**
	 * ...
	 * @author k0t0vich
	 */
	public class Main extends Sprite 
	{
		private var loader:Loader = new Loader();
		private var code:ICode;
 
		public function Main():void 
		{
			if (stage) init();
			else addEventListener(Event.ADDED_TO_STAGE, init);
		}
 
		private function init(e:Event = null):void 
		{
			removeEventListener(Event.ADDED_TO_STAGE, init);
			// entry point
			// меняем урл, т.е. выбираем какой код подгружать
			var url:String = "code1.swf";
			loader.contentLoaderInfo.addEventListener(Event.COMPLETE, codeLoaded);
			loader.load(new URLRequest(url));	
		}
 
 
		private function codeLoaded(e:Event):void 
		{
			var loaderInfo:LoaderInfo = e.target as LoaderInfo;
			// выполняем код из загруженного спрайта
			code = (loaderInfo.content as ICode);
			trace(code.doCode(10)); // ->11	
		}
 
	}
 
}

package  
{
 
	/**
	 * Интерфейс класса кодов
	 * @author k0t0vich
	 */
	public interface ICode 
	{
		function doCode(value:int):Number;
	}
 
}

package  
{
	import flash.display.Sprite;
	import flash.events.Event;
 
	/**
	 * Спрайт с кодом 1
	 * @author k0t0vich
	 */
	public class Code1Sprite extends Sprite implements ICode
	{
 
		public function Code1Sprite() 
		{
 
		}
 
		public function doCode(value:int):Number
		{
			return (value + 1);
		}
 
	}
 
}

package  
{
	import flash.display.Sprite;
	import flash.events.Event;
 
	/**
	 * Спрайт с кодом 2
	 * @author k0t0vich
	 */
	public class Code2Sprite extends Sprite implements ICode
	{
 
		public function Code2Sprite() 
		{
 
		}
 
		public function doCode(value:int):Number
		{
			return (value + 2);
		}	
 
	}
 
}