Оптимизация с помощю Bitmap

[iNils]

Сообщение от goodguy

2) dispose() не занулит картинку. Она так и останется висеть в памяти, пока не занулишь еще и ссылку на нее.

dispose удаляет содержимое картинки из памяти.

[goodguy]

dispose удаляет содержимое картинки из памяти.

Да это понятно, но тем не менее, по пока на изображение есть хоть одна ссылка, оно так и будет занимать то количество памяти, которое и занимало до вызова dispose(). О чем, собственно, говорит отладчик во флешдевелоп.

[iNils]

Сообщение от goodguy

Да это понятно, но тем не менее, по пока на изображение есть хоть одна ссылка, оно так и будет занимать то количество памяти, которое и занимало до вызова dispose(). О чем, собственно, говорит отладчик во флешдевелоп.

Ничего подобного.
Простой тест.

package {
	/*    IMPORT             *///{ /
	import flash.display.*;
	import flash.events.*;
	//}
	public class TestDispose extends Sprite {
		/*  - VAR PRIVATE        *///{ /
		private var _bitmap:Bitmap = null;
		//}
		/*  * CONSTRUCTOR *      *///{ /
		public function TestDispose () {
			_bitmap = new Bitmap ()
			addChild (_bitmap)
			stage.addEventListener (MouseEvent.CLICK, onClick)
		}
		//}
		/*    EVENT              *///{ /
		private function onClick (event:MouseEvent):void {
			if (_bitmap.bitmapData == null) {
				_bitmap.bitmapData = new BitmapData (3000, 3000);
				trace ('new');
			} else {
				_bitmap.bitmapData.dispose ();
				trace ('dispose');
			}
		}
		//}
	}
}

При запуске отладчик показывает 5 кб
При new 40,8 кб
При dispose 5,6 кб

Можно воспользоваться System.totalMemory вместо профайлера, результат будет тот же.

[goodguy]

Такой тест не проводил.
А вот если сделать так:

package {
	import flash.display.Bitmap;
	import flash.display.Sprite;
 
	public class Test extends Sprite {
 
		[Embed(source = "image.png")] private var Img:Class;
		private var _image:Bitmap = new Img as Bitmap;
 
		public function Test() {
			addChild(_image);
		}
		public function clear():void {
			removeChild(_image);
			_image.bitmapData.dispose();
		}
	}
}

То после вызова clear() занимаемое картинкой количество памяти не поменятеся. + она так же будет болтаться в списке live objects
Однако, если сделать так:

package {
	import flash.display.Bitmap;
	import flash.display.Sprite;
 
	public class Test extends Sprite {
 
		[Embed(source = "image.png")] private var Img:Class;
		private var _image:Bitmap = new Img as Bitmap;
 
		public function Test() {
			addChild(_image);
		}
		public function clear():void {
			removeChild(_image);
			_image.bitmapData.dispose();
                                  _image = null;
		}
	}
}

То все ок. Объект будет уничтожен сборщиком мусора, и память освободится.

[iNils]

То после вызова clear() занимаемое картинкой количество памяти не поменятеся.

Меняется.

package {
	/*    IMPORT             *///{ /
	import flash.display.*;
	import flash.events.*;
	import flash.system.System;
	//}
	public class TestDispose extends Sprite {
		/*    CONSTANT           *///{ /
		[Embed(source='wpapers.jpg')]private var Img:Class;
		private var _bitmap:Bitmap = null;
		//}
		/*  * CONSTRUCTOR *      *///{ /
		public function TestDispose () {
			stage.addEventListener (MouseEvent.CLICK, onClick)
		}
		//}
		/*    EVENT              *///{ /
		private function onClick (event:MouseEvent):void {
			if (_bitmap == null) {
				_bitmap = new Img as Bitmap;
				addChild (_bitmap);
				trace (System.totalMemory);
			} else {
				removeChild (_bitmap)
				_bitmap.bitmapData.dispose ();
				trace (System.totalMemory);
			}
		}
		//}
	}
}

Старт: 6'725'632
Первый клик: 18'034'688
Второй клик: 6'979'584
Хотя ссылку не обнулял.

[goodguy]

Значит во флешдевелоп профайлер не обновляет данные о потребляемой картинкой памяти, пока объект полностью не удалится, или у меня что-то в нем не правльно настроено. Хз. Пару месяцев назад мне это просто выносило мозг, даже тему тут создавал. Но когда стал занулять ссылки, все быстренько стало подчищаться.

[alatar]

goodguy, не надо путать теплое с мягким. Bitmap != BitmapData. В вашем случае BitmapData уже уничтожена, а Bitmap жив, на него есть ссылки, ему можно приатачить новый BitmapData.