цвет курсора текстового поля

[TanaTiX]

Как изменить цвет курсора текстового поля? Есть ли такая возможность или для этого необходимо создавать курсор и его поведение вручную?
Заранее спасибо.

Upd. etc, спасибо за пример. Данная вещица интересовала на данный момент исключительно академически: есть или нет, true или false. Но если вдруг будет поставлена подобная задача обязательно обращусь за помощью к этому коду.

[udaaff]

Только в ручную, видимо...

[etc]

Из закромов:

function textInput(event:TextEvent):void {
    input.appendText(event.text);
    caretIndex++;
    updateCaret();
    event.preventDefault();
}
function updateCaret():void {
    var rect:Rectangle = input.getCharBoundaries(caretIndex - 1);
 
    if (!rect) {
        caret.x = 0;
        caret.y = input.height - 2;
    } else {
        caret.x = rect.x + rect.width;
        caret.y = rect.y;
    }    
    var m:TextLineMetrics = input.getLineMetrics(0);
    caret.graphics.clear();
    caret.graphics.lineStyle(0, 0xFF0000);
    caret.graphics.lineTo(0, m.height);
}
var caretIndex:uint = 0;
var dir:int = -1;
function enterFrame(event:Event):void {
    caret.alpha += dir * 0.1;
    if (caret.alpha < 0.01 || caret.alpha >= 0.99) dir *= -1;
}
function keyDown(event:KeyboardEvent):void {
    switch (event.keyCode) {
        case 8:
            caretIndex = caretIndex > 0 ? caretIndex - 1 : 0;
            input.text = input.text.substr(0, -1);
            this.updateCaret();
            break;
    }
}
var tf:TextField = new TextField();
tf.addEventListener(TextEvent.TEXT_INPUT, textInput);
tf.width = super.stage.stageWidth;
tf.height = super.stage.stageHeight;
tf.type = TextFieldType.INPUT;
tf.filters = [new BlurFilter(0, 0, 0)];
tf.alpha = 0;
tf.multiline = true;
var input:TextField = new TextField();
input.width = super.stage.stageWidth;
input.height = super.stage.stageHeight;
input.selectable = false;
input.mouseEnabled = false;
input.autoSize = TextFieldAutoSize.LEFT;
super.addChild(input);
super.addChild(tf);
super.stage.focus = tf;
var caret:Shape = new Shape();
super.addChild(caret);
super.stage.addEventListener(Event.ENTER_FRAME, enterFrame);
super.stage.addEventListener(KeyboardEvent.KEY_DOWN, keyDown);
updateCaret();

Допилите сами.