[7thsky™]

ну так и рисуй ручками, во флэше, в чем проблема? создаешь кнопку на таймлайне (лучше две), задаешь имя инстанса, например btn1 и btn2, во фрэйме пишешь

btn1.addEventListener (MouseEvent.CLICK,
	btnClickHandler, false, 0, true);

btn2.addEventListener (MouseEvent.CLICK,
	btnClickHandler, false, 0, true);

function btnClickHandler (evt:MouseEvent):void {
	var index:int = parseInt (evt.target.name.slice (3));
	
	Global.getInstance ().selectedSection = index;
}

код класса Global

package {
	
	import flash.events.*;
	
	public class Global 
	extends EventDispatcher {
		
		public static const SELECTED_SECTION_CHANGED:String = 'selectedSectionChanged';
		
		private var _selectedSection:int = -1;
		
		public function Global () {
		}
		
		public function get selectedSection ():int {
			return _selectedSection;
		}
		
		public function set selectedSection (value:int):void {
			if (_selectedSection != value) {
				_selectedSection = value;
				
				trace ('selectedSection: ' + value);
				dispatchEvent (new Event (SELECTED_SECTION_CHANGED));
			} // end if
		}
		
		private static var instance:Global = null;
		public static function getInstance ():Global {
			if (instance == null) {
				instance = new Global ();
			} // end if
			return instance;
		}
	}
}

в любом другом месте пишешь

Global.getInstance ().addEventListener (Global.SELECTED_SECTION_CHANGED, selectedSectionChangedHandler, false, 0, true);

function selectedSectionChangedHandler (evt:Event):void {
// тут реагируй на изменение как твоей душе угодно
}