Форум Flasher.ru

Форум Flasher.ru (http://www.flasher.ru/forum/index.php)
-   ActionScript 3.0 (http://www.flasher.ru/forum/forumdisplay.php?f=83)
-   -   Помогите понять строчку кода (http://www.flasher.ru/forum/showthread.php?t=213829)

zackscript 28.01.2017 16:34

Помогите понять строчку кода
 
Привет всем, я тысячакратно извиняюсь за тупой вопрос.
Ребят скажите как понять приведение типа такого характера:

Код AS3:

p = pool.getObject() as Point;

Дабы больше разъяснить, выкладываю весь код с одного сайта (возможно некоторые побывали там )):
Код AS3:

public final class ObjectPool
{
    private var pool:Vector.<Object>;
    private var counter:uint;
    private var className:Class;
 
    public function ObjectPool(className:Class, length:uint = 1)
    {
        this.className = className;
        pool = new Vector.<Object>(length);
 
        var i:uint = counter = length;
        //создадим начальный набор объектов
        while( --i > -1 )
            pool[i] = new className();
    }
 
    public function getObject():Object
    {
        if ( counter > 0 )
            return pool[ --counter ];
        // если объекты закончились
        // создаю объект и увеличивая длину массива
        pool.unshift( new className() );
        return pool[0];
    }
 
    public function releaseObject(value:Object):void
    {
        pool[ counter++ ] = value;
    }
 
    // необязательный метод для тестирования
    public function toString():String
    {
        return "Pool of " + className + " count = " + counter + "/" + pool.length;
    }
}

Здесь автор использует объект с непонятным мне приведением типа:

Код AS3:

var pool:ObjectPool = new ObjectPool(Point, 20);
trace(pool);
trace("---------");
for (var i:int = 0, p:Point; i < 40; i++)
{
    p = pool.getObject() as Point; // как здесь это работает ???
    p.x = Math.random() * 400;
    if(p.x > 300)
        pool.releaseObject(p);
    trace( pool.toString() );
}

Если я непонятно изложил свою проблему, попробую написать так:

ОбъектНекоегоКласса.какой-тоМетод () as Какой-тоТип; // вот как это работает ?

или же:
var _bit_map:Bitmap = _loader.content as Bitmap; // ?

ZackMercury 28.01.2017 17:04

В массив записывается набор экземпляров класса Point, однако сам класс совсем не знает, какой именно класс участвует в этом процессе. Именно поэтому в классе массив Object, под тип которого можно привести абсолютно что угодно.
Код AS3:

ОбъектНекоегоКласса.какой-тоМетод () as Какой-тоТип; // вот как это работает ?

метод ОбъектНекоегоКласса возвращает какой-то объект. В данном случае это
Цитата:

public function getObject():Object
{
if ( counter > 0 )
return pool[ --counter ];
// если объекты закончились
// создаю объект и увеличивая длину массива
pool.unshift( new className() );
return pool[0];
}
Где
Цитата:

private var pool:Vector.<Object>;
Но при этом этот объект не является экземпляром Object, а является его потомком.
В этом случае мы можем привести его тип к его истинному типу, которым он был до записи в Vector.<Object>.

Почему Point?
Потому, что мы передаём его в конструктор тут
Цитата:

var pool:ObjectPool = new ObjectPool(Point, 20);
Затем он проходит сюда
Цитата:

public function ObjectPool(className:Class, length:uint = 1)
{
this.className = className;
pool = new Vector.<Object>(length);

var i:uint = counter = length;
//создадим начальный набор объектов
while( --i > -1 )
pool[i] = new className();
}
Это значит, что Pool создаёт набор экземпляров класса, который мы передаём его в конструктор, записывает его в типизированный массив Object, и при вытаскивании нужно привести тип к истинному.

Object используется потому, что он является предком всех существующих и создаваемых вами классов. Можно привести тип любого экземпляра класса к Object.

Добавлено через 1 час 8 минут
Цитата:

var _bit_map:Bitmap = _loader.content as Bitmap;
_loader.content имеет также неопределённый тип: Loader может загружать как изображения(Bitmap), звуки(Sound), так и другие swf(Sprite, MovieClip)

zackscript 28.01.2017 18:13

так, ага...
Цитата:

В массив записывается набор экземпляров класса Point
А о каком Point здесь говорится о встроенном классе Point или обычный пользовательский класс ?

ZackMercury 28.01.2017 18:15

Возможны оба варианта. Зависит от того, что импортировать перед этим кодом
Код AS3:

var pool:ObjectPool = new ObjectPool(Point, 20);
trace(pool);
trace("---------");
for (var i:int = 0, p:Point; i < 40; i++)
{
    p = pool.getObject() as Point; // как здесь это работает ???
    p.x = Math.random() * 400;
    if(p.x > 300)
        pool.releaseObject(p);
    trace( pool.toString() );
}

Если ваш собственный класс - то получится пул из ваших пользовательских точек.
Код AS3:

import com.zackscript.tools.Point;
var pool:ObjectPool = new ObjectPool(Point, 20);
trace(pool);
trace("---------");
for (var i:int = 0, p:Point; i < 40; i++)
{
    p = pool.getObject() as Point; // как здесь это работает ???
    p.x = Math.random() * 400;
    if(p.x > 300)
        pool.releaseObject(p);
    trace( pool.toString() );
}

Или встроенныx:
Код AS3:

import flash.geom.Point;
var pool:ObjectPool = new ObjectPool(Point, 20);
trace(pool);
trace("---------");
for (var i:int = 0, p:Point; i < 40; i++)
{
    p = pool.getObject() as Point; // как здесь это работает ???
    p.x = Math.random() * 400;
    if(p.x > 300)
        pool.releaseObject(p);
    trace( pool.toString() );
}


zackscript 28.01.2017 18:46

Так ну теперь кое-что стало понятно, вот тут: pool[i] = new className(); он пока ни знает какой объект класса создает , так...
А здесь: p = pool.getObject() as Point; - заставляет вернуть в место Object тип Point (мой/пользовательский)

ZackMercury 28.01.2017 18:51

Нет, он возвращает Object, который на самом деле Point, и этим
Код AS3:

pool.getObject() as Point

вы говорите машине исполнения, что возвращаемый объект на самом деле не Object, а его потомок, и вы хотите использовать его как Point(вызывать методы и свойства Point у этого объекта).
Всё это написано в документации, товарищ.

zackscript 28.01.2017 18:55

Спасибо товарищ ) теперь ясно.
Цитата:

Всё это написано в документации, товарищ.
Тока где ?! (риторический вопрос)

ZackMercury 28.01.2017 19:08

Цитата:

Тока где ?!
http://help.adobe.com/ru_RU/FlashPla...rators.html#as
http://help.adobe.com/ru_RU/ActionSc...0204-7f8a.html
Немного недописано, действительно, что оператор на самом деле делает. Но я точно помню, что где-то читал, либо в книге Колина Мука, либо в документации)

zackscript 28.01.2017 19:15

Код AS3:

public var myArray:Array = ["one", "two", "three"];
trace(myArray as Array);  // one,two,three
trace(myArray as Number); // null
trace(myArray as int);    // null

Данный пример - это просто убожество.
Хотя много раз видел этот пример.

Добавлено через 35 минут
ZackMercury, ещё один вопрос , если тип возвращаемого объект я присвою заранее то и не нужно приведение ?
Код AS3:

public function getObject():Point
    {
        if ( counter > 0 )
            return pool[ --counter ];
        // если объекты закончились
        // создаю объект и увеличивая длину массива
        pool.unshift( new className() );
        return pool[0];
    }

p.s. возможности тестирования пока нет )

ZackMercury 28.01.2017 22:41

тогда
Код AS3:

public function getObject():Point
    {
        if ( counter > 0 )
            return pool[ --counter ] as Point;
        // если объекты закончились
        // создаю объект и увеличивая длину массива
        pool.unshift( new className() );
        return pool[0] as Point;
    }



Часовой пояс GMT +4, время: 23:28.

Copyright © 1999-2008 Flasher.ru. All rights reserved.
Работает на vBulletin®. Copyright ©2000 - 2026, Jelsoft Enterprises Ltd. Перевод: zCarot
Администрация сайта не несёт ответственности за любую предоставленную посетителями информацию. Подробнее см. Правила.