package 

{

        import flash.display.Sprite;

        import flash.events.Event;

        import flash.display.StageAlign;

        import flash.display.StageScaleMode;

        import flash.events.MouseEvent;

        import flash.net.URLLoader;

        import flash.net.URLLoaderDataFormat;

        import flash.net.URLRequest;

 

        public class Main extends Sprite 

        {

                private var _blocksArray:Array = new Array();

 

                public function Main():void 

                {

                        if (stage) init();

                        else addEventListener(Event.ADDED_TO_STAGE, init);

                }

 

                private function init(e:Event = null):void 

                {

                        removeEventListener(Event.ADDED_TO_STAGE, init);

                        stage.align = StageAlign.TOP_LEFT;

            stage.scaleMode = StageScaleMode.NO_SCALE;

                        stage.showDefaultContextMenu = false;

                        // entry point

                        var dataLoader:URLLoader = new URLLoader();

                        dataLoader.dataFormat = URLLoaderDataFormat.TEXT;

                        var request:URLRequest = new URLRequest("http://somesite.ru/data.php");

                        dataLoader.addEventListener(Event.COMPLETE, dataCompleteHandler);

                        dataLoader.load(request);

                }

 

                private function dataCompleteHandler(event:Event):void 

                {

                        var data:XML = new XML( (event.currentTarget as URLLoader).data );

                        var topics:XMLList = data.topic;

                        var blocksContainer:Sprite = new Sprite();

                        addChild(blocksContainer);

                        blocksContainer.x = blocksContainer.y = 50;

 

                        var blockHeight:Number = 0;

                        for (var i:uint = 0; i < topics.length(); i++)

                        {

                                var block:InfoBlock = new InfoBlock(topics[i]);

                                block.y = blockHeight;

                                blockHeight += block.height + 1;

                                block.addEventListener(MouseEvent.CLICK, infoBlockClickHandler);

                                blocksContainer.addChild(block);

                                _blocksArray.push(block);

                        }

 

                }

 

                private function infoBlockClickHandler(event:MouseEvent):void 

                {

                        var blockC:InfoBlock = event.currentTarget as InfoBlock;

                        blockC.hiden = !blockC.hiden;

                        var blockHeight:Number = 0;

                        for (var i:uint = 0; i < _blocksArray.length; i++)

                        {

                                var block:InfoBlock = _blocksArray[i];

                                if (block !== blockC)

                                {

                                        if (!block.hiden) block.hiden = true;

                                }

                                block.y = blockHeight;

                                blockHeight += block.height + 1;

                        }

                }

 

        }

 

}