Форум Flasher.ru - Передача значения переменной из одного класса в другой

Форум Flasher.ru (http://www.flasher.ru/forum/index.php)

- ActionScript 3.0 (http://www.flasher.ru/forum/forumdisplay.php?f=83)

Передача значения переменной из одного класса в другой

До сих пор находил все ответы через поиск, но тут какой-то затыр. Сдаюсь. Хоть и вопрос простой.

Ситуация: есть XML файл, из которого загружаются данные классом LoadXML. Есть основной класс gallery, куда надо передать эти данные.

В файле test.fla прописан класс actions.gallery, лежащий в соответствующей папке. В gallery импортирован actions.LoadXML.

LoadXML:

Код AS3:

package actions{

 

        import flash.display.*;

        import flash.events.*;

        import flash.net.*;

        import flash.utils.*;

 

        public class LoadXML extends Sprite {

 

                public var imgLinks:Array; //задаю переменную, чтоб впоследствии обратиться к ней из класса gallery

                public var example:XML = new XML();

 

                public function LoadXML() {

                        var loader:URLLoader = new URLLoader();

                        loader.dataFormat=URLLoaderDataFormat.TEXT;

                        loader.addEventListener(Event.COMPLETE, onComplete);

                        loader.load(new URLRequest("example.xml"));

                }

 

                public function onComplete (event:Event):void {

                        var example:XML=XML(event.target.data);

                        var imgLinks1 = new Array();

                        for (var i:int=0; i<example.image.length(); i++){

                                imgLinks1[i] = example.image[i];

                        }

                        imgLinks = imgLinks1;

                        //на этом этапе данные выводятся трейсом без ошибок

                }

        }

}

gallery:

Код AS3:

package actions {

 

        import flash.display.*;

        import flash.events.*;

        import flash.text.*;

        import flash.net.*;

        import actions.LoadXML;

 

        public class gallery extends Sprite {

 

                public var loadXML:LoadXML;

 

                public function gallery(){

                        trace(loadXML.imgLinks); //

                }

        }

}

выводит ошибку:

Код:

TypeError: Error #1009: Cannot access a property or method of a null object reference.

        at actions::gallery()

Что я делаю не так? Можно достичь цели и другим способом, если объясните в общих чертах. Самому знаний пока что не хватает. Заранее спасибо ;)

Код AS3:

public var loadXML:LoadXML;

 

public function gallery(){

        loadXML = new LoadXML();

        trace(loadXML.imgLinks); //

}

Косяк, да. Эта ошибка, разумеется, теперь не выводится. Проблема в другом. trace(loadXML.imgLinks) почему-то возвращает null.

Значит на момент чтения переменной, событие Event.COMPLETE ещё не произошло.

как по мне класс с названием LoadXML делает лишнюю работу — парсит данные, складывает что-то в массив. это никак не лепится с абстрактным названием "LoadXML".
если это весь код класса, то он мне видится излишним — всю его логику запросто можно затулить внутрь gallery.
ну а если все же надо разделить, то лучше LoadXML наследовать от URLLoader и подписываться на его COMPLETE, после чего "приводить в действие" gallery (а лучше Gallery)

На его комплит подписываться не всегда удобно, т.к. парсинг сложного XML лучше засовывать внутрь класса. Как по мне, так лучше отнаследовать от EventDispatcher и диспетчеризовывать кастомный ивент, когда уже все отгрузилось. Снаружи будет выглядеть как уже красивый, сформированный, например, объект.

в целом — вариант. но в данном случае не знаю... дополнительное событие. да и парсинг не такой тяжелый. все-таки в конкретной задаче, на мой взгляд, LoadXML extends URLLoader, а Gallery создается с передачей в него загруженного XML по факту COMPLETE.
а еще правильней создавать Gallery с передачей не XML, а уже готового массива imgLinks, чтобы не привязывать класс к конкретному способы получения списка URL-ов (когда-то это будет не XML, возможно)

public var loadXML:LoadXML;
----->
public static loadXML:loadXML = new loadXML();
должно помочь

Спасибо всем, кто откликнулся. Вы мне очень помогли. Правда.

Zebestov, с одной стороны да. Но суть в том, что я только начал изучать АS3, и мне почему-то показалось, что удобнее будет держать описания отдельных функций в отдельных файлах. Как минимум, это неплохие модули на будущее. Хотя может я неправ — с опытом пойму.

3p.station, не работает. E-mail правильно сказал: "на момент чтения переменной, событие Event.COMPLETE ещё не произошло".

Сайлас, спасибо. Сделал как раз диспатчером:

LoadXML:

Код AS3:

package actions {

 

   import flash.events.*;

   import flash.display.*;

   import flash.net.URLLoader;

   import flash.net.URLRequest;

 

   public class LoadXML extends Sprite { //Sprite включает в себя EventDispatcher

 

      public var xmlData:XML;

      public static var LOADED:String = "loadedXML";

 

      public function LoadXML(file:String):void {

         var loader:URLLoader = new URLLoader(new URLRequest(file));

         loader.addEventListener(Event.COMPLETE, loadedXML);

      }

 

      private function loadedXML(e:Event):void

      {

         xmlData = new XML(e.target.data);

         dispatchEvent(new Event(LoadXML.LOADED,true));

      }

   }

}

Gallery:

Код AS3:

package actions{

 

        import flash.display.*;

        import flash.events.*;

        import flash.text.*;

        import flash.net.*;

 

        public class gallery extends Sprite {

 

                public function gallery():void {

                        var xmlHolder:LoadXML=new LoadXML("example.xml");

                        xmlHolder.addEventListener(LoadXML.LOADED,handlerXmlLoaded);

                }

                private function handlerXmlLoaded(event:Event):void {

                        var example:XML=XML(event.target.xmlData);

                        var imgLinks = new Array();

                        for (var i:int=0; i<example.image.length(); i++){

                                imgLinks[i] = example.image[i];

                        }

                        trace (imgLinks);

                }

        }

}