package 

{

        import flash.display.Graphics;

        import flash.display.Sprite;

        import flash.events.MouseEvent;

        import flash.geom.Point;

 

        /**

         * ...

         * @author gbee

         */

        public class TreeTest extends Sprite 

        {

                 private static const VGAP:int = 15;

                private static const HGAP:int = 50;

                private var _levelsOffset:Array;

 

                private var _g:Graphics;

                public function TreeTest() 

                {

                        super();

 

                        var spr:Sprite = new Sprite();

                        spr.graphics.beginFill(0, 0.4);

                        spr.graphics.drawRect(800, 0, 100, 40);

                        spr.addEventListener(MouseEvent.CLICK, refresh);

                        addChild(spr);

                        refresh();

                }

 

                private function refresh(event:MouseEvent = null):void

                {

                        _g = graphics;

                        _g.clear();

                        _g.beginFill(0x008800);

                        _g.lineStyle(1, 0x004400);

                        _levelsOffset = [0, 0, 0, 0, 0, 0, 0, 0, 0];

                        drawTree(generateTree(5, 3), 0);

                }

 

                private function generateTree(maxChilds:int, level:int):TreeNode

                {

                        var childsCount:int = int(Math.random() * maxChilds);

                        var node:TreeNode = new TreeNode();

                        if (level == 0)

                                return node;

                         for (var i:int = 0; i < childsCount; i++)

                                node.children.push(generateTree(maxChilds, level - 1));

                        node.count = childsCount;

                        return node;

                }

 

 

                private function drawTree(node:TreeNode, level:int):Number

                {

                        var levelY:Number = 0; 

                        if (node.count)

                        {

                                var linesY:Array = []; //массив Y для рисования связей.

                                for each(var child:TreeNode in node.children)

                                {

                                        var cY:Number = drawTree(child, level + 1);

                                        levelY += cY;

                                        linesY.push(cY);

                                }

                                _levelsOffset[level + 1] += VGAP;

 

                                levelY = levelY / node.count;

 

                                if(levelY - _levelsOffset[level] >= VGAP)

                                        _levelsOffset[level] = levelY;

                                else

                                {

                                        _levelsOffset[level] += VGAP;

                                        levelY = _levelsOffset[level];

                                }

 

                                //Рисуем связи

                                for each(cY in linesY)

                                {

                                        _g.moveTo(HGAP * level, levelY);

                                        _g.lineTo(HGAP * (level + 1), cY);

                                }

                        }

                        else

                        {

                                levelY = _levelsOffset[level]; 

                                _levelsOffset[level] += VGAP;

                                //Запрещаем рисовать ноды чужих детей выше себя. Но тут надо подумать в примере не запрещено.

                                if(_levelsOffset[level + 1] < _levelsOffset[level])

                                        _levelsOffset[level + 1] = _levelsOffset[level];

                        }

 

                        //Рисуем ноду

                        _g.drawCircle(HGAP * level, levelY, 5);

                        return levelY;

                }

 

 

        }

 

}

package 

{

        /**

         * ...

         * @author gbee

         */

        public class TreeNode 

        {

                public var children:Array = [];

                public var count:int = 0;

                public function TreeNode() 

                {

 

                }

 

        }

 

}

{

    "root": {

        "branch_1": {

            "leaf_1": "Hello world"

        },

        "leaf_1": "Hello world",

        "leaf_2": "Hello world",

        "branch_2": {

            "leaf_1": "Hello world",

            "leaf_2": "Hello world",

            "leaf_3": "Hello world",

            "leaf_4": "Hello world",

            "leaf_5": "Hello world"

        },

        "branch_3": {

            "leaf_1": "Hello world",

            "leaf_2": "Hello world",

            "leaf_3": "Hello world",

            "leaf_4": "Hello world",

            "leaf_5": "Hello world",

            "leaf_6": "Hello world"

        },

        "leaf_3": "Hello world"

    }

}

<root>

    <branch>

        <leaf/>

    </branch>

    <leaf/>

    <leaf/>

    <branch>

        <leaf/>

        <leaf/>

        <leaf/>

        <leaf/>

        <leaf/>

    </branch>

    <branch>

        <leaf/>

        <leaf/>

        <leaf/>

        <leaf/>

        <leaf/>

        <leaf/>

    </branch>

    <leaf/>

</root>

public class Node

{

    // массив детей, которые могут иметь своих детей и т.д.

    // может быть пустым

    public var children:Vector.<Node>;

 

    // данные, которые мы хотим хранить в узле дерева

    // может быть null

    public var info:String;

 

    public function Node(info:String = null)

    {

        this.children = new Vector.<Node>();

        this.info = info;

    }

}

var parent:Node = new Node("I'm a parent!");

var child:Node = new Node("I'm a child!");

 

parent.children.push(child);

public class NodeView extends Sprite

{

    private var _data:Node;

    private var _textView:TextField;

 

    public function NodeView(data:Node)

    {

        super();

 

        _data = data;

 

        this.draw();

    }

 

    // тут мы рисуем что-то, что отображает наши данные

    // так как в наши данные входит текст, то рисуем текстовое поле

    // а раз уж у нас есть еще и дети - сразу создаем отображения детей

    // "по образу и подобию" =)

    private function draw():void

    {

        _textView = new TextField();

        _textView.text = _data.info;

 

        for each (var childData:Node in _data.children)

        {

            var childView:NodeView = new NodeView(childData);

 

            // выравниваем детишек друг относительно друга

            childView.x = ...;

            childView.y = ...;

 

            // и добавляем в список отображения

            super.addChild(childView);

        }

    }

}

А не начинает нападать на автора, увидев незнакомые обозначения.