Форум Flasher.ru - Как сделать "искатель" в Плейбаре FLV плеера?

Форум Flasher.ru (http://www.flasher.ru/forum/index.php)

- ActionScript 1.0/2.0 (http://www.flasher.ru/forum/forumdisplay.php?f=93)

- - Как сделать "искатель" в Плейбаре FLV плеера? (http://www.flasher.ru/forum/showthread.php?t=112707)

Как сделать "искатель" в Плейбаре FLV плеера?

То есть временная шкала (она у меня уже есть) и по ней едет полоска проигрывания.

Мне нкжно сделать искатель. Т.е. чтобы по плейбару куда кликнешь, что-бы с того места начинается проинрывание.

Плеер:

Код:

// Stream FLV-player by Jonathan

// Разрешение видео - 320 x 240



var src:String = "letstalk.flv";



var flv_connect:NetConnection = new NetConnection();

flv_connect.connect(null);

var motionStream:NetStream = new NetStream(flv_connect);

var soundControll:Sound = new Sound(_level0);

var duration:Number = 0;

// длина ролика. ее мы будем получать по событию onMetaData

var seeker:Number = null;

// переменная для setInterval - для ускорения перемотки

var timePressed:Number = 0;

// таймер фиксирующий время нажатия клавиши перемотки

var onTheRun:Boolean = false;

// состояние плеера - проигрывается видео или нет

//////////Чтобы проигрывать видео необходимо создать экземпляр типа Video (Делается это в библиотеке)

motion_mc.motion_vid.attachVideo(motionStream);

motionStream.setBufferTime(2);

/// Указывает сколько секунд видео должно загрузиться чтобы началось воспроизведение. В процессе проигрывания, если первые 2 секунды уже проигрались, а вторая порция еще не подгрузилась происходит остановка, до тех пор пока не подгрузятся следубщие 2 секунды.

motionStream.onMetaData = function(meta:Object):Void  {

        duration = meta.duration;

        /*событие возникает, когда плеер связывается с видеоФайлом, и получает от него Мета_данные в виде объекта.

        Чтобы трассировать эти данные необходимо раскомментировать код.*/

        //for (var prop in meta) {

        //        trace(prop+" = "+meta[prop]);

        //}

};

motionStream.onStatus = function(motion_status:Object):Void  {

        //for(var prop in motion_status) {

        //trace(prop + ": "+motion_status[prop]);

        //};

        //// Событие помогает отслеживать состояния воспроизведения - ошибки загрущки, остановку, начало, перемотку - читаем хелп, там все написано. Вот тут возможен момент - если готовить flv  в Макромедиа Флеш8Видео энкодере - и подрезать там длину ролика - то это неблагоприятно сказывается на статусе СТОП. Вывод - не резать длину ролика в энкодере.

        if (motion_status.code == "NetStream.Play.Stop") {

                motionStream.seek(duration);

                motionStream.pause(true);

                play_btn._visible = true;

                pause_btn._visible = false;

        }

};

/*****КНОПКИ*****/

//PLAY

play_btn.onEnterFrame = function() {

  if(this.direct) this.nextFrame();

  else this.prevFrame();

}

play_btn.onRollOver = function() {

        this.direct = true;

}

play_btn.onRollOut = function() {

this.direct = false; 

}

play_btn.onRelease = function():Void  {

        this._visible = false;

        pause_btn._visible = true;

        if (onTheRun) {

                if (vt_mc._width == 320) {

                        motionStream.seek(0);

                }

                motionStream.pause(false);

        } else {

                onTheRun = true;

                motionStream.play(src);

        }

};

//PAUSE

pause_btn.onEnterFrame = function() {

  if(this.direct) this.nextFrame();

  else this.prevFrame();

}

pause_btn.onRollOver = function() {

        this.direct = true;

}

pause_btn.onRollOut = function() {

this.direct = false; 

}

pause_btn.onRelease = function():Void  {

        this._visible = false;

        play_btn._visible = true;

        motionStream.pause(true);

};

//STOP

stop_btn.onEnterFrame = function() {

  if(this.direct) this.nextFrame();

  else this.prevFrame();

}

stop_btn.onRollOver = function() {

        this.direct = true;

}

stop_btn.onRollOut = function() {

this.direct = false; 

}

stop_btn.onRelease = function():Void  {

        motionStream.seek(0);

        onTheRun = false;

        pause_btn._visible = false;

        play_btn._visible = true;

        motionStream.close();

        motion_mc.motion_vid.clear();

};

rew_btn.onPress = function():Void  {

        clearInterval(seeker);

        timePressed = 0;

        seeker = setInterval(changePos, 100, -2);

};

fwd_btn.onPress = function():Void  {

        clearInterval(seeker);

        timePressed = 1;

        seeker = setInterval(changePos, 50, 1);

};

fwd_btn.onRelease = rew_btn.onRelease=function ():Void {

        clearInterval(seeker);

        timePressed = 1;

};

//////////seek

function changePos(dir:Number):Void {

        timePressed++;

        dir *= Math.ceil(timePressed/10);

        var dest:Number = motionStream.time+dir;

        if (dest<0) {

                dest = 0;

        }

        if (dest>duration) {

                dest = duration;

        }

        motionStream.seek(dest);

}

///////////////// volume

volumes.vd_mc.onPress = function():Void  {

        this.startDrag(false, 1, 5, 44, 5);

        this.onMouseMove = changeVolume;

};

volumes.vd_mc.onRelease = volumes.vd_mc.onReleaseOutside=function ():Void {

        this.stopDrag();

        delete this.onMouseMove;

};

function changeVolume():Void {

        var val:Number = Math.floor((this._x-7)*2.7);

        soundControll.setVolume(val);

        this._parent.vi_mc._x = this._x;

        updateAfterEvent();

        if (this._x < 2) {

                _root.vol_ico.gotoAndStop(2);

        }

        if (this._x > 1) {

                _root.vol_ico.gotoAndStop(1);

        }

        

}

////// инит графики

vt_mc._width = 0;

// vt - индикатор времени 

vl_mc._width = 0;

// vl - индикатор загруженного контентая

motion_mc.onEnterFrame = function():Void  {

        var proc:Number = Math.floor(motionStream.bytesLoaded/motionStream.bytesTotal*320);

        vl_mc._width = proc<320 ? proc : 320;

        var timer:Number = Math.ceil(motionStream.time/duration*320);

        vt_mc._width = timer<320 ? timer : 320;

};

//volumes._y = 256;

volumes.vi_mc.setMask(volumes.vm_mc);

pause_btn._visible = false;

Креплю исходник.

см. NetStream.seek

О! Здорово! А как мне проследить куда именно тыкнул юзер? Что мне нужно сздать в качестве полосы, по которой тыкает юзер? Клип чтоли какой-то? Не доходит до меня...

клип вполне подойдет..

юзер тычет обычно в точку с координатами _xmouse, _ymouse

А как бы это написать? Всмысле как будет выглядеть

if (клацнул на _xmouse=7, _ymouse=15) {
NetStream.seek(percent);
}

в хелп заглянуть не пробовал ?
по форуму опять же поискать как отследить нажатие..

жалко канеш, что "Stream FLV-player by Jonathan" может не состояться из-за такой ерунды, но обсуждать здесь азы как-то не с руки..

Цитата:

Stream FLV-player by Jonathan

:)

Да лажу я, лажу. Уже что-то получасться даже стало :)

Код:

....onRelease = function() {

  var percent:Number = (this._xmouse/this._width)*100;

  ....seek(percent);

}

Немного не так!

Код:

seek();

Указывается не в процентах, а в секундах! Написал вот так:

Код:

_root.sledak.onRelease = function() {

        var number_one:Number = this._xmouse/this._width;

        var number_two:Number = duration*number_one;

         motionStream.seek(number_two);

}

Расшифрую код:
duration - это длина видео, полученная из onMetaData (У меня это 40.464 секунды)
Остальное вроде понятно.

Теперь заработало, но не так как хотелось бы. Есть небольшая неточность!
Почему-то когда тыкаешь в некоторые точки определенные, в моем варианте их 4 это:
1) x: ≈ 55
2) x: ≈ 130
3) x: ≈ 212
4) x: ≈ 295
То все прекрасно работает. Видео переходит. Но если не попадаешь в эти 4 точки, то как не крути, воспроизведение прыгает на x координату одной из этих 4-х точек, в увеличительном порядке. Почему так происходит? Как с этим бороться?

Эх... И почему я не учил математику в школе? Дурак...

так и должно быть: seek ставит воспроизведение на ближайший к переданному в параметре времени ключевой кадр
стало быть в твоем flv их всего 4
попробуй на других примерах или пережми этот с другой частотой кейфреймов и все увидишь

Ну да. Когда более длинное виде вставляешь, то все гуд! Спасибо.

А не подскажете, как можно сменить надписи в плеере когда жмякаешь правой мышькой? Или в таком это нельзя?

пункты "настройки" и "о программе" будут всегда!

Джонатан! и Все остальные флэшеры!! Подскажите пожалуйста какие изменение нужно внести в скрипт этого проигрывателя что бы воспроизведение этого .flv файла начиналось автоматически, а не после нажатия на кнопку PLAY, как это работает сейчас!

Очень прошу - Помогите!
Своими силами проблему решить не удалось.. ((

toha20072008, создайте свою тему.