Реализация Fluent interfaces

Код AS3:

package 
{
	import flash.display.Sprite;
	import flash.events.Event;
	import ru.k0t0vich.fluent.Unit;
	import ru.k0t0vich.fluent.UnitList;
 
	/**
	 * Тестоый пример
	 * @author k0t0vich
	 */
	public class Main extends Sprite 
	{
 
		public function Main():void 
		{
			if (stage) init();
			else addEventListener(Event.ADDED_TO_STAGE, init);
		}
 
		private function init(e:Event = null):void 
		{
			removeEventListener(Event.ADDED_TO_STAGE, init);
			// entry point
 
			//Создаем список юнитов
			var enemies:UnitList = new UnitList();
 
			// Заполняем
			for (var i:int = 0; i < 10; i++) 
			{
				var unit:Unit = new Unit(i,i*10);
				enemies.push(unit);
			}
			// весь список
			trace("TOTAL: " + enemies);
			// выполняем
			// все враги выше 2 уровня и высотой меньше 50 стреляют оружием 1 типа с частотой 1.
			enemies.isLevelGreater(2).isZLower(50).doShoot(1, 10);
 
			// выделяем группу врагов старше 8 уровня
			var bigEnemies:UnitList = enemies.isLevelGreater(8);
 
			// список больших врагов
			trace(" Big: " +bigEnemies);
 
		}
 
	}
 
}

Код AS3:

package ru.k0t0vich.fluent 
{
 
	/**
	 * 
	 * @author k0t0vich
	 */
	public class UnitList
	{
		private var unitList:Array;
 
		public function UnitList($unitList:Array=null) 
		{
			if ($unitList) unitList = $unitList;
			else unitList = [];
 
		}
 
 
		/**
		 * 
		 *		Конкретные методы сортировки
		 */
 
 
		/**
		 * @param	z
		 * @return
		 */
		public function isZLower(z:int):UnitList
		{
 
			var retUnitList:UnitList = new UnitList();
			var len:int = unitList.length;
			for (var i:int = 0; i < len; i++) 
			{
				var unit:IUnit = unitList[i];
				/**
				 * выражение для добавления в список
				 */
				if (unit.z < z)
				retUnitList.push(unit)
			}
 
			return retUnitList;
 
		}
 
 
 
		public function isLevelGreater(level:int):UnitList
		{
			var retUnitList:UnitList = new UnitList();
			var len:int = unitList.length;
			for (var i:int = 0; i < len; i++) 
			{
				var unit:IUnit = unitList[i];
				/**
				 * выражение для добавления в список
				 */
				if (unit.level > level)
				retUnitList.push(unit)
			}
 
			return retUnitList;
		}
 
 
		/**
		 * Конкретный метод - окончание выражения
		 * @param	type
		 * @param	f
		 */
		public function doShoot(type:int,f:int):void
		{
			var len:int = unitList.length;
				for (var i:int = 0; i < len; i++) 
				{
					var unit:IUnit = unitList[i];
					unit.doShoot(type, f);
				}
		}
 
		/**
		 * Композиционные методы для массива
		 * TODO: добавить остальные
		 */
		public function push(unit:IUnit):UnitList
		{
			unitList.push(unit);
			return this;
		}
 
		public function pop(unit:IUnit):IUnit
		{
 
			return unitList.pop() as IUnit;
		}
 
 
		public function toString():String
		{
			return String(unitList);
		}
 
	}
 
}

Код AS3:

package ru.k0t0vich.fluent 
{
	import ru.k0t0vich.fluent.IUnit;
 
	/**
	 * ...
	 * @author k0t0vich
	 */
	public class Unit implements IUnit
	{
		private var _level:int;
		private var _z:int=100;
 
		public function Unit($level:int=1,$z:int=0) 
		{
			level = $level;
			z = $z;
		}
 
		public function doShoot(type:int, f:int):void
		{
			trace("Unit.doShoot >  level:"+ this.level+" z:"+z);
		}
 
		public function get level():int { return _level; }
 
		public function set level(value:int):void 
		{
			_level = value;
		}
 
		public function get z():int { return _z; }
 
		public function set z(value:int):void 
		{
			_z = value;
		}
		public function toString():String
		{
			return ("[Unit  level:"+ this.level+" z:"+z+"]");
		}
	}
 
}

Код AS3:

package ru.k0t0vich.fluent 
{
 
	/**
	 * ...
	 * @author k0t0vich
	 */
	public interface IUnit 
	{
		function doShoot(type:int, f:int):void;
		function get z():int;
		function get level():int;
	}
 
}

Код AS3:

greater(field:String,value)
lower(field:String,value)
with(field:String,value)
range(field:String,value1,value2)
where(????), select(???)

Код AS3:

enemies.greater(Unit.LEVEL,5)

Код AS3:

enemies.isLevelGreater(5)

Код AS3:

CustomFluentScript (hero,enemies)

Код AS3:

render()