Тестовый сокет-сервер для Windows

Код AS3:

package chat 
{
 
	/**
	 * ...
	 * @author k0t0vich
	 */
	public class Chat extends Sprite
	{
		private var urlLoader:URLLoader;
		private var configManager:ConfigManager;
		private var socketConnector:XMLSocketConnector = new XMLSocketConnector();
                // форматы сокета
		//private var socketConnector:SocketConnector = new SocketConnector();
		//private var socketConnector:ProtoBufConnector = new ProtoBufConnector();
                // гуй чата
		private var chatInput:ChatInput;
 
		public function Chat() 
		{
			if (stage) init();
			else addEventListener(Event.ADDED_TO_STAGE, init);
		}
 
		private function init(e:Event=null):void 
		{
			removeEventListener(Event.ADDED_TO_STAGE, init);
			// поле чата и сообщений.
			addChild(new Output());
			chatInput = new ChatInput();
			addChild(chatInput);
			chatInput.addEventListener(DataEvent.DATA, sendToChat);
 
			loadConfig();
		}
 
		private function sendToChat(e:DataEvent):void 
		{
			socketConnector.send(e.data);
		}
 
		public function loadConfig():void
		{
			urlLoader = new URLLoader(new URLRequest("config.xml"));
			urlLoader.addEventListener(Event.COMPLETE, onLoadConfig);
		}
 
		private function onLoadConfig(e:Event):void 
		{
			configManager = new ConfigManager(XML(urlLoader.data));
			socketConnector.init(configManager);
			socketConnector.addEventListener(DataEvent.DATA, onSocketData);
			socketConnector.connect();
		}
 
		private function onSocketData(e:DataEvent):void 
		{
			Output.trace("message > " + e.data);
		}
 
	}
 
}

Код AS3:

package server
 
	/**
	 * ...
	 * @author k0t0vich
	 */
	[Event(name="data", type="flash.events.DataEvent")]
	public class XMLSocketConnector extends EventDispatcher
	{
		private var configManager:ConfigManager;
		private var serverHost:String;
		private var serverPort:int;
		private var socket:XMLSocket;
		private var socketPolicyPort:int = 843;
		private var timer:Timer;
		private var session:String=null;
 
		public function XMLSocketConnector() 
		{
			super();
		}
 
		/**
		 * 
		 * @param	configManager
		 */
		public function init(configManager:ConfigManager):void	{
			this.configManager = configManager;
			serverHost = configManager.serverHost;
			serverPort = int(configManager.serverPort);
			socketPolicyPort = serverPort;
		}
 
		public function connect():void	{
			Output.trace("ServerConnector.connect");
			System.useCodePage = true;
			//Security.loadPolicyFile("xmlsocket://"+serverHost + ":" + socketPolicyPort);
			timer = new Timer(10, 1);
			timer.addEventListener(TimerEvent.TIMER, tryConnect);
			timer.start();
		}
 
 
		//--------------------------tryConnect---------------------------------------
		private function tryConnect(e:TimerEvent=null):void 
		{
			Output.trace("ServerConnector.tryConnect > e : " + e);
			timer.removeEventListener(TimerEvent.TIMER, tryConnect);
 
			socket = new XMLSocket();
			socket.addEventListener(Event.CONNECT, onTryConnect);
			socket.addEventListener(DataEvent.DATA, onTryData);
			socket.addEventListener(Event.CLOSE, onTryClose);
 
                        if (serverHost && serverPort) {
                           socket.connect(serverHost, socketPolicyPort);
                        }
		}
 
 
		private function onTryConnect(e:Event):void 
		{
			socket.removeEventListener(Event.CONNECT, onTryConnect);
			// посылаем первый пинг
			send("ping");
		}
 
		/**
		 * Хэндлер политики безопасности
		 * Запускаем основной коннект
		 * @param	e
		 */
		private function onTryClose(e:Event=null):void 
		{
			Output.trace("ServerConnector.onTryClose > e : " + e);
			socket.removeEventListener(Event.CLOSE, onTryClose);
			socket.removeEventListener(DataEvent.DATA, onTryData);
			socket.removeEventListener(Event.CONNECT, onTryConnect);
 
			baseConnect();
		}
 
		private function onTryData(e:DataEvent):void 
		{
			Output.trace("ServerConnector.onTryData > e : " + e);
			socket.close();
			onTryClose();
		}
 
 
		//--------------------------baseConnect---------------------------------------
 
		private function baseConnect():void
		{
			Output.trace("ServerConnector.baseConnect"); 
			configureListeners(socket);
                        socket.connect(serverHost, serverPort);
		}
 
 
 
 
		/**
		 * Посылка данных
		 * @param	data
		 */
		public function send(data:*):void {
                      socket.send(data);
                 }
 
 
		//----------------socket handlers---------------------------------------
		private function configureListeners(dispatcher:IEventDispatcher):void {
            dispatcher.addEventListener(Event.CLOSE, closeHandler);
            dispatcher.addEventListener(Event.CONNECT, connectHandler);
            dispatcher.addEventListener(DataEvent.DATA, dataHandler);
            dispatcher.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
            dispatcher.addEventListener(ProgressEvent.PROGRESS, progressHandler);
            dispatcher.addEventListener(SecurityErrorEvent.SECURITY_ERROR, securityErrorHandler);
        }
 
 
        private function closeHandler(event:Event):void {
            Output.trace("closeHandler: " + event);
			// пробуем коннект после прихода политик
        }
 
        private function connectHandler(event:Event):void {
            Output.trace("connectHandler: " + event);
        }
 
        private function ioErrorHandler(event:IOErrorEvent):void {
            Output.trace("ioErrorHandler: " + event);
        }
 
        private function progressHandler(event:ProgressEvent):void {
            Output.trace("progressHandler loaded:" + event.bytesLoaded + " total: " + event.bytesTotal);
        }
 
        private function securityErrorHandler(event:SecurityErrorEvent):void {
            Output.trace("securityErrorHandler: " + event);
        }
 
		/**
		 *  Хэндлер сообщений
		 * @param	event
		 */
        private function dataHandler(event:DataEvent):void {
            //Output.trace("dataHandler: " + event);	
			dispatchEvent(new DataEvent(DataEvent.DATA, false, false, event.data));
        }
		//----------------socket handlers---------------------------------------
 
	}
 
}