Список актуальных камер юзера.

Код AS3:

_testCams = new ActiveCameraList();
_testCams.addEventListener(Event.COMPLETE, onCompleteScanVideoDevices);
_testCams.checkCams();

Код AS3:

package media
{
	import flash.events.Event;
	import flash.events.EventDispatcher;
	import flash.events.StatusEvent;
	import flash.events.TimerEvent;
	import flash.media.Camera;
	import flash.media.Video;
	import flash.system.Security;
	import flash.system.SecurityPanel;
	import flash.utils.Timer;
 
 
	public class ActiveCameraList extends EventDispatcher
	{
 
		private var _video:Video;
 
		private var _currentCamIndex:uint;
 
		private var _camera:Camera;
 
		/*		список актуальных камер			*/
		private var _list:Array = [];
 
		/* 		список с потенциальными камерами	*/
		private var _probableCamList:Array;
 
		private var _timer:Timer = new Timer(2000);
 
 
		public function checkCams():void
		{
			//если камер не обнаружено
			if(Camera.names == null) 
			{
				complete();
				return;
			}
			////
			_probableCamList = Camera.names;
			_currentCamIndex = 0;
			_camera = Camera.getCamera(_currentCamIndex.toString());
 
			//если у юзера по умолчанию стоит согласие с передачей данных с микрофона и камеры
			if(!_camera.muted)
			{
				_video = new Video();
				_video.attachCamera(_camera);
				_timer.addEventListener(TimerEvent.TIMER, checkCam);
				_timer.start();
			}
			//иначе предлагаем юзеру разрешить доступ к камере
			else
			{
				_camera.addEventListener(StatusEvent.STATUS , onCamStatus);
				Security.showSettings(SecurityPanel.PRIVACY);
			}
		}
 
		private function onCamStatus(event:StatusEvent):void 
		{ 
			// если юзер дал согласие - начинаем тестить камеры, иначе по вашему усмотрению
			if(!_camera.muted)
			{
				_camera.removeEventListener(StatusEvent.STATUS , onCamStatus);
				_video = new Video();
				_video.attachCamera(_camera);
				_timer.addEventListener(TimerEvent.TIMER, checkCam);
				_timer.start();
			}
                        else
                        {
                                //TODO
                        }
                        // также юзер мог вообще не делать выбор и просто закрыть окно SecurityPanel.PRIVACY как это словить я не знаю (:
		}
 
		private function checkCam(event:TimerEvent):void 
		{ 
			//если текущее значение ФПС больше нуля, добавляем в список имя камеры, также можно передать и индекс
			if(_camera.currentFPS > 0)
			{
				_list.push(_camera.name);
				//_list.push(_currentCamIndex);
			}
			// проверяем следующую камеру
			_currentCamIndex ++;
			if(_currentCamIndex < _probableCamList.length)
			{
				_camera = Camera.getCamera(_currentCamIndex.toString());
				_video = new Video();
				_video.attachCamera(_camera);
				_timer.start();
			}
			else
			{
				_camera = null;
				_video = null;
				_timer.stop();
				_timer.removeEventListener(TimerEvent.TIMER, checkCam);
				complete();
			}
		} 
 
		private function complete():void
		{
			dispatchEvent(new Event(Event.COMPLETE));
		}
 
		public function get list():Array 
		{ 
			return(_list);
		} 
 
	}//end class
}//end package