Загрузка изображений на этапе компиляции и дальнейшее использование

[bifidokk]

Понадобилось загрузить 30-40 изображений. Все они имеют имена: 1.gif, 2.gif итд.
закидываю их во флеш:

[Embed(source="/images/damage_digits/1.gif")] var damageDigit1:Class;

и т.д. все 30

далее есть метод, который должен обратиться к нужно картинке по параметру, вытащить ее и возвратить вызывающему.

private function loadDamageDigit(damage:int):Bitmap{
           var imgLoad:Class=getDefinitionByName("damageDigit" + damage.toString())    as Class;
           damageDigits[damage.toString()] = new imgLoad();
           return damageDigits[damage.toString()];

вроде все должно работать, но компилятор выдает ошибку и говорит, что damageDigit1 не определена.
как решить проблему?

[Wolsh]

Сложите классы в массив, все станет проще.

[ps_spectre]

Предлагаю рассмотреть такой вариант:
something.Embeds.as

package something
{
	public class Embeds
	{
		[Embed(source="../assets/SomeImage.png")]
		public var Image1:Class;
 
		[Embed(source="../assets/SomeImage2.png")]
		public var Image2:Class;
 
		public function Embeds() {}
	}
}

Tests.as

package
{
	import flash.display.Sprite;	
 
	import something.Embeds;
 
	public class Tests extends Sprite
	{
		public function Tests()
		{
			var e:Embeds = new Embeds();
 
			addChild(new e["Image1"]);
			addChild(new e["Image2"]);			
		}
	}
}

Второй вариант, требует понимание как примерно работает mxmlc.

package something
{
	public class Embeds
	{
		[Embed(source="../assets/SomeImage.png")]
		public static var Image1:Class;
 
		[Embed(source="../assets/SomeImage2.png")]
		public static var Image2:Class;
 
		public function Embeds() {}
	}
}

(для невнимательных: переменные static)

package
{
	import flash.display.Sprite;
	import flash.utils.getDefinitionByName;
 
	import something.Embeds;
 
	public class Tests extends Sprite
	{
		public function Tests()
		{
			var Img1:Class = getDefinitionByName("something.Embeds_Image1") as Class;
			var Emb:Class = getDefinitionByName("something.Embeds") as Class;
			addChild(new Emb["Image2"]);
			addChild(new Img1());
		}
	}
}

но обязательно надо указать компилятору явно включить класс Embeds

 -includes something.Embeds

something.Embeds_Image1 это появилось при компиляции. Детальней в блоге я писал. (тыц)

[bifidokk]

спасибо, буду пробовать)