Загрузка изображения с машины юзера во flash без загрузки на сервер

[9172]

Схема сейчас такая:
Юзер выбирает файл изображения на своём компе, через FileReference происходит загрузка изображения на сервер, и потом flash загружает это изображение с сервера, выводя его на экран.

Вопрос:
Реально сделать всё это без загрузки картинки на сервер, ведь физически и картинка и flash player находяться на одном компе???

[kackbip]

Только флэшом - нет.
Чем можно - хз

[iNils]

Только начиная с 10-го плеера.

[9172]

Спасибо, так я идумал... но для 10-го пллера делать пока рано...

[SamFR]

Извините, может чего недопонял. iNils, а почему только с 10-го? Чем не подходит

var loader:Loader = new Loader();
loader.load(new URLRequest('путь_на_локальной_машине.jpg'));

Ведь речь идёт о загрузке и отображении изображения с компа юзера?

[iNils]

путь_на_локальной_машине через FileReference нельзя получить.

[SamFR]

Точно. Не знал.
iNils, а можно узнать, как это под FP10 делается?

[musat]

Под Flash Player 10:

package {
	import flash.display.Sprite;
	import flash.display.Loader;
	import flash.net.FileReference;
	import flash.net.FileFilter;
	import flash.events.Event;
	import flash.utils.ByteArray;
 
	public class Main extends Sprite {
		private var fileRef:FileReference;
		private var loader:Loader;
 
		public function Main() {
			fileRef = new FileReference();
			fileRef.addEventListener(Event.SELECT,onFileSelected);
			var imageTypeFilter:FileFilter = new FileFilter("Изображения (*.jpg, *.jpeg, *.gif, *.png)","*.jpg;*.jpeg;*.gif;*.png");
			fileRef.browse([imageTypeFilter]);
		}
 
		private function onFileSelected(e:Event):void {
			fileRef.addEventListener(Event.COMPLETE,onComplete);
			fileRef.load();
		}
 
		private function onComplete(e:Event):void {
			var imageData:ByteArray = fileRef.data;  // это и есть загруженная картинка
			loader = new Loader();
			loader.loadBytes(imageData);
			addChild(loader);
		}
	}
}

[iNils]

Метод FileReference.load ()

[SamFR]

Спасибо, буду знать.